let Y be non empty set ; :: thesis: for PA, PB being a_partition of Y
for y being Element of Y ex X being Subset of Y st
( y in X & X is_min_depend PA,PB )
let PA, PB be a_partition of Y; :: thesis: for y being Element of Y ex X being Subset of Y st
( y in X & X is_min_depend PA,PB )
let y be Element of Y; :: thesis: ex X being Subset of Y st
( y in X & X is_min_depend PA,PB )
A1: union PA = Y by EQREL_1:def 6;
A2: for A being set st A in PA holds
( A <> {} & ( for B being set holds
( not B in PA or A = B or A misses B ) ) ) by EQREL_1:def 6;
A3: ( Y is_a_dependent_set_of PA & Y is_a_dependent_set_of PB ) by Th9;
defpred S₁[ set ] means ( y in $1 & $1 is_a_dependent_set_of PA & $1 is_a_dependent_set_of PB );
reconsider XX = { X where X is Subset of Y : S₁[X] } as Subset-Family of Y from DOMAIN_1:sch 7();
reconsider XX = XX as Subset-Family of Y ;
Y c= Y ;
then A5: Y in XX by A3;
for X1 being set st X1 in XX holds
y in X1

proof

let X1 be set ; :: thesis: ( X1 in XX implies y in X1 )
assume X1 in XX ; :: thesis: y in X1
then ex X being Subset of Y st
( X = X1 & y in X & X is_a_dependent_set_of PA & X is_a_dependent_set_of PB ) ;
hence y in X1 ; :: thesis: verum

end;

then A9: y in meet XX by A5, SETFAM_1:def 1;
then A10: Intersect XX <> {} by SETFAM_1:def 10;
take Intersect XX ; :: thesis: ( y in Intersect XX & Intersect XX is_min_depend PA,PB )
for X1 being set st X1 in XX holds
X1 is_a_dependent_set_of PA

proof

let X1 be set ; :: thesis: ( X1 in XX implies X1 is_a_dependent_set_of PA )
assume X1 in XX ; :: thesis: X1 is_a_dependent_set_of PA
then ex X being Subset of Y st
( X = X1 & y in X & X is_a_dependent_set_of PA & X is_a_dependent_set_of PB ) ;
hence X1 is_a_dependent_set_of PA ; :: thesis: verum

end;

then A14: Intersect XX is_a_dependent_set_of PA by A10, Th10;
for X1 being set st X1 in XX holds
X1 is_a_dependent_set_of PB

proof

let X1 be set ; :: thesis: ( X1 in XX implies X1 is_a_dependent_set_of PB )
assume X1 in XX ; :: thesis: X1 is_a_dependent_set_of PB
then ex X being Subset of Y st
( X = X1 & y in X & X is_a_dependent_set_of PA & X is_a_dependent_set_of PB ) ;
hence X1 is_a_dependent_set_of PB ; :: thesis: verum

end;

then A18: Intersect XX is_a_dependent_set_of PB by A10, Th10;
for d being set st d c= Intersect XX & d is_a_dependent_set_of PA & d is_a_dependent_set_of PB holds
d = Intersect XX

proof

let d be set ; :: thesis: ( d c= Intersect XX & d is_a_dependent_set_of PA & d is_a_dependent_set_of PB implies d = Intersect XX )
assume that
A20: d c= Intersect XX and
A21: d is_a_dependent_set_of PA and
A22: d is_a_dependent_set_of PB ; :: thesis: d = Intersect XX
consider Ad being set such that
A23: Ad c= PA and
A24: Ad <> {} and
A25: d = union Ad by A21, Def1;
A26: d c= Y by A1, A23, A25, ZFMISC_1:95;

per cases ( y in d or not y in d ) ;

suppose y in d ; :: thesis: d = Intersect XX

then A28: d in XX by A21, A22, A26;
Intersect XX c= d

proof

let X1 be set ; :: according to TARSKI:def 3 :: thesis: ( not X1 in Intersect XX or X1 in d )
assume X1 in Intersect XX ; :: thesis: X1 in d
then X1 in meet XX by A5, SETFAM_1:def 10;
hence X1 in d by A28, SETFAM_1:def 1; :: thesis: verum

end;

hence d = Intersect XX by A20, XBOOLE_0:def 10; :: thesis: verum

end;

suppose A32: not y in d ; :: thesis: d = Intersect XX

reconsider d = d as Subset of Y by A1, A23, A25, ZFMISC_1:95;
d ` = Y \ d by SUBSET_1:def 5;
then A34: y in d ` by A32, XBOOLE_0:def 5;
d misses d ` by SUBSET_1:44;
then A36: d /\ (d ` ) = {} by XBOOLE_0:def 7;
d <> Y by A32;
then ( d ` is_a_dependent_set_of PA & d ` is_a_dependent_set_of PB ) by A21, A22, Th12;
then A39: d ` in XX by A34;
Intersect XX c= d `

proof

let X1 be set ; :: according to TARSKI:def 3 :: thesis: ( not X1 in Intersect XX or X1 in d ` )
assume X1 in Intersect XX ; :: thesis: X1 in d `
then X1 in meet XX by A5, SETFAM_1:def 10;
hence X1 in d ` by A39, SETFAM_1:def 1; :: thesis: verum

end;

then A43: d /\ (Intersect XX) = {} by A36, XBOOLE_1:3, XBOOLE_1:26;
d /\ d c= d /\ (Intersect XX) by A20, XBOOLE_1:26;
then A45: union Ad = {} by A25, A43;
consider ad being set such that
A46: ad in Ad by A24, XBOOLE_0:def 1;
A47: ad <> {} by A2, A23, A46;
ad c= {} by A45, A46, ZFMISC_1:92;
hence d = Intersect XX by A47; :: thesis: verum

end;

end;

end;

hence ( y in Intersect XX & Intersect XX is_min_depend PA,PB ) by A5, A9, A14, A18, Def2, SETFAM_1:def 10; :: thesis: verum