defpred S₁[ set ] means ( W is Chain of W & ( for p being FinSequence of NAT st p in W holds
ProperPrefixes p c= W ) );
consider X being set such that
A1: for Y being set holds
( Y in X iff ( Y in bool W & S₁[Y] ) ) from XBOOLE_0:sch 1();
( {} is Chain of W & ( for p being FinSequence of NAT st p in {} holds
ProperPrefixes p c= {} ) ) by Th21;
then A3: X <> {} by A1;

now

let Z be set ; :: thesis: ( Z <> {} & Z c= X & Z is c=-linear implies union Z in X )
assume that
Z <> {} and
A5: Z c= X and
A6: Z is c=-linear ; :: thesis: union Z in X
union Z c= W

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in union Z or x in W )
assume x in union Z ; :: thesis: x in W
then consider Y being set such that
A9: x in Y and
A10: Y in Z by TARSKI:def 4;
Y in bool W by A1, A5, A10;
hence x in W by A9; :: thesis: verum

end;

then reconsider Z9 = union Z as Subset of W ;
A12: Z9 is Chain of W

proof

let p be FinSequence of NAT ; :: according to TREES_2:def 3 :: thesis: for q being FinSequence of NAT st p in Z9 & q in Z9 holds
p,q are_c=-comparable
let q be FinSequence of NAT ; :: thesis: ( p in Z9 & q in Z9 implies p,q are_c=-comparable )
assume p in Z9 ; :: thesis: ( not q in Z9 or p,q are_c=-comparable )
then consider X1 being set such that
A14: p in X1 and
A15: X1 in Z by TARSKI:def 4;
assume q in Z9 ; :: thesis: p,q are_c=-comparable
then consider X2 being set such that
A17: q in X2 and
A18: X2 in Z by TARSKI:def 4;
X1,X2 are_c=-comparable by A6, A15, A18, ORDINAL1:def 9;
then A20: ( X1 c= X2 or X2 c= X1 ) by XBOOLE_0:def 9;
A21: X1 is Chain of W by A1, A5, A15;
X2 is Chain of W by A1, A5, A18;
hence p,q are_c=-comparable by A14, A17, A20, A21, Def3; :: thesis: verum

end;

now

let p be FinSequence of NAT ; :: thesis: ( p in union Z implies ProperPrefixes p c= union Z )
assume p in union Z ; :: thesis: ProperPrefixes p c= union Z
then consider X1 being set such that
A25: ( p in X1 & X1 in Z ) by TARSKI:def 4;
( ProperPrefixes p c= X1 & X1 c= union Z ) by A1, A5, A25, ZFMISC_1:92;
hence ProperPrefixes p c= union Z by XBOOLE_1:1; :: thesis: verum

end;

hence union Z in X by A1, A12; :: thesis: verum

end;

then consider Y being set such that
A27: Y in X and
A28: for Z being set st Z in X & Z <> Y holds
not Y c= Z by A3, ORDERS_1:177;
reconsider Y = Y as Chain of W by A1, A27;
take Y ; :: thesis: Y is Branch-like
thus for p being FinSequence of NAT st p in Y holds
ProperPrefixes p c= Y by A1, A27; :: according to TREES_2:def 7 :: thesis: for p being FinSequence of NAT holds
( not p in W or ex q being FinSequence of NAT st
( q in Y & not q is_a_proper_prefix_of p ) )
given p being FinSequence of NAT such that A29: p in W and
A30: for q being FinSequence of NAT st q in Y holds
q is_a_proper_prefix_of p ; :: thesis: contradiction
set Z = (ProperPrefixes p) \/ {p};
( ProperPrefixes p c= W & {p} c= W ) by A29, TREES_1:def 5, ZFMISC_1:37;
then reconsider Z9 = (ProperPrefixes p) \/ {p} as Subset of W by XBOOLE_1:8;
A32: Z9 is Chain of W

proof

let q be FinSequence of NAT ; :: according to TREES_2:def 3 :: thesis: for q being FinSequence of NAT st q in Z9 & q in Z9 holds
q,q are_c=-comparable
let r be FinSequence of NAT ; :: thesis: ( q in Z9 & r in Z9 implies q,r are_c=-comparable )
assume that
A33: q in Z9 and
A34: r in Z9 ; :: thesis: q,r are_c=-comparable
A35: ( q in ProperPrefixes p or q in {p} ) by A33, XBOOLE_0:def 3;
A36: ( r in ProperPrefixes p or r in {p} ) by A34, XBOOLE_0:def 3;
A37: ( q is_a_proper_prefix_of p or q = p ) by A35, TARSKI:def 1, TREES_1:36;
A38: ( r is_a_proper_prefix_of p or r = p ) by A36, TARSKI:def 1, TREES_1:36;
A39: q is_a_prefix_of p by A37, XBOOLE_0:def 8;
r is_a_prefix_of p by A38, XBOOLE_0:def 8;
hence q,r are_c=-comparable by A39, Th1; :: thesis: verum

end;

now

let q be FinSequence of NAT ; :: thesis: ( q in (ProperPrefixes p) \/ {p} implies ProperPrefixes q c= (ProperPrefixes p) \/ {p} )
assume q in (ProperPrefixes p) \/ {p} ; :: thesis: ProperPrefixes q c= (ProperPrefixes p) \/ {p}
then ( q in ProperPrefixes p or q in {p} ) by XBOOLE_0:def 3;
then ( q is_a_proper_prefix_of p or q = p ) by TARSKI:def 1, TREES_1:36;
then q is_a_prefix_of p by XBOOLE_0:def 8;
then A46: ProperPrefixes q c= ProperPrefixes p by TREES_1:41;
ProperPrefixes p c= (ProperPrefixes p) \/ {p} by XBOOLE_1:7;
hence ProperPrefixes q c= (ProperPrefixes p) \/ {p} by A46, XBOOLE_1:1; :: thesis: verum

end;

then A48: (ProperPrefixes p) \/ {p} in X by A1, A32;
A49: p in {p} by TARSKI:def 1;
A50: not p in Y by A30;
A51: p in (ProperPrefixes p) \/ {p} by A49, XBOOLE_0:def 3;
Y c= (ProperPrefixes p) \/ {p}

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in Y or x in (ProperPrefixes p) \/ {p} )
assume A53: x in Y ; :: thesis: x in (ProperPrefixes p) \/ {p}
then reconsider t = x as Element of W ;
t is_a_proper_prefix_of p by A30, A53;
then t in ProperPrefixes p by TREES_1:36;
hence x in (ProperPrefixes p) \/ {p} by XBOOLE_0:def 3; :: thesis: verum

end;

hence contradiction by A28, A48, A50, A51; :: thesis: verum