let A be closed-interval Subset of REAL; :: thesis: for Z being open Subset of REAL st A c= Z holds
integral ((sin + ((id Z) (#) cos)),A) = (((id Z) (#) sin) . (upper_bound A)) - (((id Z) (#) sin) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z implies integral ((sin + ((id Z) (#) cos)),A) = (((id Z) (#) sin) . (upper_bound A)) - (((id Z) (#) sin) . (lower_bound A)) )
assume A1: A c= Z ; :: thesis: integral ((sin + ((id Z) (#) cos)),A) = (((id Z) (#) sin) . (upper_bound A)) - (((id Z) (#) sin) . (lower_bound A))
A2: cos is_differentiable_on Z by FDIFF_1:34, SIN_COS:72;
A3: for x being Real st x in Z holds
(id Z) . x = (1 * x) + 0 by FUNCT_1:35;
dom (sin + ((id Z) (#) cos)) = REAL /\ (dom ((id Z) (#) cos)) by SIN_COS:27, VALUED_1:def 1
.= dom ((id Z) (#) cos) by XBOOLE_1:28
.= (dom (id Z)) /\ REAL by SIN_COS:27, VALUED_1:def 4
.= dom (id Z) by XBOOLE_1:28 ;
then A4: Z = dom (sin + ((id Z) (#) cos)) by RELAT_1:71;
then Z = (dom sin) /\ (dom ((id Z) (#) cos)) by VALUED_1:def 1;
then A5: Z c= dom ((id Z) (#) cos) by XBOOLE_1:18;
then Z c= (dom (id Z)) /\ (dom cos) by VALUED_1:def 4;
then Z c= dom (id Z) by XBOOLE_1:18;
then id Z is_differentiable_on Z by A3, FDIFF_1:31;
then ( sin is_differentiable_on Z & (id Z) (#) cos is_differentiable_on Z ) by A5, A2, FDIFF_1:29, FDIFF_1:34, SIN_COS:73;
then A6: (sin + ((id Z) (#) cos)) | Z is continuous by A4, FDIFF_1:26, FDIFF_1:33;
then (sin + ((id Z) (#) cos)) | A is continuous by A1, FCONT_1:17;
then A7: sin + ((id Z) (#) cos) is_integrable_on A by A1, A4, INTEGRA5:11;
A8: dom ((id Z) (#) sin) = (dom (id Z)) /\ REAL by SIN_COS:27, VALUED_1:def 4
.= dom (id Z) by XBOOLE_1:28
.= Z by RELAT_1:71 ;
then A9: (id Z) (#) sin is_differentiable_on Z by FDIFF_4:45;
A10: for x being Real st x in Z holds
(sin + ((id Z) (#) cos)) . x = (sin . x) + (x * (cos . x))

proof

let x be Real; :: thesis: ( x in Z implies (sin + ((id Z) (#) cos)) . x = (sin . x) + (x * (cos . x)) )
assume A11: x in Z ; :: thesis: (sin + ((id Z) (#) cos)) . x = (sin . x) + (x * (cos . x))
then (sin + ((id Z) (#) cos)) . x = (sin . x) + (((id Z) (#) cos) . x) by A4, VALUED_1:def 1
.= (sin . x) + (((id Z) . x) * (cos . x)) by VALUED_1:5
.= (sin . x) + (x * (cos . x)) by A11, FUNCT_1:35 ;
hence (sin + ((id Z) (#) cos)) . x = (sin . x) + (x * (cos . x)) ; :: thesis: verum

end;

A12: for x being Real st x in dom (((id Z) (#) sin) `| Z) holds
(((id Z) (#) sin) `| Z) . x = (sin + ((id Z) (#) cos)) . x

proof

let x be Real; :: thesis: ( x in dom (((id Z) (#) sin) `| Z) implies (((id Z) (#) sin) `| Z) . x = (sin + ((id Z) (#) cos)) . x )
assume x in dom (((id Z) (#) sin) `| Z) ; :: thesis: (((id Z) (#) sin) `| Z) . x = (sin + ((id Z) (#) cos)) . x
then A13: x in Z by A9, FDIFF_1:def 8;
then (((id Z) (#) sin) `| Z) . x = (sin . x) + (x * (cos . x)) by A8, FDIFF_4:45
.= (sin + ((id Z) (#) cos)) . x by A10, A13 ;
hence (((id Z) (#) sin) `| Z) . x = (sin + ((id Z) (#) cos)) . x ; :: thesis: verum

end;

dom (((id Z) (#) sin) `| Z) = dom (sin + ((id Z) (#) cos)) by A4, A9, FDIFF_1:def 8;
then A14: ((id Z) (#) sin) `| Z = sin + ((id Z) (#) cos) by A12, PARTFUN1:34;
(sin + ((id Z) (#) cos)) | A is bounded by A1, A4, A6, FCONT_1:17, INTEGRA5:10;
hence integral ((sin + ((id Z) (#) cos)),A) = (((id Z) (#) sin) . (upper_bound A)) - (((id Z) (#) sin) . (lower_bound A)) by A1, A8, A7, A14, FDIFF_4:45, INTEGRA5:13; :: thesis: verum