let E be non empty finite set ; :: thesis: for ASeq being SetSequence of E st ASeq is non-ascending holds
ex N being Element of NAT st
for m being Element of NAT st N <= m holds
ASeq . N = ASeq . m
let ASeq be SetSequence of E; :: thesis: ( ASeq is non-ascending implies ex N being Element of NAT st
for m being Element of NAT st N <= m holds
ASeq . N = ASeq . m )
defpred S₁[ Element of NAT , set ] means $2 = card (ASeq . $1);
A1: for x being Element of NAT ex y being Element of REAL st S₁[x,y]

proof

let x be Element of NAT ; :: thesis: ex y being Element of REAL st S₁[x,y]
card (ASeq . x) in NAT ;
hence ex y being Element of REAL st S₁[x,y] ; :: thesis: verum

end;

consider seq being Function of NAT ,REAL such that
A2: for n being Element of NAT holds S₁[n,seq . n] from FUNCT_2:sch 3(A1);

now

let m be Element of NAT ; :: thesis: - 1 < seq . m
seq . m = card (ASeq . m) by A2;
hence - 1 < seq . m ; :: thesis: verum

end;

then A3: seq is bounded_below by SEQ_2:def 4;
assume A4: ASeq is non-ascending ; :: thesis: ex N being Element of NAT st
for m being Element of NAT st N <= m holds
ASeq . N = ASeq . m

A5: now

let n, m be Element of NAT ; :: thesis: ( n <= m implies seq . m <= seq . n )
assume n <= m ; :: thesis: seq . m <= seq . n
then A6: ASeq . m c= ASeq . n by A4, PROB_1:def 6;
( seq . m = card (ASeq . m) & seq . n = card (ASeq . n) ) by A2;
hence seq . m <= seq . n by A6, NAT_1:44; :: thesis: verum

end;

then seq is V62() by SEQM_3:14;
then consider g being real number such that
A7: for p being real number st 0 < p holds
ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs ((seq . m) - g) < p by A3, SEQ_2:def 6;
consider N being Element of NAT such that
A8: for m being Element of NAT st N <= m holds
abs ((seq . m) - g) < 1 / 2 by A7;
take N ; :: thesis: for m being Element of NAT st N <= m holds
ASeq . N = ASeq . m

now

abs ((seq . N) - g) < 1 / 2 by A8;
then A9: abs (g - (seq . N)) < 1 / 2 by COMPLEX1:146;
let m be Element of NAT ; :: thesis: ( N <= m implies ASeq . m = ASeq . N )
A10: ( seq . N = card (ASeq . N) & seq . m = card (ASeq . m) ) by A2;
assume A11: N <= m ; :: thesis: ASeq . m = ASeq . N
then A12: ( seq . m <= seq . N & ASeq . m c= ASeq . N ) by A4, A5, PROB_1:def 6;
abs ((seq . m) - g) < 1 / 2 by A8, A11;
then A13: (abs ((seq . m) - g)) + (abs (g - (seq . N))) < (1 / 2) + (1 / 2) by A9, XREAL_1:10;
abs ((seq . m) - (seq . N)) <= (abs ((seq . m) - g)) + (abs (g - (seq . N))) by COMPLEX1:149;
then abs ((seq . m) - (seq . N)) < 1 by A13, XXREAL_0:2;
then abs ((seq . N) - (seq . m)) < 1 by COMPLEX1:146;
then (seq . N) - (seq . m) < 1 by ABSVALUE:def 1;
then ((seq . N) - (seq . m)) + (seq . m) < 1 + (seq . m) by XREAL_1:10;
then seq . N <= seq . m by A10, NAT_1:8;
hence ASeq . m = ASeq . N by A10, A12, CARD_FIN:1, XXREAL_0:1; :: thesis: verum

end;

hence for m being Element of NAT st N <= m holds
ASeq . N = ASeq . m ; :: thesis: verum