let A be closed-interval Subset of REAL; :: thesis: for f being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & f = - ((exp_R * cot) / (sin ^2)) & Z = dom f & f | A is continuous holds
integral (f,A) = ((exp_R * cot) . (upper_bound A)) - ((exp_R * cot) . (lower_bound A))
let f be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & f = - ((exp_R * cot) / (sin ^2)) & Z = dom f & f | A is continuous holds
integral (f,A) = ((exp_R * cot) . (upper_bound A)) - ((exp_R * cot) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & f = - ((exp_R * cot) / (sin ^2)) & Z = dom f & f | A is continuous implies integral (f,A) = ((exp_R * cot) . (upper_bound A)) - ((exp_R * cot) . (lower_bound A)) )
assume A1: ( A c= Z & f = - ((exp_R * cot) / (sin ^2)) & Z = dom f & f | A is continuous ) ; :: thesis: integral (f,A) = ((exp_R * cot) . (upper_bound A)) - ((exp_R * cot) . (lower_bound A))
then A2: ( f is_integrable_on A & f | A is bounded ) by INTEGRA5:10, INTEGRA5:11;
AA: Z = dom ((exp_R * cot) / (sin ^2)) by A1, VALUED_1:8;
then Z c= (dom (exp_R * cot)) /\ ((dom (sin ^2)) \ ((sin ^2) " {0})) by RFUNCT_1:def 4;
then A3: Z c= dom (exp_R * cot) by XBOOLE_1:18;
then A4: exp_R * cot is_differentiable_on Z by FDIFF_8:17;
A5: for x being Real st x in Z holds
f . x = - ((exp_R . (cot . x)) / ((sin . x) ^2))

proof

let x be Real; :: thesis: ( x in Z implies f . x = - ((exp_R . (cot . x)) / ((sin . x) ^2)) )
assume A6: x in Z ; :: thesis: f . x = - ((exp_R . (cot . x)) / ((sin . x) ^2))
(- ((exp_R * cot) / (sin ^2))) . x = - (((exp_R * cot) / (sin ^2)) . x) by VALUED_1:8
.= - (((exp_R * cot) . x) / ((sin ^2) . x)) by RFUNCT_1:def 4, A6, AA
.= - ((exp_R . (cot . x)) / ((sin ^2) . x)) by FUNCT_1:22, A3, A6
.= - ((exp_R . (cot . x)) / ((sin . x) ^2)) by VALUED_1:11 ;
hence f . x = - ((exp_R . (cot . x)) / ((sin . x) ^2)) by A1; :: thesis: verum

end;

A7: for x being Real st x in dom ((exp_R * cot) `| Z) holds
((exp_R * cot) `| Z) . x = f . x

proof

let x be Real; :: thesis: ( x in dom ((exp_R * cot) `| Z) implies ((exp_R * cot) `| Z) . x = f . x )
assume x in dom ((exp_R * cot) `| Z) ; :: thesis: ((exp_R * cot) `| Z) . x = f . x
then A8: x in Z by A4, FDIFF_1:def 8;
then ((exp_R * cot) `| Z) . x = - ((exp_R . (cot . x)) / ((sin . x) ^2)) by A3, FDIFF_8:17
.= f . x by A5, A8 ;
hence ((exp_R * cot) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((exp_R * cot) `| Z) = dom f by A1, A4, FDIFF_1:def 8;
then (exp_R * cot) `| Z = f by A7, PARTFUN1:34;
hence integral (f,A) = ((exp_R * cot) . (upper_bound A)) - ((exp_R * cot) . (lower_bound A)) by A1, A2, A3, FDIFF_8:17, INTEGRA5:13; :: thesis: verum