let Y be non empty set ; :: thesis: for G being Subset of (PARTITIONS Y)
for b, c, a being Element of Funcs (Y,BOOLEAN)
for PA being a_partition of Y holds ((Ex (b,PA,G)) '&' (All ((b 'imp' c),PA,G))) '&' (All ((c 'imp' a),PA,G)) '<' Ex ((a '&' b),PA,G)
let G be Subset of (PARTITIONS Y); :: thesis: for b, c, a being Element of Funcs (Y,BOOLEAN)
for PA being a_partition of Y holds ((Ex (b,PA,G)) '&' (All ((b 'imp' c),PA,G))) '&' (All ((c 'imp' a),PA,G)) '<' Ex ((a '&' b),PA,G)
let b, c, a be Element of Funcs (Y,BOOLEAN); :: thesis: for PA being a_partition of Y holds ((Ex (b,PA,G)) '&' (All ((b 'imp' c),PA,G))) '&' (All ((c 'imp' a),PA,G)) '<' Ex ((a '&' b),PA,G)
let PA be a_partition of Y; :: thesis: ((Ex (b,PA,G)) '&' (All ((b 'imp' c),PA,G))) '&' (All ((c 'imp' a),PA,G)) '<' Ex ((a '&' b),PA,G)
let z be Element of Y; :: according to BVFUNC_1:def 15 :: thesis: ( not (((Ex (b,PA,G)) '&' (All ((b 'imp' c),PA,G))) '&' (All ((c 'imp' a),PA,G))) . z = TRUE or (Ex ((a '&' b),PA,G)) . z = TRUE )
assume (((Ex (b,PA,G)) '&' (All ((b 'imp' c),PA,G))) '&' (All ((c 'imp' a),PA,G))) . z = TRUE ; :: thesis: (Ex ((a '&' b),PA,G)) . z = TRUE
then A1: (((Ex (b,PA,G)) '&' (All ((b 'imp' c),PA,G))) . z) '&' ((All ((c 'imp' a),PA,G)) . z) = TRUE by MARGREL1:def 21;
then (((Ex (b,PA,G)) . z) '&' ((All ((b 'imp' c),PA,G)) . z)) '&' ((All ((c 'imp' a),PA,G)) . z) = TRUE by MARGREL1:def 21;
then A2: ((Ex (b,PA,G)) . z) '&' ((All ((b 'imp' c),PA,G)) . z) = TRUE by MARGREL1:45;

now

assume for x being Element of Y holds
( not x in EqClass (z,(CompF (PA,G))) or not b . x = TRUE ) ; :: thesis: contradiction
then (B_SUP (b,(CompF (PA,G)))) . z = FALSE by BVFUNC_1:def 20;
then (Ex (b,PA,G)) . z = FALSE by BVFUNC_2:def 10;
hence contradiction by A2, MARGREL1:45; :: thesis: verum

end;

then consider x1 being Element of Y such that
A3: x1 in EqClass (z,(CompF (PA,G))) and
A4: b . x1 = TRUE ;
A5: ( 'not' (c . x1) = TRUE or 'not' (c . x1) = FALSE ) by XBOOLEAN:def 3;

now

assume ex x being Element of Y st
( x in EqClass (z,(CompF (PA,G))) & not (c 'imp' a) . x = TRUE ) ; :: thesis: contradiction
then (B_INF ((c 'imp' a),(CompF (PA,G)))) . z = FALSE by BVFUNC_1:def 19;
then (All ((c 'imp' a),PA,G)) . z = FALSE by BVFUNC_2:def 9;
hence contradiction by A1, MARGREL1:45; :: thesis: verum

end;

then (c 'imp' a) . x1 = TRUE by A3;
then A6: ('not' (c . x1)) 'or' (a . x1) = TRUE by BVFUNC_1:def 11;
A7: ( 'not' (b . x1) = TRUE or 'not' (b . x1) = FALSE ) by XBOOLEAN:def 3;

now

assume ex x being Element of Y st
( x in EqClass (z,(CompF (PA,G))) & not (b 'imp' c) . x = TRUE ) ; :: thesis: contradiction
then (B_INF ((b 'imp' c),(CompF (PA,G)))) . z = FALSE by BVFUNC_1:def 19;
then (All ((b 'imp' c),PA,G)) . z = FALSE by BVFUNC_2:def 9;
hence contradiction by A2, MARGREL1:45; :: thesis: verum

end;

then (b 'imp' c) . x1 = TRUE by A3;
then A8: ('not' (b . x1)) 'or' (c . x1) = TRUE by BVFUNC_1:def 11;

per cases ( ( 'not' (c . x1) = TRUE & 'not' (b . x1) = TRUE ) or ( 'not' (c . x1) = TRUE & c . x1 = TRUE ) or ( a . x1 = TRUE & 'not' (b . x1) = TRUE ) or ( a . x1 = TRUE & c . x1 = TRUE ) ) by A6, A5, A8, A7, BINARITH:7;

suppose ( 'not' (c . x1) = TRUE & 'not' (b . x1) = TRUE ) ; :: thesis: (Ex ((a '&' b),PA,G)) . z = TRUE

hence (Ex ((a '&' b),PA,G)) . z = TRUE by A4, MARGREL1:41; :: thesis: verum

end;

suppose ( 'not' (c . x1) = TRUE & c . x1 = TRUE ) ; :: thesis: (Ex ((a '&' b),PA,G)) . z = TRUE

hence (Ex ((a '&' b),PA,G)) . z = TRUE by MARGREL1:41; :: thesis: verum

end;

suppose ( a . x1 = TRUE & 'not' (b . x1) = TRUE ) ; :: thesis: (Ex ((a '&' b),PA,G)) . z = TRUE

hence (Ex ((a '&' b),PA,G)) . z = TRUE by A4, MARGREL1:41; :: thesis: verum

end;

suppose ( a . x1 = TRUE & c . x1 = TRUE ) ; :: thesis: (Ex ((a '&' b),PA,G)) . z = TRUE

then (a '&' b) . x1 = TRUE '&' TRUE by A4, MARGREL1:def 21
.= TRUE ;
then (B_SUP ((a '&' b),(CompF (PA,G)))) . z = TRUE by A3, BVFUNC_1:def 20;
hence (Ex ((a '&' b),PA,G)) . z = TRUE by BVFUNC_2:def 10; :: thesis: verum

end;

end;