let a, b be Real; :: thesis: for A being closed-interval Subset of REAL
for f1, f being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
f1 . x = (a * x) + b ) & Z = dom f & f = (a (#) (sin / cos)) + (f1 / (cos ^2)) holds
integral (f,A) = ((f1 (#) tan) . (upper_bound A)) - ((f1 (#) tan) . (lower_bound A))
let A be closed-interval Subset of REAL; :: thesis: for f1, f being PartFunc of REAL,REAL
for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
f1 . x = (a * x) + b ) & Z = dom f & f = (a (#) (sin / cos)) + (f1 / (cos ^2)) holds
integral (f,A) = ((f1 (#) tan) . (upper_bound A)) - ((f1 (#) tan) . (lower_bound A))
let f1, f be PartFunc of REAL,REAL; :: thesis: for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
f1 . x = (a * x) + b ) & Z = dom f & f = (a (#) (sin / cos)) + (f1 / (cos ^2)) holds
integral (f,A) = ((f1 (#) tan) . (upper_bound A)) - ((f1 (#) tan) . (lower_bound A))
let Z be open Subset of REAL; :: thesis: ( A c= Z & ( for x being Real st x in Z holds
f1 . x = (a * x) + b ) & Z = dom f & f = (a (#) (sin / cos)) + (f1 / (cos ^2)) implies integral (f,A) = ((f1 (#) tan) . (upper_bound A)) - ((f1 (#) tan) . (lower_bound A)) )
assume A1: ( A c= Z & ( for x being Real st x in Z holds
f1 . x = (a * x) + b ) & Z = dom f & f = (a (#) (sin / cos)) + (f1 / (cos ^2)) ) ; :: thesis: integral (f,A) = ((f1 (#) tan) . (upper_bound A)) - ((f1 (#) tan) . (lower_bound A))
then A3: Z = (dom (a (#) (sin / cos))) /\ (dom (f1 / (cos ^2))) by VALUED_1:def 1;
then A4: Z c= dom (a (#) (sin / cos)) by XBOOLE_1:18;
then A5: Z c= dom (sin / cos) by VALUED_1:def 5;
A6: Z c= dom (f1 / (cos ^2)) by XBOOLE_1:18, A3;
dom (f1 / (cos ^2)) = (dom f1) /\ ((dom (cos ^2)) \ ((cos ^2) " {0})) by RFUNCT_1:def 4;
then A8: Z c= dom f1 by A6, XBOOLE_1:18;
then Z c= (dom f1) /\ (dom tan) by XBOOLE_1:19, A5;
then A11: Z c= dom (f1 (#) tan) by VALUED_1:def 4;
for x being Real st x in Z holds
sin / cos is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies sin / cos is_differentiable_in x )
assume x in Z ; :: thesis: sin / cos is_differentiable_in x
then cos . x <> 0 by A5, FDIFF_8:1;
hence sin / cos is_differentiable_in x by FDIFF_7:46; :: thesis: verum

end;

then sin / cos is_differentiable_on Z by A5, FDIFF_1:16;
then A14: a (#) (sin / cos) is_differentiable_on Z by A4, FDIFF_1:28;
A15: f1 is_differentiable_on Z by A1, A8, FDIFF_1:31;
cos is_differentiable_on Z by FDIFF_1:34, SIN_COS:72;
then A17: cos ^2 is_differentiable_on Z by FDIFF_2:20;
for x being Real st x in Z holds
(cos ^2) . x <> 0

proof

let x be Real; :: thesis: ( x in Z implies (cos ^2) . x <> 0 )
assume x in Z ; :: thesis: (cos ^2) . x <> 0
then x in dom (f1 / (cos ^2)) by A6;
then x in (dom f1) /\ ((dom (cos ^2)) \ ((cos ^2) " {0})) by RFUNCT_1:def 4;
then x in (dom (cos ^2)) \ ((cos ^2) " {0}) by XBOOLE_0:def 4;
then x in dom ((cos ^2) ^) by RFUNCT_1:def 8;
hence (cos ^2) . x <> 0 by RFUNCT_1:13; :: thesis: verum

end;

then f1 / (cos ^2) is_differentiable_on Z by A15, A17, FDIFF_2:21;
then f | Z is continuous by FDIFF_1:33, A1, A14, FDIFF_1:26;
then f | A is continuous by A1, FCONT_1:17;
then A22: ( f is_integrable_on A & f | A is bounded ) by A1, INTEGRA5:10, INTEGRA5:11;
A23: f1 (#) tan is_differentiable_on Z by A1, A11, FDIFF_8:28;
B1: for x being Real st x in Z holds
f . x = ((a * (sin . x)) / (cos . x)) + (((a * x) + b) / ((cos . x) ^2))

proof

let x be Real; :: thesis: ( x in Z implies f . x = ((a * (sin . x)) / (cos . x)) + (((a * x) + b) / ((cos . x) ^2)) )
assume B2: x in Z ; :: thesis: f . x = ((a * (sin . x)) / (cos . x)) + (((a * x) + b) / ((cos . x) ^2))
then ((a (#) (sin / cos)) + (f1 / (cos ^2))) . x = ((a (#) (sin / cos)) . x) + ((f1 / (cos ^2)) . x) by VALUED_1:def 1, A1
.= (a * ((sin / cos) . x)) + ((f1 / (cos ^2)) . x) by VALUED_1:6
.= (a * ((sin . x) / (cos . x))) + ((f1 / (cos ^2)) . x) by RFUNCT_1:def 4, B2, A5
.= ((a * (sin . x)) / (cos . x)) + ((f1 . x) / ((cos ^2) . x)) by RFUNCT_1:def 4, B2, A6
.= ((a * (sin . x)) / (cos . x)) + ((f1 . x) / ((cos . x) ^2)) by VALUED_1:11
.= ((a * (sin . x)) / (cos . x)) + (((a * x) + b) / ((cos . x) ^2)) by A1, B2 ;
hence f . x = ((a * (sin . x)) / (cos . x)) + (((a * x) + b) / ((cos . x) ^2)) by A1; :: thesis: verum

end;

A24: for x being Real st x in dom ((f1 (#) tan) `| Z) holds
((f1 (#) tan) `| Z) . x = f . x

proof

let x be Real; :: thesis: ( x in dom ((f1 (#) tan) `| Z) implies ((f1 (#) tan) `| Z) . x = f . x )
assume x in dom ((f1 (#) tan) `| Z) ; :: thesis: ((f1 (#) tan) `| Z) . x = f . x
then A25: x in Z by A23, FDIFF_1:def 8;
then ((f1 (#) tan) `| Z) . x = ((a * (sin . x)) / (cos . x)) + (((a * x) + b) / ((cos . x) ^2)) by A1, A11, FDIFF_8:28
.= f . x by B1, A25 ;
hence ((f1 (#) tan) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((f1 (#) tan) `| Z) = dom f by A1, A23, FDIFF_1:def 8;
then (f1 (#) tan) `| Z = f by A24, PARTFUN1:34;
hence integral (f,A) = ((f1 (#) tan) . (upper_bound A)) - ((f1 (#) tan) . (lower_bound A)) by A1, A22, A11, FDIFF_8:28, INTEGRA5:13; :: thesis: verum