let s be State of SCMPDS ; :: thesis: for I being parahalting Program of SCMPDS
for J being Program of SCMPDS st Initialize (stop I) c= s holds
for m being Element of NAT st m <= LifeSpan (ProgramPart s),s holds
Comput (ProgramPart s),s,m, Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m equal_outside NAT
let I be parahalting Program of SCMPDS ; :: thesis: for J being Program of SCMPDS st Initialize (stop I) c= s holds
for m being Element of NAT st m <= LifeSpan (ProgramPart s),s holds
Comput (ProgramPart s),s,m, Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m equal_outside NAT
let J be Program of SCMPDS ; :: thesis: ( Initialize (stop I) c= s implies for m being Element of NAT st m <= LifeSpan (ProgramPart s),s holds
Comput (ProgramPart s),s,m, Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m equal_outside NAT )
set SI = stop I;
defpred S₁[ Element of NAT ] means ( $1 <= LifeSpan (ProgramPart s),s implies Comput (ProgramPart s),s,$1, Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),$1 equal_outside NAT );
A1: Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),0 = s +* (I ';' J) by AMI_1:13;
assume A2: Initialize (stop I) c= s ; :: thesis: for m being Element of NAT st m <= LifeSpan (ProgramPart s),s holds
Comput (ProgramPart s),s,m, Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m equal_outside NAT
then A3: ProgramPart s halts_on s by SCMPDS_4:63;
A4: for m being Element of NAT st S₁[m] holds
S₁[m + 1]

proof

dom (I ';' J) = (dom I) \/ (dom (Shift J,(card I))) by FUNCT_4:def 1;
then A5: dom I c= dom (I ';' J) by XBOOLE_1:7;
let m be Element of NAT ; :: thesis: ( S₁[m] implies S₁[m + 1] )
assume A6: ( m <= LifeSpan (ProgramPart s),s implies Comput (ProgramPart s),s,m, Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m equal_outside NAT ) ; :: thesis: S₁[m + 1]
assume A7: m + 1 <= LifeSpan (ProgramPart s),s ; :: thesis: Comput (ProgramPart s),s,(m + 1), Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),(m + 1) equal_outside NAT
then A8: IC (Comput (ProgramPart s),s,m) = IC (Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m) by A6, COMPOS_1:24, NAT_1:13;
T: ProgramPart (s +* (I ';' J)) = ProgramPart (Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m) by AMI_1:123;
A9: Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),(m + 1) = Following (ProgramPart (s +* (I ';' J))),(Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m) by AMI_1:14
.= Exec (CurInstr (ProgramPart (Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m)),(Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m)),(Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m) by T ;
T: ProgramPart s = ProgramPart (Comput (ProgramPart s),s,m) by AMI_1:123;
A10: Comput (ProgramPart s),s,(m + 1) = Following (ProgramPart s),(Comput (ProgramPart s),s,m) by AMI_1:14
.= Exec (CurInstr (ProgramPart (Comput (ProgramPart s),s,m)),(Comput (ProgramPart s),s,m)),(Comput (ProgramPart s),s,m) by T ;
A11: I ';' J c= Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m by AMI_1:81, FUNCT_4:26;
A12: IC (Comput (ProgramPart s),s,m) in dom (stop I) by A2, SCMPDS_4:def 9;
Y: (ProgramPart (Comput (ProgramPart s),s,m)) /. (IC (Comput (ProgramPart s),s,m)) = (Comput (ProgramPart s),s,m) . (IC (Comput (ProgramPart s),s,m)) by COMPOS_1:38;
TX: ProgramPart s = ProgramPart (Comput (ProgramPart s),s,m) by AMI_1:123;
dom (stop I) misses dom (Start-At 0 ,SCMPDS ) by SCMPDS_4:54;
then stop I c= (stop I) +* (Start-At 0 ,SCMPDS ) by FUNCT_4:33;
then stop I c= s by A2, XBOOLE_1:1;
then stop I c= Comput (ProgramPart s),s,m by AMI_1:81;
then A13: CurInstr (ProgramPart s),(Comput (ProgramPart s),s,m) = (stop I) . (IC (Comput (ProgramPart s),s,m)) by A12, Y, TX, GRFUNC_1:8;
Y: (ProgramPart (Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m)) /. (IC (Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m)) = (Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m) . (IC (Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m)) by COMPOS_1:38;
m < LifeSpan (ProgramPart s),s by A7, NAT_1:13;
then (stop I) . (IC (Comput (ProgramPart s),s,m)) <> halt SCMPDS by A3, A13, AMI_1:def 46;
then A14: IC (Comput (ProgramPart s),s,m) in dom I by A12, Th3;
then CurInstr (ProgramPart (Comput (ProgramPart s),s,m)),(Comput (ProgramPart s),s,m) = I . (IC (Comput (ProgramPart s),s,m)) by A13, TX, SCMPDS_4:37
.= (I ';' J) . (IC (Comput (ProgramPart s),s,m)) by A14, SCMPDS_4:37
.= CurInstr (ProgramPart (Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m)),(Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),m) by A8, A11, A14, A5, Y, GRFUNC_1:8 ;
hence Comput (ProgramPart s),s,(m + 1), Comput (ProgramPart (s +* (I ';' J))),(s +* (I ';' J)),(m + 1) equal_outside NAT by A6, A7, A10, A9, NAT_1:13, SCMPDS_4:15; :: thesis: verum

end;

Comput (ProgramPart s),s,0 = s by AMI_1:13;
then A15: S₁[ 0 ] by A1, FUNCT_7:132;
thus for m being Element of NAT holds S₁[m] from NAT_1:sch 1(A15, A4); :: thesis: verum