reconsider C = (y>=0-plane \ y=0-line ) /\ (product <*RAT ,RAT *>) as dense Subset of Niemytzki-plane by Th40;
set T = Niemytzki-plane ;
defpred S₁[ set , set ] means ex U, V being open Subset of Niemytzki-plane st
( $2 = U /\ C & $1 c= U & y=0-line \ $1 c= V & U misses V );
A1: exp 2,omega in exp 2,(exp 2,omega ) by CARD_5:23;
card C c= card (product <*RAT ,RAT *>) by CARD_1:27, XBOOLE_1:17;
then card C c= omega by Th12, CARD_4:54, TOPGEN_3:17;
then A2: exp 2,(card C) c= exp 2,omega by CARD_3:139;
assume A3: for W, V being Subset of Niemytzki-plane st W <> {} & V <> {} & W is closed & V is closed & W misses V holds
ex P, Q being Subset of Niemytzki-plane st
( P is open & Q is open & W c= P & V c= Q & P misses Q ) ; :: according to COMPTS_1:def 6 :: thesis: contradiction
A4: for a being set st a in bool y=0-line holds
ex b being set st S₁[a,b]

proof

let a be set ; :: thesis: ( a in bool y=0-line implies ex b being set st S₁[a,b] )
assume a in bool y=0-line ; :: thesis: ex b being set st S₁[a,b]
then reconsider aa = a, a9 = y=0-line \ a as Subset of y=0-line by XBOOLE_1:36;
reconsider A = aa, B = a9 as closed Subset of Niemytzki-plane by Th46;

per cases ( a = {} or a = y=0-line or ( a <> {} & a <> y=0-line ) ) ;

suppose A5: a = {} ; :: thesis: ex b being set st S₁[a,b]

take b = {} ; :: thesis: S₁[a,b]
take U = {} Niemytzki-plane ; :: thesis: ex V being open Subset of Niemytzki-plane st
( b = U /\ C & a c= U & y=0-line \ a c= V & U misses V )
take V = [#] Niemytzki-plane ; :: thesis: ( b = U /\ C & a c= U & y=0-line \ a c= V & U misses V )
thus ( b = U /\ C & a c= U & y=0-line \ a c= V & U misses V ) by A5, Def3, Th23, XBOOLE_1:65; :: thesis: verum

end;

suppose A6: a = y=0-line ; :: thesis: ex b being set st S₁[a,b]

take b = ([#] Niemytzki-plane ) /\ C; :: thesis: S₁[a,b]
take U = [#] Niemytzki-plane ; :: thesis: ex V being open Subset of Niemytzki-plane st
( b = U /\ C & a c= U & y=0-line \ a c= V & U misses V )
take V = {} Niemytzki-plane ; :: thesis: ( b = U /\ C & a c= U & y=0-line \ a c= V & U misses V )
thus ( b = U /\ C & a c= U & y=0-line \ a c= V & U misses V ) by A6, Def3, Th23, XBOOLE_1:37, XBOOLE_1:65; :: thesis: verum

end;

suppose A7: ( a <> {} & a <> y=0-line ) ; :: thesis: ex b being set st S₁[a,b]

(aa ` ) ` = a9 ` ;
then A8: B <> {} y=0-line by A7;
A misses B by XBOOLE_1:79;
then consider P, Q being Subset of Niemytzki-plane such that
A9: P is open and
A10: Q is open and
A11: A c= P and
A12: B c= Q and
A13: P misses Q by A8, A3, A7;
take b = P /\ C; :: thesis: S₁[a,b]
thus S₁[a,b] by A9, A10, A11, A12, A13; :: thesis: verum

end;

end;

end;

consider G being Function such that
A14: dom G = bool y=0-line and
A15: for a being set st a in bool y=0-line holds
S₁[a,G . a] from CLASSES1:sch 1(A4);
G is one-to-one

proof

let x, y be set ; :: according to FUNCT_1:def 8 :: thesis: ( not x in proj1 G or not y in proj1 G or not G . x = G . y or x = y )
assume that
A16: x in dom G and
A17: y in dom G ; :: thesis: ( not G . x = G . y or x = y )
reconsider A = x, B = y as Subset of y=0-line by A16, A17, A14;
assume that
A18: G . x = G . y and
A19: x <> y ; :: thesis: contradiction
consider z being set such that
A20: ( ( z in A & not z in B ) or ( z in B & not z in A ) ) by A19, TARSKI:2;
A21: ( z in A \ B or z in B \ A ) by A20, XBOOLE_0:def 5;
consider UB, VB being open Subset of Niemytzki-plane such that
A22: G . B = UB /\ C and
A23: B c= UB and
A24: y=0-line \ B c= VB and
A25: UB misses VB by A15;
consider UA, VA being open Subset of Niemytzki-plane such that
A26: G . A = UA /\ C and
A27: A c= UA and
A28: y=0-line \ A c= VA and
A29: UA misses VA by A15;
B \ A = B /\ (A ` ) by SUBSET_1:32;
then A30: B \ A c= UB /\ VA by A28, A23, XBOOLE_1:27;
A \ B = A /\ (B ` ) by SUBSET_1:32;
then A \ B c= UA /\ VB by A27, A24, XBOOLE_1:27;
then ( C meets UA /\ VB or C meets UB /\ VA ) by A30, A21, TOPS_1:80;
then ( ex z being set st
( z in C & z in UA /\ VB ) or ex z being set st
( z in C & z in UB /\ VA ) ) by XBOOLE_0:3;
then consider z being set such that
A31: z in C and
A32: ( z in UA /\ VB or z in UB /\ VA ) ;
( ( z in UA & z in VB ) or ( z in UB & z in VA ) ) by A32, XBOOLE_0:def 4;
then ( ( z in UA & not z in UB ) or ( z in UB & not z in UA ) ) by A29, A25, XBOOLE_0:3;
then ( ( z in G . A & not z in G . B ) or ( z in G . B & not z in G . A ) ) by A26, A22, A31, XBOOLE_0:def 4;
hence contradiction by A18; :: thesis: verum

end;

then A33: card (dom G) c= card (rng G) by CARD_1:26;
rng G c= bool C

proof

let a be set ; :: according to TARSKI:def 3 :: thesis: ( not a in rng G or a in bool C )
assume a in rng G ; :: thesis: a in bool C
then consider b being set such that
A34: b in dom G and
A35: a = G . b by FUNCT_1:def 5;
S₁[b,a] by A14, A15, A34, A35;
then a c= C by XBOOLE_1:17;
hence a in bool C ; :: thesis: verum

end;

then card (rng G) c= card (bool C) by CARD_1:27;
then card (bool y=0-line ) c= card (bool C) by A33, A14, XBOOLE_1:1;
then A36: exp 2,continuum c= card (bool C) by Th20, CARD_2:44;
card (bool C) = exp 2,(card C) by CARD_2:44;
then exp 2,continuum c= exp 2,omega by A36, A2, XBOOLE_1:1;
then exp 2,omega in exp 2,omega by A1, TOPGEN_3:29;
hence contradiction ; :: thesis: verum