let C, D, D9 be Category; :: thesis: for T being Functor of C,D
for T9 being Functor of C,D9 holds <:T,T9:> is Functor of C,[:D,D9:]
let T be Functor of C,D; :: thesis: for T9 being Functor of C,D9 holds <:T,T9:> is Functor of C,[:D,D9:]
let T9 be Functor of C,D9; :: thesis: <:T,T9:> is Functor of C,[:D,D9:]
reconsider S = <:T,T9:> as Function of the carrier' of C, the carrier' of [:D,D9:] ;

now

thus for c being Object of C ex dd9 being Object of [:D,D9:] st S . (id c) = id dd9 :: thesis: ( ( for f being Morphism of C holds
( S . (id (dom f)) = id (dom (S . f)) & S . (id (cod f)) = id (cod (S . f)) ) ) & ( for f, g being Morphism of C st dom g = cod f holds
S . (g * f) = (S . g) * (S . f) ) )

proof

let c be Object of C; :: thesis: ex dd9 being Object of [:D,D9:] st S . (id c) = id dd9
set d = (Obj T) . c;
set d9 = (Obj T9) . c;
take dd9 = [((Obj T) . c),((Obj T9) . c)]; :: thesis: S . (id c) = id dd9
thus S . (id c) = [(T . (id c)),(T9 . (id c))] by FUNCT_3:79
.= [(id ((Obj T) . c)),(T9 . (id c))] by CAT_1:104
.= [(id ((Obj T) . c)),(id ((Obj T9) . c))] by CAT_1:104
.= id dd9 by Th41 ; :: thesis: verum

end;

thus for f being Morphism of C holds
( S . (id (dom f)) = id (dom (S . f)) & S . (id (cod f)) = id (cod (S . f)) ) :: thesis: for f, g being Morphism of C st dom g = cod f holds
S . (g * f) = (S . g) * (S . f)

proof

let f be Morphism of C; :: thesis: ( S . (id (dom f)) = id (dom (S . f)) & S . (id (cod f)) = id (cod (S . f)) )
( T . (id (dom f)) = id (dom (T . f)) & T9 . (id (dom f)) = id (dom (T9 . f)) ) by CAT_1:98;
hence S . (id (dom f)) = [(id (dom (T . f))),(id (dom (T9 . f)))] by FUNCT_3:79
.= id [(dom (T . f)),(dom (T9 . f))] by Th41
.= id (dom [(T . f),(T9 . f)]) by Th38
.= id (dom (S . f)) by FUNCT_3:79 ;
:: thesis: S . (id (cod f)) = id (cod (S . f))
( T . (id (cod f)) = id (cod (T . f)) & T9 . (id (cod f)) = id (cod (T9 . f)) ) by CAT_1:98;
hence S . (id (cod f)) = [(id (cod (T . f))),(id (cod (T9 . f)))] by FUNCT_3:79
.= id [(cod (T . f)),(cod (T9 . f))] by Th41
.= id (cod [(T . f),(T9 . f)]) by Th38
.= id (cod (S . f)) by FUNCT_3:79 ;
:: thesis: verum

end;

let f, g be Morphism of C; :: thesis: ( dom g = cod f implies S . (g * f) = (S . g) * (S . f) )
assume A1: dom g = cod f ; :: thesis: S . (g * f) = (S . g) * (S . f)
then A2: ( dom (T . g) = cod (T . f) & dom (T9 . g) = cod (T9 . f) ) by CAT_1:99;
( T . (g * f) = (T . g) * (T . f) & T9 . (g * f) = (T9 . g) * (T9 . f) ) by A1, CAT_1:99;
hence S . (g * f) = [((T . g) * (T . f)),((T9 . g) * (T9 . f))] by FUNCT_3:79
.= [(T . g),(T9 . g)] * [(T . f),(T9 . f)] by A2, Th39
.= (S . g) * [(T . f),(T9 . f)] by FUNCT_3:79
.= (S . g) * (S . f) by FUNCT_3:79 ;
:: thesis: verum

end;

hence <:T,T9:> is Functor of C,[:D,D9:] by CAT_1:96; :: thesis: verum