let G be Go-board; :: thesis: Int (h_strip (G,0)) = { |[r,s]| where r, s is Real : s < (G * (1,1)) `2 }
0 <> len G by GOBOARD1:def 5;
then 1 <= len G by NAT_1:14;
then A1: h_strip (G,0) = { |[r,s]| where r, s is Real : s <= (G * (1,1)) `2 } by GOBOARD5:8;
thus Int (h_strip (G,0)) c= { |[r,s]| where r, s is Real : s < (G * (1,1)) `2 } :: according to XBOOLE_0:def 10 :: thesis: { |[r,s]| where r, s is Real : s < (G * (1,1)) `2 } c= Int (h_strip (G,0))

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in Int (h_strip (G,0)) or x in { |[r,s]| where r, s is Real : s < (G * (1,1)) `2 } )
assume A2: x in Int (h_strip (G,0)) ; :: thesis: x in { |[r,s]| where r, s is Real : s < (G * (1,1)) `2 }
then reconsider u = x as Point of (Euclid 2) by Lm6;
consider s1 being real number such that
A3: s1 > 0 and
A4: Ball (u,s1) c= h_strip (G,0) by A2, Th8;
reconsider p = u as Point of (TOP-REAL 2) by Lm6;
A5: p = |[(p `1),(p `2)]| by EUCLID:57;
reconsider s1 = s1 as Real by XREAL_0:def 1;
set q = |[((p `1) + 0),((p `2) + (s1 / 2))]|;
s1 / 2 < s1 by A3, XREAL_1:218;
then |[((p `1) + 0),((p `2) + (s1 / 2))]| in Ball (u,s1) by A3, A5, Th11;
then |[((p `1) + 0),((p `2) + (s1 / 2))]| in h_strip (G,0) by A4;
then ex r2, s2 being Real st
( |[((p `1) + 0),((p `2) + (s1 / 2))]| = |[r2,s2]| & s2 <= (G * (1,1)) `2 ) by A1;
then A6: (p `2) + (s1 / 2) <= (G * (1,1)) `2 by SPPOL_2:1;
p `2 < (p `2) + (s1 / 2) by A3, XREAL_1:31, XREAL_1:217;
then p `2 < (G * (1,1)) `2 by A6, XXREAL_0:2;
hence x in { |[r,s]| where r, s is Real : s < (G * (1,1)) `2 } by A5; :: thesis: verum

end;

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in { |[r,s]| where r, s is Real : s < (G * (1,1)) `2 } or x in Int (h_strip (G,0)) )
assume x in { |[r,s]| where r, s is Real : s < (G * (1,1)) `2 } ; :: thesis: x in Int (h_strip (G,0))
then consider r, s being Real such that
A7: x = |[r,s]| and
A8: s < (G * (1,1)) `2 ;
reconsider u = |[r,s]| as Point of (Euclid 2) by TOPREAL3:13;
A9: Ball (u,(((G * (1,1)) `2) - s)) c= h_strip (G,0)

proof

let y be set ; :: according to TARSKI:def 3 :: thesis: ( not y in Ball (u,(((G * (1,1)) `2) - s)) or y in h_strip (G,0) )
A10: Ball (u,(((G * (1,1)) `2) - s)) = { v where v is Point of (Euclid 2) : dist (u,v) < ((G * (1,1)) `2) - s } by METRIC_1:18;
assume y in Ball (u,(((G * (1,1)) `2) - s)) ; :: thesis: y in h_strip (G,0)
then consider v being Point of (Euclid 2) such that
A11: v = y and
A12: dist (u,v) < ((G * (1,1)) `2) - s by A10;
reconsider q = v as Point of (TOP-REAL 2) by TOPREAL3:13;
0 <= (r - (q `1)) ^2 by XREAL_1:65;
then ( (s - (q `2)) ^2 >= 0 & ((s - (q `2)) ^2) + 0 <= ((r - (q `1)) ^2) + ((s - (q `2)) ^2) ) by XREAL_1:8, XREAL_1:65;
then A13: sqrt ((s - (q `2)) ^2) <= sqrt (((r - (q `1)) ^2) + ((s - (q `2)) ^2)) by SQUARE_1:94;
A14: q = |[(q `1),(q `2)]| by EUCLID:57;
then sqrt (((r - (q `1)) ^2) + ((s - (q `2)) ^2)) < ((G * (1,1)) `2) - s by A12, Th9;
then sqrt ((s - (q `2)) ^2) <= ((G * (1,1)) `2) - s by A13, XXREAL_0:2;
then A15: abs (s - (q `2)) <= ((G * (1,1)) `2) - s by COMPLEX1:158;

per cases ( s <= q `2 or s >= q `2 ) ;

suppose s <= q `2 ; :: thesis: y in h_strip (G,0)

then A16: (q `2) - s >= 0 by XREAL_1:50;
abs (s - (q `2)) = abs (- (s - (q `2))) by COMPLEX1:138
.= (q `2) - s by A16, ABSVALUE:def 1 ;
then q `2 <= (G * (1,1)) `2 by A15, XREAL_1:11;
hence y in h_strip (G,0) by A1, A11, A14; :: thesis: verum

end;

suppose s >= q `2 ; :: thesis: y in h_strip (G,0)

then q `2 <= (G * (1,1)) `2 by A8, XXREAL_0:2;
hence y in h_strip (G,0) by A1, A11, A14; :: thesis: verum

end;

end;

end;

reconsider B = Ball (u,(((G * (1,1)) `2) - s)) as Subset of (TOP-REAL 2) by TOPREAL3:13;
A17: B is open by Th6;
u in Ball (u,(((G * (1,1)) `2) - s)) by A8, Th4, XREAL_1:52;
hence x in Int (h_strip (G,0)) by A7, A9, A17, TOPS_1:54; :: thesis: verum