let r, s be Real; :: thesis: ( ex x0, y0, z0 being Real st
( u = <*x0,y0,z0*> & ex N being Neighbourhood of y0 st
( N c= dom (SVF1 2,(pdiff1 f,2),u) & ex L being LINEAR ex R being REST st
( r = L . 1 & ( for y being Real st y in N holds
((SVF1 2,(pdiff1 f,2),u) . y) - ((SVF1 2,(pdiff1 f,2),u) . y0) = (L . (y - y0)) + (R . (y - y0)) ) ) ) ) & ex x0, y0, z0 being Real st
( u = <*x0,y0,z0*> & ex N being Neighbourhood of y0 st
( N c= dom (SVF1 2,(pdiff1 f,2),u) & ex L being LINEAR ex R being REST st
( s = L . 1 & ( for y being Real st y in N holds
((SVF1 2,(pdiff1 f,2),u) . y) - ((SVF1 2,(pdiff1 f,2),u) . y0) = (L . (y - y0)) + (R . (y - y0)) ) ) ) ) implies r = s )
assume that
A6: ex x0, y0, z0 being Real st
( u = <*x0,y0,z0*> & ex N being Neighbourhood of y0 st
( N c= dom (SVF1 2,(pdiff1 f,2),u) & ex L being LINEAR ex R being REST st
( r = L . 1 & ( for y being Real st y in N holds
((SVF1 2,(pdiff1 f,2),u) . y) - ((SVF1 2,(pdiff1 f,2),u) . y0) = (L . (y - y0)) + (R . (y - y0)) ) ) ) ) and
A7: ex x0, y0, z0 being Real st
( u = <*x0,y0,z0*> & ex N being Neighbourhood of y0 st
( N c= dom (SVF1 2,(pdiff1 f,2),u) & ex L being LINEAR ex R being REST st
( s = L . 1 & ( for y being Real st y in N holds
((SVF1 2,(pdiff1 f,2),u) . y) - ((SVF1 2,(pdiff1 f,2),u) . y0) = (L . (y - y0)) + (R . (y - y0)) ) ) ) ) ; :: thesis: r = s
consider x0, y0, z0 being Real such that
A8: ( u = <*x0,y0,z0*> & ex N being Neighbourhood of y0 st
( N c= dom (SVF1 2,(pdiff1 f,2),u) & ex L being LINEAR ex R being REST st
( r = L . 1 & ( for y being Real st y in N holds
((SVF1 2,(pdiff1 f,2),u) . y) - ((SVF1 2,(pdiff1 f,2),u) . y0) = (L . (y - y0)) + (R . (y - y0)) ) ) ) ) by A6;
consider N being Neighbourhood of y0 such that
A9: ( N c= dom (SVF1 2,(pdiff1 f,2),u) & ex L being LINEAR ex R being REST st
( r = L . 1 & ( for y being Real st y in N holds
((SVF1 2,(pdiff1 f,2),u) . y) - ((SVF1 2,(pdiff1 f,2),u) . y0) = (L . (y - y0)) + (R . (y - y0)) ) ) ) by A8;
consider L being LINEAR, R being REST such that
A10: ( r = L . 1 & ( for y being Real st y in N holds
((SVF1 2,(pdiff1 f,2),u) . y) - ((SVF1 2,(pdiff1 f,2),u) . y0) = (L . (y - y0)) + (R . (y - y0)) ) ) by A9;
consider x1, y1, z1 being Real such that
A11: ( u = <*x1,y1,z1*> & ex N being Neighbourhood of y1 st
( N c= dom (SVF1 2,(pdiff1 f,2),u) & ex L being LINEAR ex R being REST st
( s = L . 1 & ( for y being Real st y in N holds
((SVF1 2,(pdiff1 f,2),u) . y) - ((SVF1 2,(pdiff1 f,2),u) . y1) = (L . (y - y1)) + (R . (y - y1)) ) ) ) ) by A7;
consider N1 being Neighbourhood of y1 such that
A12: ( N1 c= dom (SVF1 2,(pdiff1 f,2),u) & ex L being LINEAR ex R being REST st
( s = L . 1 & ( for y being Real st y in N1 holds
((SVF1 2,(pdiff1 f,2),u) . y) - ((SVF1 2,(pdiff1 f,2),u) . y1) = (L . (y - y1)) + (R . (y - y1)) ) ) ) by A11;
consider L1 being LINEAR, R1 being REST such that
A13: ( s = L1 . 1 & ( for y being Real st y in N1 holds
((SVF1 2,(pdiff1 f,2),u) . y) - ((SVF1 2,(pdiff1 f,2),u) . y1) = (L1 . (y - y1)) + (R1 . (y - y1)) ) ) by A12;
consider r1 being Real such that
A14: for p being Real holds L . p = r1 * p by FDIFF_1:def 4;
consider p1 being Real such that
A15: for p being Real holds L1 . p = p1 * p by FDIFF_1:def 4;
A16: r = r1 * 1 by A10, A14;
A17: s = p1 * 1 by A13, A15;
A18: ( x0 = x1 & y0 = y1 & z0 = z1 ) by A8, A11, FINSEQ_1:99;
A19: now
let y be Real; :: thesis: ( y in N & y in N1 implies (r * (y - y0)) + (R . (y - y0)) = (s * (y - y0)) + (R1 . (y - y0)) )
assume A20: ( y in N & y in N1 ) ; :: thesis: (r * (y - y0)) + (R . (y - y0)) = (s * (y - y0)) + (R1 . (y - y0))
then ((SVF1 2,(pdiff1 f,2),u) . y) - ((SVF1 2,(pdiff1 f,2),u) . y0) = (L . (y - y0)) + (R . (y - y0)) by A10;
then (L . (y - y0)) + (R . (y - y0)) = (L1 . (y - y0)) + (R1 . (y - y0)) by A13, A18, A20;
then (r1 * (y - y0)) + (R . (y - y0)) = (L1 . (y - y0)) + (R1 . (y - y0)) by A14;
hence (r * (y - y0)) + (R . (y - y0)) = (s * (y - y0)) + (R1 . (y - y0)) by A15, A16, A17; :: thesis: verum
end;
consider N0 being Neighbourhood of y0 such that
A21: ( N0 c= N & N0 c= N1 ) by A18, RCOMP_1:38;
consider g being real number such that
A22: ( 0 < g & N0 = ].(y0 - g),(y0 + g).[ ) by RCOMP_1:def 7;
deffunc H1( Element of NAT ) -> Element of REAL = g / ($1 + 2);
consider s1 being Real_Sequence such that
A23: for n being Element of NAT holds s1 . n = H1(n) from SEQ_1:sch 1();
now
let n be Element of NAT ; :: thesis: s1 . n <> 0
g / (n + 2) <> 0 by A22, XREAL_1:141;
hence s1 . n <> 0 by A23; :: thesis: verum
end;
then A24: s1 is non-zero by SEQ_1:7;
( s1 is convergent & lim s1 = 0 ) by A23, SEQ_4:46;
then reconsider h = s1 as convergent_to_0 Real_Sequence by A24, FDIFF_1:def 1;
A25: for n being Element of NAT ex y being Real st
( y in N & y in N1 & h . n = y - y0 )
proof
let n be Element of NAT ; :: thesis: ex y being Real st
( y in N & y in N1 & h . n = y - y0 )
A26: g / (n + 2) > 0 by A22, XREAL_1:141;
0 + 1 < (n + 1) + 1 by XREAL_1:8;
then g / (n + 2) < g / 1 by A22, XREAL_1:78;
then A27: y0 + (g / (n + 2)) < y0 + g by XREAL_1:8;
y0 + (- g) < y0 + (g / (n + 2)) by A22, A26, XREAL_1:8;
then A28: y0 + (g / (n + 2)) in ].(y0 - g),(y0 + g).[ by A27;
take y = y0 + (g / (n + 2)); :: thesis: ( y in N & y in N1 & h . n = y - y0 )
thus ( y in N & y in N1 & h . n = y - y0 ) by A21, A22, A23, A28; :: thesis: verum
end;
A29: now
let n be Nat; :: thesis: r - s = (((h " ) (#) (R1 /* h)) - ((h " ) (#) (R /* h))) . n
X: n in NAT by ORDINAL1:def 13;
then ex y being Real st
( y in N & y in N1 & h . n = y - y0 ) by A25;
then A30: (r * (h . n)) + (R . (h . n)) = (s * (h . n)) + (R1 . (h . n)) by A19;
h is non-zero by FDIFF_1:def 1;
then A31: h . n <> 0 by SEQ_1:7, X;
A32: ((r * (h . n)) / (h . n)) + ((R . (h . n)) / (h . n)) = ((s * (h . n)) + (R1 . (h . n))) / (h . n) by A30, XCMPLX_1:63;
A33: (r * (h . n)) / (h . n) = r * ((h . n) / (h . n)) by XCMPLX_1:75
.= r * 1 by A31, XCMPLX_1:60
.= r ;
(s * (h . n)) / (h . n) = s * ((h . n) / (h . n)) by XCMPLX_1:75
.= s * 1 by A31, XCMPLX_1:60
.= s ;
then A34: r + ((R . (h . n)) / (h . n)) = s + ((R1 . (h . n)) / (h . n)) by A32, A33, XCMPLX_1:63;
dom R = REAL by PARTFUN1:def 4;
then A35: rng h c= dom R ;
dom R1 = REAL by PARTFUN1:def 4;
then A36: rng h c= dom R1 ;
A37: (R . (h . n)) / (h . n) = (R . (h . n)) * ((h . n) " ) by XCMPLX_0:def 9
.= (R . (h . n)) * ((h " ) . n) by VALUED_1:10
.= ((R /* h) . n) * ((h " ) . n) by A35, FUNCT_2:185, X
.= ((h " ) (#) (R /* h)) . n by VALUED_1:5 ;
(R1 . (h . n)) / (h . n) = (R1 . (h . n)) * ((h . n) " ) by XCMPLX_0:def 9
.= (R1 . (h . n)) * ((h " ) . n) by VALUED_1:10
.= ((R1 /* h) . n) * ((h " ) . n) by A36, FUNCT_2:185, X
.= ((h " ) (#) (R1 /* h)) . n by VALUED_1:5 ;
then r = s + ((((h " ) (#) (R1 /* h)) . n) - (((h " ) (#) (R /* h)) . n)) by A34, A37;
hence r - s = (((h " ) (#) (R1 /* h)) - ((h " ) (#) (R /* h))) . n by RFUNCT_2:6, X; :: thesis: verum
end;
then A38: ((h " ) (#) (R1 /* h)) - ((h " ) (#) (R /* h)) is V20() by VALUED_0:def 18;
(((h " ) (#) (R1 /* h)) - ((h " ) (#) (R /* h))) . 1 = r - s by A29;
then A39: lim (((h " ) (#) (R1 /* h)) - ((h " ) (#) (R /* h))) = r - s by A38, SEQ_4:40;
A40: ( (h " ) (#) (R /* h) is convergent & lim ((h " ) (#) (R /* h)) = 0 ) by FDIFF_1:def 3;
( (h " ) (#) (R1 /* h) is convergent & lim ((h " ) (#) (R1 /* h)) = 0 ) by FDIFF_1:def 3;
then r - s = 0 - 0 by A39, A40, SEQ_2:26;
hence r = s ; :: thesis: verum