set g = multreal ;
set h = multcomplex ;
let F be FinSequence of REAL ; :: thesis: Product F = multreal $$ F
rng F c= COMPLEX by NUMBERS:11, XBOOLE_1:1;
then reconsider f = F as FinSequence of COMPLEX by FINSEQ_1:def 4;
defpred S₁[ Nat] means multreal $$ (finSeg $1),([#] F,(the_unity_wrt multreal )) = multcomplex $$ (finSeg $1),([#] f,(the_unity_wrt multcomplex ));
consider n being Nat such that
A1: dom f = Seg n by FINSEQ_1:def 2;
A2: ( multreal $$ F = multreal $$ (finSeg n),([#] F,(the_unity_wrt multreal )) & multcomplex $$ f = multcomplex $$ (finSeg n),([#] f,(the_unity_wrt multcomplex )) ) by A1, SETWOP_2:def 2;
A3: for k being Nat st S₁[k] holds
S₁[k + 1]

proof

set j = [#] f,(the_unity_wrt multcomplex );
set i = [#] F,(the_unity_wrt multreal );
let k be Nat; :: thesis: ( S₁[k] implies S₁[k + 1] )
assume A4: S₁[k] ; :: thesis: S₁[k + 1]
A5: ([#] F,(the_unity_wrt multreal )) . (k + 1) = ([#] f,(the_unity_wrt multcomplex )) . (k + 1)

proof

per cases ( k + 1 in dom f or not k + 1 in dom f ) ;

suppose A6: k + 1 in dom f ; :: thesis: ([#] F,(the_unity_wrt multreal )) . (k + 1) = ([#] f,(the_unity_wrt multcomplex )) . (k + 1)

then ([#] f,(the_unity_wrt multcomplex )) . (k + 1) = F . (k + 1) by SETWOP_2:22
.= ([#] F,(the_unity_wrt multreal )) . (k + 1) by A6, SETWOP_2:22 ;
hence ([#] F,(the_unity_wrt multreal )) . (k + 1) = ([#] f,(the_unity_wrt multcomplex )) . (k + 1) ; :: thesis: verum

end;

suppose A7: not k + 1 in dom f ; :: thesis: ([#] F,(the_unity_wrt multreal )) . (k + 1) = ([#] f,(the_unity_wrt multcomplex )) . (k + 1)

then ([#] f,(the_unity_wrt multcomplex )) . (k + 1) = the_unity_wrt multcomplex by SETWOP_2:22
.= ([#] F,(the_unity_wrt multreal )) . (k + 1) by A7, BINOP_2:6, BINOP_2:7, SETWOP_2:22 ;
hence ([#] F,(the_unity_wrt multreal )) . (k + 1) = ([#] f,(the_unity_wrt multcomplex )) . (k + 1) ; :: thesis: verum

end;

end;

end;

A8: not k + 1 in Seg k by FINSEQ_3:9;
reconsider k = k as Element of NAT by ORDINAL1:def 13;
multreal $$ (finSeg (k + 1)),([#] F,(the_unity_wrt multreal )) = multreal $$ ((finSeg k) \/ {.(k + 1).}),([#] F,(the_unity_wrt multreal )) by FINSEQ_1:11
.= multreal . (multreal $$ (finSeg k),([#] F,(the_unity_wrt multreal ))),(([#] F,(the_unity_wrt multreal )) . (k + 1)) by A8, SETWOP_2:4
.= (multreal $$ (finSeg k),([#] F,(the_unity_wrt multreal ))) * (([#] F,(the_unity_wrt multreal )) . (k + 1)) by BINOP_2:def 11
.= multcomplex . (multcomplex $$ (finSeg k),([#] f,(the_unity_wrt multcomplex ))),(([#] f,(the_unity_wrt multcomplex )) . (k + 1)) by A4, A5, BINOP_2:def 5
.= multcomplex $$ ((finSeg k) \/ {.(k + 1).}),([#] f,(the_unity_wrt multcomplex )) by A8, SETWOP_2:4
.= multcomplex $$ (finSeg (k + 1)),([#] f,(the_unity_wrt multcomplex )) by FINSEQ_1:11 ;
hence S₁[k + 1] ; :: thesis: verum

end;

A9: Seg 0 = {}. NAT ;
then multreal $$ (finSeg 0 ),([#] F,(the_unity_wrt multreal )) = the_unity_wrt multcomplex by BINOP_2:6, BINOP_2:7, SETWISEO:40
.= multcomplex $$ (finSeg 0 ),([#] f,(the_unity_wrt multcomplex )) by A9, SETWISEO:40 ;
then A10: S₁[ 0 ] ;
for k being Nat holds S₁[k] from NAT_1:sch 2(A10, A3);
then multreal $$ F = multcomplex $$ f by A2;
hence Product F = multreal $$ F by Def14; :: thesis: verum