let V be RealLinearSpace; :: thesis: for v1, v2 being VECTOR of V holds
( v1 <> v2 & {v1,v2} is linearly-independent iff ( v2 <> 0. V & ( for a being Real holds v1 <> a * v2 ) ) )
let v1, v2 be VECTOR of V; :: thesis: ( v1 <> v2 & {v1,v2} is linearly-independent iff ( v2 <> 0. V & ( for a being Real holds v1 <> a * v2 ) ) )
thus ( v1 <> v2 & {v1,v2} is linearly-independent implies ( v2 <> 0. V & ( for a being Real holds v1 <> a * v2 ) ) ) :: thesis: ( v2 <> 0. V & ( for a being Real holds v1 <> a * v2 ) implies ( v1 <> v2 & {v1,v2} is linearly-independent ) )

proof

deffunc H₁( Element of V) -> Element of NAT = 0 ;
assume that
A1: v1 <> v2 and
A2: {v1,v2} is linearly-independent ; :: thesis: ( v2 <> 0. V & ( for a being Real holds v1 <> a * v2 ) )
thus v2 <> 0. V by A2, Th11; :: thesis: for a being Real holds v1 <> a * v2
let a be Real; :: thesis: v1 <> a * v2
consider f being Function of the carrier of V,REAL such that
A3: ( f . v1 = - 1 & f . v2 = a ) and
A4: for v being Element of V st v <> v1 & v <> v2 holds
f . v = H₁(v) from FUNCT_2:sch 7(A1);
reconsider f = f as Element of Funcs the carrier of V,REAL by FUNCT_2:11;

now

let v be VECTOR of V; :: thesis: ( not v in {v1,v2} implies f . v = 0 )
assume not v in {v1,v2} ; :: thesis: f . v = 0
then ( v <> v1 & v <> v2 ) by TARSKI:def 2;
hence f . v = 0 by A4; :: thesis: verum

end;

then reconsider f = f as Linear_Combination of V by RLVECT_2:def 5;
Carrier f c= {v1,v2}

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in Carrier f or x in {v1,v2} )
assume x in Carrier f ; :: thesis: x in {v1,v2}
then A5: ex u being VECTOR of V st
( x = u & f . u <> 0 ) ;
assume not x in {v1,v2} ; :: thesis: contradiction
then ( x <> v1 & x <> v2 ) by TARSKI:def 2;
hence contradiction by A4, A5; :: thesis: verum

end;

then reconsider f = f as Linear_Combination of {v1,v2} by RLVECT_2:def 8;
A6: v1 in Carrier f by A3;
set w = a * v2;
assume v1 = a * v2 ; :: thesis: contradiction
then Sum f = ((- 1) * (a * v2)) + (a * v2) by A1, A3, RLVECT_2:51
.= (- (a * v2)) + (a * v2) by RLVECT_1:29
.= - ((a * v2) - (a * v2)) by RLVECT_1:47
.= - (0. V) by RLVECT_1:28
.= 0. V by RLVECT_1:25 ;
hence contradiction by A2, A6, Def1; :: thesis: verum

end;

assume A7: v2 <> 0. V ; :: thesis: ( ex a being Real st not v1 <> a * v2 or ( v1 <> v2 & {v1,v2} is linearly-independent ) )
assume A8: for a being Real holds v1 <> a * v2 ; :: thesis: ( v1 <> v2 & {v1,v2} is linearly-independent )
A9: 1 * v2 = v2 by RLVECT_1:def 11;
hence v1 <> v2 by A8; :: thesis: {v1,v2} is linearly-independent
let l be Linear_Combination of {v1,v2}; :: according to RLVECT_3:def 1 :: thesis: ( Sum l = 0. V implies Carrier l = {} )
assume that
A10: Sum l = 0. V and
A11: Carrier l <> {} ; :: thesis: contradiction
A12: 0. V = ((l . v1) * v1) + ((l . v2) * v2) by A8, A9, A10, RLVECT_2:51;
consider x being Element of Carrier l;
Carrier l c= {v1,v2} by RLVECT_2:def 8;
then A13: x in {v1,v2} by A11, TARSKI:def 3;
x in Carrier l by A11;
then A14: ex u being VECTOR of V st
( x = u & l . u <> 0 ) ;

now

per cases ( l . v1 <> 0 or ( l . v2 <> 0 & l . v1 = 0 ) ) by A14, A13, TARSKI:def 2;

suppose A15: l . v1 <> 0 ; :: thesis: contradiction

0. V = ((l . v1) " ) * (((l . v1) * v1) + ((l . v2) * v2)) by A12, RLVECT_1:23
.= (((l . v1) " ) * ((l . v1) * v1)) + (((l . v1) " ) * ((l . v2) * v2)) by RLVECT_1:def 8
.= ((((l . v1) " ) * (l . v1)) * v1) + (((l . v1) " ) * ((l . v2) * v2)) by RLVECT_1:def 10
.= ((((l . v1) " ) * (l . v1)) * v1) + ((((l . v1) " ) * (l . v2)) * v2) by RLVECT_1:def 10
.= (1 * v1) + ((((l . v1) " ) * (l . v2)) * v2) by A15, XCMPLX_0:def 7
.= v1 + ((((l . v1) " ) * (l . v2)) * v2) by RLVECT_1:def 11 ;
then v1 = - ((((l . v1) " ) * (l . v2)) * v2) by RLVECT_1:19
.= (- 1) * ((((l . v1) " ) * (l . v2)) * v2) by RLVECT_1:29
.= ((- 1) * (((l . v1) " ) * (l . v2))) * v2 by RLVECT_1:def 10 ;
hence contradiction by A8; :: thesis: verum

end;

suppose A16: ( l . v2 <> 0 & l . v1 = 0 ) ; :: thesis: contradiction

0. V = ((l . v2) " ) * (((l . v1) * v1) + ((l . v2) * v2)) by A12, RLVECT_1:23
.= (((l . v2) " ) * ((l . v1) * v1)) + (((l . v2) " ) * ((l . v2) * v2)) by RLVECT_1:def 8
.= ((((l . v2) " ) * (l . v1)) * v1) + (((l . v2) " ) * ((l . v2) * v2)) by RLVECT_1:def 10
.= ((((l . v2) " ) * (l . v1)) * v1) + ((((l . v2) " ) * (l . v2)) * v2) by RLVECT_1:def 10
.= ((((l . v2) " ) * (l . v1)) * v1) + (1 * v2) by A16, XCMPLX_0:def 7
.= (0 * v1) + v2 by A16, RLVECT_1:def 11
.= (0. V) + v2 by RLVECT_1:23
.= v2 by RLVECT_1:10 ;
hence contradiction by A7; :: thesis: verum

end;

end;

end;

hence contradiction ; :: thesis: verum