let vseq be sequence of l1_Space ; :: thesis: ( vseq is CCauchy implies vseq is convergent )
assume A1: vseq is CCauchy ; :: thesis: vseq is convergent
defpred S₁[ set , set ] means ex i being Element of NAT st
( $1 = i & ex rseqi being Real_Sequence st
( ( for n being Element of NAT holds rseqi . n = (seq_id (vseq . n)) . i ) & rseqi is convergent & $2 = lim rseqi ) );
A2: for x being set st x in NAT holds
ex y being set st
( y in REAL & S₁[x,y] )

proof

let x be set ; :: thesis: ( x in NAT implies ex y being set st
( y in REAL & S₁[x,y] ) )
assume x in NAT ; :: thesis: ex y being set st
( y in REAL & S₁[x,y] )
then reconsider i = x as Element of NAT ;
deffunc H₁( Element of NAT ) -> Element of REAL = (seq_id (vseq . $1)) . i;
consider rseqi being Real_Sequence such that
A3: for n being Element of NAT holds rseqi . n = H₁(n) from SEQ_1:sch 1();
take y = lim rseqi; :: thesis: ( y in REAL & S₁[x,y] )

now

let e be real number ; :: thesis: ( e > 0 implies ex k being Element of NAT st
for m being Element of NAT st k <= m holds
abs ((rseqi . m) - (rseqi . k)) < e )
assume A4: e > 0 ; :: thesis: ex k being Element of NAT st
for m being Element of NAT st k <= m holds
abs ((rseqi . m) - (rseqi . k)) < e
thus ex k being Element of NAT st
for m being Element of NAT st k <= m holds
abs ((rseqi . m) - (rseqi . k)) < e :: thesis: verum

proof

e is Real by XREAL_0:def 1;
then consider k being Element of NAT such that
A5: for n, m being Element of NAT st n >= k & m >= k holds
||.((vseq . n) - (vseq . m)).|| < e by A1, A4, Th10;
for m being Element of NAT st k <= m holds
abs ((rseqi . m) - (rseqi . k)) < e

proof

let m be Element of NAT ; :: thesis: ( k <= m implies abs ((rseqi . m) - (rseqi . k)) < e )
assume A6: k <= m ; :: thesis: abs ((rseqi . m) - (rseqi . k)) < e
A7: for i being Element of NAT holds 0 <= (abs (seq_id ((vseq . m) - (vseq . k)))) . i

proof

let i be Element of NAT ; :: thesis: 0 <= (abs (seq_id ((vseq . m) - (vseq . k)))) . i
0 <= abs ((seq_id ((vseq . m) - (vseq . k))) . i) by COMPLEX1:132;
hence 0 <= (abs (seq_id ((vseq . m) - (vseq . k)))) . i by SEQ_1:16; :: thesis: verum

end;

seq_id ((vseq . m) - (vseq . k)) is absolutely_summable by Def1;
then abs (seq_id ((vseq . m) - (vseq . k))) is summable by SERIES_1:def 5;
then A8: (abs (seq_id ((vseq . m) - (vseq . k)))) . i <= Sum (abs (seq_id ((vseq . m) - (vseq . k)))) by A7, RSSPACE2:4;
seq_id ((vseq . m) - (vseq . k)) = seq_id ((seq_id (vseq . m)) - (seq_id (vseq . k))) by Th8
.= (seq_id (vseq . m)) - (seq_id (vseq . k)) by RSSPACE:3
.= (seq_id (vseq . m)) + (- (seq_id (vseq . k))) by SEQ_1:15 ;
then (seq_id ((vseq . m) - (vseq . k))) . i = ((seq_id (vseq . m)) . i) + ((- (seq_id (vseq . k))) . i) by SEQ_1:11
.= ((seq_id (vseq . m)) . i) + (- ((seq_id (vseq . k)) . i)) by SEQ_1:14
.= ((seq_id (vseq . m)) . i) - ((seq_id (vseq . k)) . i)
.= (rseqi . m) - ((seq_id (vseq . k)) . i) by A3
.= (rseqi . m) - (rseqi . k) by A3 ;
then A9: abs ((rseqi . m) - (rseqi . k)) = (abs (seq_id ((vseq . m) - (vseq . k)))) . i by SEQ_1:16;
||.((vseq . m) - (vseq . k)).|| = Sum (abs (seq_id ((vseq . m) - (vseq . k)))) by Th8;
then Sum (abs (seq_id ((vseq . m) - (vseq . k)))) < e by A5, A6;
hence abs ((rseqi . m) - (rseqi . k)) < e by A8, A9, XXREAL_0:2; :: thesis: verum

end;

hence ex k being Element of NAT st
for m being Element of NAT st k <= m holds
abs ((rseqi . m) - (rseqi . k)) < e ; :: thesis: verum

end;

end;

then rseqi is convergent by SEQ_4:58;
hence ( y in REAL & S₁[x,y] ) by A3; :: thesis: verum

end;

consider f being Function of NAT ,REAL such that
A10: for x being set st x in NAT holds
S₁[x,f . x] from FUNCT_2:sch 1(A2);
reconsider tseq = f as Real_Sequence ;

A11: now

let i be Element of NAT ; :: thesis: ex rseqi being Real_Sequence st
( ( for n being Element of NAT holds rseqi . n = (seq_id (vseq . n)) . i ) & rseqi is convergent & tseq . i = lim rseqi )
reconsider x = i as set ;
ex i0 being Element of NAT st
( x = i0 & ex rseqi being Real_Sequence st
( ( for n being Element of NAT holds rseqi . n = (seq_id (vseq . n)) . i0 ) & rseqi is convergent & f . x = lim rseqi ) ) by A10;
hence ex rseqi being Real_Sequence st
( ( for n being Element of NAT holds rseqi . n = (seq_id (vseq . n)) . i ) & rseqi is convergent & tseq . i = lim rseqi ) ; :: thesis: verum

end;

A12: for e being Real st e > 0 holds
ex k being Element of NAT st
for n being Element of NAT st n >= k holds
( abs ((seq_id tseq) - (seq_id (vseq . n))) is summable & Sum (abs ((seq_id tseq) - (seq_id (vseq . n)))) < e )

proof

let e1 be Real; :: thesis: ( e1 > 0 implies ex k being Element of NAT st
for n being Element of NAT st n >= k holds
( abs ((seq_id tseq) - (seq_id (vseq . n))) is summable & Sum (abs ((seq_id tseq) - (seq_id (vseq . n)))) < e1 ) )
assume A13: e1 > 0 ; :: thesis: ex k being Element of NAT st
for n being Element of NAT st n >= k holds
( abs ((seq_id tseq) - (seq_id (vseq . n))) is summable & Sum (abs ((seq_id tseq) - (seq_id (vseq . n)))) < e1 )
set e = e1 / 2;
A14: e1 / 2 < e1 by A13, XREAL_1:218;
e1 / 2 > 0 by A13, XREAL_1:217;
then consider k being Element of NAT such that
A15: for n, m being Element of NAT st n >= k & m >= k holds
||.((vseq . n) - (vseq . m)).|| < e1 / 2 by A1, Th10;
A16: for m, n being Element of NAT st n >= k & m >= k holds
( abs (seq_id ((vseq . n) - (vseq . m))) is summable & Sum (abs (seq_id ((vseq . n) - (vseq . m)))) < e1 / 2 & ( for i being Element of NAT holds 0 <= (abs (seq_id ((vseq . n) - (vseq . m)))) . i ) )

proof

let m, n be Element of NAT ; :: thesis: ( n >= k & m >= k implies ( abs (seq_id ((vseq . n) - (vseq . m))) is summable & Sum (abs (seq_id ((vseq . n) - (vseq . m)))) < e1 / 2 & ( for i being Element of NAT holds 0 <= (abs (seq_id ((vseq . n) - (vseq . m)))) . i ) ) )
assume ( n >= k & m >= k ) ; :: thesis: ( abs (seq_id ((vseq . n) - (vseq . m))) is summable & Sum (abs (seq_id ((vseq . n) - (vseq . m)))) < e1 / 2 & ( for i being Element of NAT holds 0 <= (abs (seq_id ((vseq . n) - (vseq . m)))) . i ) )
then ||.((vseq . n) - (vseq . m)).|| < e1 / 2 by A15;
then A17: the normF of l1_Space . ((vseq . n) - (vseq . m)) < e1 / 2 ;
A18: for i being Element of NAT holds 0 <= (abs (seq_id ((vseq . n) - (vseq . m)))) . i

proof

let i be Element of NAT ; :: thesis: 0 <= (abs (seq_id ((vseq . n) - (vseq . m)))) . i
0 <= abs ((seq_id ((vseq . n) - (vseq . m))) . i) by COMPLEX1:132;
hence 0 <= (abs (seq_id ((vseq . n) - (vseq . m)))) . i by SEQ_1:16; :: thesis: verum

end;

seq_id ((vseq . n) - (vseq . m)) is absolutely_summable by Def1;
hence ( abs (seq_id ((vseq . n) - (vseq . m))) is summable & Sum (abs (seq_id ((vseq . n) - (vseq . m)))) < e1 / 2 & ( for i being Element of NAT holds 0 <= (abs (seq_id ((vseq . n) - (vseq . m)))) . i ) ) by A17, A18, Def2, SERIES_1:def 5; :: thesis: verum

end;

A19: for n, i being Element of NAT
for rseq being Real_Sequence st ( for m being Element of NAT holds rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . i ) holds
( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i )

proof

let n be Element of NAT ; :: thesis: for i being Element of NAT
for rseq being Real_Sequence st ( for m being Element of NAT holds rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . i ) holds
( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i )
defpred S₂[ Element of NAT ] means for rseq being Real_Sequence st ( for m being Element of NAT holds rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . $1 ) holds
( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . $1 );
A20: for m, k being Element of NAT holds seq_id ((vseq . m) - (vseq . k)) = (seq_id (vseq . m)) - (seq_id (vseq . k))

proof

let m, k be Element of NAT ; :: thesis: seq_id ((vseq . m) - (vseq . k)) = (seq_id (vseq . m)) - (seq_id (vseq . k))
seq_id ((vseq . m) - (vseq . k)) = seq_id ((seq_id (vseq . m)) - (seq_id (vseq . k))) by Th8;
hence seq_id ((vseq . m) - (vseq . k)) = (seq_id (vseq . m)) - (seq_id (vseq . k)) by RSSPACE:3; :: thesis: verum

end;

now

let i be Element of NAT ; :: thesis: ( ( for rseq being Real_Sequence st ( for m being Element of NAT holds rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . i ) holds
( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i ) ) implies for rseq being Real_Sequence st ( for m being Element of NAT holds rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . (i + 1) ) holds
( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . (i + 1) ) )
assume A21: for rseq being Real_Sequence st ( for m being Element of NAT holds rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . i ) holds
( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i ) ; :: thesis: for rseq being Real_Sequence st ( for m being Element of NAT holds rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . (i + 1) ) holds
( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . (i + 1) )
thus for rseq being Real_Sequence st ( for m being Element of NAT holds rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . (i + 1) ) holds
( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . (i + 1) ) :: thesis: verum

proof

deffunc H₁( Element of NAT ) -> Element of REAL = (Partial_Sums (abs (seq_id ((vseq . $1) - (vseq . n))))) . i;
consider rseqb being Real_Sequence such that
A22: for m being Element of NAT holds rseqb . m = H₁(m) from SEQ_1:sch 1();
consider rseq0 being Real_Sequence such that
A23: for m being Element of NAT holds rseq0 . m = (seq_id (vseq . m)) . (i + 1) and
A24: rseq0 is convergent and
A25: tseq . (i + 1) = lim rseq0 by A11;
let rseq be Real_Sequence; :: thesis: ( ( for m being Element of NAT holds rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . (i + 1) ) implies ( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . (i + 1) ) )
assume A26: for m being Element of NAT holds rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . (i + 1) ; :: thesis: ( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . (i + 1) )

A27: now

let m be Element of NAT ; :: thesis: rseq . m = (abs ((rseq0 . m) - ((seq_id (vseq . n)) . (i + 1)))) + (rseqb . m)
thus rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . (i + 1) by A26
.= ((abs (seq_id ((vseq . m) - (vseq . n)))) . (i + 1)) + ((Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . i) by SERIES_1:def 1
.= ((abs ((seq_id (vseq . m)) - (seq_id (vseq . n)))) . (i + 1)) + ((Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . i) by A20
.= ((abs ((seq_id (vseq . m)) - (seq_id (vseq . n)))) . (i + 1)) + (rseqb . m) by A22
.= (abs (((seq_id (vseq . m)) - (seq_id (vseq . n))) . (i + 1))) + (rseqb . m) by SEQ_1:16
.= (abs (((seq_id (vseq . m)) + (- (seq_id (vseq . n)))) . (i + 1))) + (rseqb . m) by SEQ_1:15
.= (abs (((seq_id (vseq . m)) . (i + 1)) + ((- (seq_id (vseq . n))) . (i + 1)))) + (rseqb . m) by SEQ_1:11
.= (abs (((seq_id (vseq . m)) . (i + 1)) + (- ((seq_id (vseq . n)) . (i + 1))))) + (rseqb . m) by SEQ_1:14
.= (abs (((seq_id (vseq . m)) . (i + 1)) - ((seq_id (vseq . n)) . (i + 1)))) + (rseqb . m)
.= (abs ((rseq0 . m) - ((seq_id (vseq . n)) . (i + 1)))) + (rseqb . m) by A23 ; :: thesis: verum

end;

A28: rseqb is convergent by A21, A22;
then lim rseq = (abs ((lim rseq0) - ((seq_id (vseq . n)) . (i + 1)))) + (lim rseqb) by A24, A27, Lm4
.= (abs ((tseq . (i + 1)) + (- ((seq_id (vseq . n)) . (i + 1))))) + (lim rseqb) by A25
.= (abs ((tseq . (i + 1)) + ((- (seq_id (vseq . n))) . (i + 1)))) + (lim rseqb) by SEQ_1:14
.= (abs ((tseq + (- (seq_id (vseq . n)))) . (i + 1))) + (lim rseqb) by SEQ_1:11
.= (abs ((tseq - (seq_id (vseq . n))) . (i + 1))) + (lim rseqb) by SEQ_1:15
.= ((abs (tseq - (seq_id (vseq . n)))) . (i + 1)) + (lim rseqb) by SEQ_1:16
.= ((abs (tseq - (seq_id (vseq . n)))) . (i + 1)) + ((Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i) by A21, A22
.= ((abs ((seq_id tseq) - (seq_id (vseq . n)))) . (i + 1)) + ((Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i) by RSSPACE:3
.= (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . (i + 1) by SERIES_1:def 1 ;
hence ( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . (i + 1) ) by A28, A24, A27, Lm4; :: thesis: verum

end;

end;

then A29: for i being Element of NAT st S₂[i] holds
S₂[i + 1] ;

now

let rseq be Real_Sequence; :: thesis: ( ( for m being Element of NAT holds rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . 0 ) implies ( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . 0 ) )
assume A30: for m being Element of NAT holds rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . 0 ; :: thesis: ( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . 0 )
thus ( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . 0 ) :: thesis: verum

proof

consider rseq0 being Real_Sequence such that
A31: for m being Element of NAT holds rseq0 . m = (seq_id (vseq . m)) . 0 and
A32: rseq0 is convergent and
A33: tseq . 0 = lim rseq0 by A11;
A34: for m being Element of NAT holds rseq . m = abs ((rseq0 . m) - ((seq_id (vseq . n)) . 0 ))

proof

let m be Element of NAT ; :: thesis: rseq . m = abs ((rseq0 . m) - ((seq_id (vseq . n)) . 0 ))
rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . 0 by A30
.= (abs (seq_id ((vseq . m) - (vseq . n)))) . 0 by SERIES_1:def 1
.= (abs ((seq_id (vseq . m)) - (seq_id (vseq . n)))) . 0 by A20
.= (abs ((seq_id (vseq . m)) + (- (seq_id (vseq . n))))) . 0 by SEQ_1:15
.= abs (((seq_id (vseq . m)) + (- (seq_id (vseq . n)))) . 0 ) by SEQ_1:16
.= abs (((seq_id (vseq . m)) . 0 ) + ((- (seq_id (vseq . n))) . 0 )) by SEQ_1:11
.= abs (((seq_id (vseq . m)) . 0 ) + (- ((seq_id (vseq . n)) . 0 ))) by SEQ_1:14
.= abs (((seq_id (vseq . m)) . 0 ) - ((seq_id (vseq . n)) . 0 )) ;
hence rseq . m = abs ((rseq0 . m) - ((seq_id (vseq . n)) . 0 )) by A31; :: thesis: verum

end;

then lim rseq = abs ((lim rseq0) - ((seq_id (vseq . n)) . 0 )) by A32, Th1
.= abs ((tseq . 0 ) + (- ((seq_id (vseq . n)) . 0 ))) by A33
.= abs ((tseq . 0 ) + ((- (seq_id (vseq . n))) . 0 )) by SEQ_1:14
.= abs ((tseq + (- (seq_id (vseq . n)))) . 0 ) by SEQ_1:11
.= abs ((tseq - (seq_id (vseq . n))) . 0 ) by SEQ_1:15
.= abs (((seq_id tseq) - (seq_id (vseq . n))) . 0 ) by RSSPACE:3
.= (abs ((seq_id tseq) - (seq_id (vseq . n)))) . 0 by SEQ_1:16
.= (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . 0 by SERIES_1:def 1 ;
hence ( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . 0 ) by A32, A34, Th1; :: thesis: verum

end;

end;

then A35: S₂[ 0 ] ;
for i being Element of NAT holds S₂[i] from NAT_1:sch 1(A35, A29);
hence for i being Element of NAT
for rseq being Real_Sequence st ( for m being Element of NAT holds rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . i ) holds
( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i ) ; :: thesis: verum

end;

for n being Element of NAT st n >= k holds
( abs ((seq_id tseq) - (seq_id (vseq . n))) is summable & Sum (abs ((seq_id tseq) - (seq_id (vseq . n)))) < e1 )

proof

let n be Element of NAT ; :: thesis: ( n >= k implies ( abs ((seq_id tseq) - (seq_id (vseq . n))) is summable & Sum (abs ((seq_id tseq) - (seq_id (vseq . n)))) < e1 ) )
assume A36: n >= k ; :: thesis: ( abs ((seq_id tseq) - (seq_id (vseq . n))) is summable & Sum (abs ((seq_id tseq) - (seq_id (vseq . n)))) < e1 )
A37: for i being Element of NAT st 0 <= i holds
(Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i <= e1 / 2

proof

let i be Element of NAT ; :: thesis: ( 0 <= i implies (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i <= e1 / 2 )
assume 0 <= i ; :: thesis: (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i <= e1 / 2
deffunc H₁( Element of NAT ) -> Element of REAL = (Partial_Sums (abs (seq_id ((vseq . $1) - (vseq . n))))) . i;
consider rseq being Real_Sequence such that
A38: for m being Element of NAT holds rseq . m = H₁(m) from SEQ_1:sch 1();
A39: for m being Element of NAT st m >= k holds
rseq . m <= e1 / 2

proof

let m be Element of NAT ; :: thesis: ( m >= k implies rseq . m <= e1 / 2 )
A40: rseq . m = (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . i by A38;
assume A41: m >= k ; :: thesis: rseq . m <= e1 / 2
then ( abs (seq_id ((vseq . m) - (vseq . n))) is summable & ( for i being Element of NAT holds 0 <= (abs (seq_id ((vseq . m) - (vseq . n)))) . i ) ) by A16, A36;
then A42: (Partial_Sums (abs (seq_id ((vseq . m) - (vseq . n))))) . i <= Sum (abs (seq_id ((vseq . m) - (vseq . n)))) by RSSPACE2:4;
Sum (abs (seq_id ((vseq . m) - (vseq . n)))) < e1 / 2 by A16, A36, A41;
hence rseq . m <= e1 / 2 by A42, A40, XXREAL_0:2; :: thesis: verum

end;

( rseq is convergent & lim rseq = (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i ) by A19, A38;
hence (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i <= e1 / 2 by A39, RSSPACE2:6; :: thesis: verum

end;

now

take e1 = e1; :: thesis: for i being Element of NAT holds (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i < e1
let i be Element of NAT ; :: thesis: (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i < e1
(Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i <= e1 / 2 by A37, NAT_1:2;
hence (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) . i < e1 by A14, XXREAL_0:2; :: thesis: verum

end;

then A43: Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n)))) is bounded_above by SEQ_2:def 3;
A44: for i being Element of NAT holds 0 <= (abs ((seq_id tseq) - (seq_id (vseq . n)))) . i

proof

let i be Element of NAT ; :: thesis: 0 <= (abs ((seq_id tseq) - (seq_id (vseq . n)))) . i
(abs ((seq_id tseq) - (seq_id (vseq . n)))) . i = abs (((seq_id tseq) - (seq_id (vseq . n))) . i) by SEQ_1:16;
hence 0 <= (abs ((seq_id tseq) - (seq_id (vseq . n)))) . i by COMPLEX1:132; :: thesis: verum

end;

then abs ((seq_id tseq) - (seq_id (vseq . n))) is summable by A43, SERIES_1:20;
then Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n)))) is convergent by SERIES_1:def 2;
then ( Sum (abs ((seq_id tseq) - (seq_id (vseq . n)))) = lim (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) & lim (Partial_Sums (abs ((seq_id tseq) - (seq_id (vseq . n))))) <= e1 / 2 ) by A37, RSSPACE2:6, SERIES_1:def 3;
hence ( abs ((seq_id tseq) - (seq_id (vseq . n))) is summable & Sum (abs ((seq_id tseq) - (seq_id (vseq . n)))) < e1 ) by A14, A44, A43, SERIES_1:20, XXREAL_0:2; :: thesis: verum

end;

hence ex k being Element of NAT st
for n being Element of NAT st n >= k holds
( abs ((seq_id tseq) - (seq_id (vseq . n))) is summable & Sum (abs ((seq_id tseq) - (seq_id (vseq . n)))) < e1 ) ; :: thesis: verum

end;

abs (seq_id tseq) is summable

proof

set d = abs (seq_id tseq);
A45: for i being Element of NAT holds 0 <= (abs (seq_id tseq)) . i

proof

let i be Element of NAT ; :: thesis: 0 <= (abs (seq_id tseq)) . i
(abs (seq_id tseq)) . i = abs ((seq_id tseq) . i) by SEQ_1:16;
hence 0 <= (abs (seq_id tseq)) . i by COMPLEX1:132; :: thesis: verum

end;

consider m being Element of NAT such that
A46: for n being Element of NAT st n >= m holds
( abs ((seq_id tseq) - (seq_id (vseq . n))) is summable & Sum (abs ((seq_id tseq) - (seq_id (vseq . n)))) < 1 ) by A12;
set b = abs (seq_id (vseq . m));
set a = abs ((seq_id tseq) - (seq_id (vseq . m)));
seq_id (vseq . m) is absolutely_summable by Def1;
then A47: abs (seq_id (vseq . m)) is summable by SERIES_1:def 5;
A48: for i being Element of NAT holds (abs (seq_id tseq)) . i <= ((abs ((seq_id tseq) - (seq_id (vseq . m)))) + (abs (seq_id (vseq . m)))) . i

proof

let i be Element of NAT ; :: thesis: (abs (seq_id tseq)) . i <= ((abs ((seq_id tseq) - (seq_id (vseq . m)))) + (abs (seq_id (vseq . m)))) . i
A49: ( (abs (seq_id (vseq . m))) . i = abs ((seq_id (vseq . m)) . i) & (abs (seq_id tseq)) . i = abs ((seq_id tseq) . i) ) by SEQ_1:16;
(abs ((seq_id tseq) - (seq_id (vseq . m)))) . i = abs (((seq_id tseq) - (seq_id (vseq . m))) . i) by SEQ_1:16
.= abs (((seq_id tseq) + (- (seq_id (vseq . m)))) . i) by SEQ_1:15
.= abs (((seq_id tseq) . i) + ((- (seq_id (vseq . m))) . i)) by SEQ_1:11
.= abs (((seq_id tseq) . i) + (- ((seq_id (vseq . m)) . i))) by SEQ_1:14
.= abs (((seq_id tseq) . i) - ((seq_id (vseq . m)) . i)) ;
then ((abs (seq_id tseq)) . i) - ((abs (seq_id (vseq . m))) . i) <= (abs ((seq_id tseq) - (seq_id (vseq . m)))) . i by A49, COMPLEX1:145;
then (((abs (seq_id tseq)) . i) - ((abs (seq_id (vseq . m))) . i)) + ((abs (seq_id (vseq . m))) . i) <= ((abs ((seq_id tseq) - (seq_id (vseq . m)))) . i) + ((abs (seq_id (vseq . m))) . i) by XREAL_1:8;
hence (abs (seq_id tseq)) . i <= ((abs ((seq_id tseq) - (seq_id (vseq . m)))) + (abs (seq_id (vseq . m)))) . i by SEQ_1:11; :: thesis: verum

end;

abs ((seq_id tseq) - (seq_id (vseq . m))) is summable by A46;
then (abs ((seq_id tseq) - (seq_id (vseq . m)))) + (abs (seq_id (vseq . m))) is summable by A47, SERIES_1:10;
hence abs (seq_id tseq) is summable by A45, A48, SERIES_1:24; :: thesis: verum

end;

then A50: seq_id tseq is absolutely_summable by SERIES_1:def 5;
A51: tseq in the_set_of_RealSequences by RSSPACE:def 1;
then reconsider tv = tseq as Point of l1_Space by A50, Def1;
for e being Real st e > 0 holds
ex m being Element of NAT st
for n being Element of NAT st n >= m holds
||.((vseq . n) - tv).|| < e

proof

let e be Real; :: thesis: ( e > 0 implies ex m being Element of NAT st
for n being Element of NAT st n >= m holds
||.((vseq . n) - tv).|| < e )
assume e > 0 ; :: thesis: ex m being Element of NAT st
for n being Element of NAT st n >= m holds
||.((vseq . n) - tv).|| < e
then consider m being Element of NAT such that
A52: for n being Element of NAT st n >= m holds
( abs ((seq_id tseq) - (seq_id (vseq . n))) is summable & Sum (abs ((seq_id tseq) - (seq_id (vseq . n)))) < e ) by A12;

now

reconsider u = tseq as VECTOR of l1_Space by A50, A51, Def1;
let n be Element of NAT ; :: thesis: ( n >= m implies ||.((vseq . n) - tv).|| < e )
assume n >= m ; :: thesis: ||.((vseq . n) - tv).|| < e
then A53: Sum (abs ((seq_id tseq) - (seq_id (vseq . n)))) < e by A52;
reconsider v = vseq . n as VECTOR of l1_Space ;
seq_id (u - v) = u - v by Th8;
then Sum (abs (seq_id (u - v))) = Sum (abs ((seq_id tseq) - (seq_id (vseq . n)))) by Th8;
then A54: the normF of l1_Space . (u - v) < e by A53, Def2;
||.((vseq . n) - tv).|| = ||.(- (tv - (vseq . n))).|| by RLVECT_1:47
.= ||.(tv - (vseq . n)).|| by NORMSP_1:6 ;
hence ||.((vseq . n) - tv).|| < e by A54; :: thesis: verum

end;

hence ex m being Element of NAT st
for n being Element of NAT st n >= m holds
||.((vseq . n) - tv).|| < e ; :: thesis: verum

end;

hence vseq is convergent by NORMSP_1:def 9; :: thesis: verum