let X be non empty set ; :: thesis: for S being SigmaField of X
for M being sigma_Measure of S
for f, g being PartFunc of X,COMPLEX
for B being Element of S st f is_integrable_on M & g is_integrable_on M & B c= dom (f + g) holds
( f + g is_integrable_on M & Integral_on M,B,(f + g) = (Integral_on M,B,f) + (Integral_on M,B,g) )
let S be SigmaField of X; :: thesis: for M being sigma_Measure of S
for f, g being PartFunc of X,COMPLEX
for B being Element of S st f is_integrable_on M & g is_integrable_on M & B c= dom (f + g) holds
( f + g is_integrable_on M & Integral_on M,B,(f + g) = (Integral_on M,B,f) + (Integral_on M,B,g) )
let M be sigma_Measure of S; :: thesis: for f, g being PartFunc of X,COMPLEX
for B being Element of S st f is_integrable_on M & g is_integrable_on M & B c= dom (f + g) holds
( f + g is_integrable_on M & Integral_on M,B,(f + g) = (Integral_on M,B,f) + (Integral_on M,B,g) )
let f, g be PartFunc of X,COMPLEX ; :: thesis: for B being Element of S st f is_integrable_on M & g is_integrable_on M & B c= dom (f + g) holds
( f + g is_integrable_on M & Integral_on M,B,(f + g) = (Integral_on M,B,f) + (Integral_on M,B,g) )
let B be Element of S; :: thesis: ( f is_integrable_on M & g is_integrable_on M & B c= dom (f + g) implies ( f + g is_integrable_on M & Integral_on M,B,(f + g) = (Integral_on M,B,f) + (Integral_on M,B,g) ) )
assume that
A1: f is_integrable_on M and
A2: g is_integrable_on M and
A3: B c= dom (f + g) ; :: thesis: ( f + g is_integrable_on M & Integral_on M,B,(f + g) = (Integral_on M,B,f) + (Integral_on M,B,g) )
A4: Re f is_integrable_on M by A1, Def4;
then (Re f) | B is_integrable_on M by MESFUNC6:91;
then A5: Re (f | B) is_integrable_on M by Th7;
then A6: Integral M,(Re (f | B)) < +infty by MESFUNC6:90;
A7: Im f is_integrable_on M by A1, Def4;
then (Im f) | B is_integrable_on M by MESFUNC6:91;
then A8: Im (f | B) is_integrable_on M by Th7;
then A9: -infty < Integral M,(Im (f | B)) by MESFUNC6:90;
A10: Integral M,(Im (f | B)) < +infty by A8, MESFUNC6:90;
-infty < Integral M,(Re (f | B)) by A5, MESFUNC6:90;
then reconsider R1 = Integral M,(Re (f | B)), I1 = Integral M,(Im (f | B)) as Real by A6, A9, A10, XXREAL_0:14;
f | B is_integrable_on M by A5, A8, Def4;
then A11: Integral M,(f | B) = R1 + (I1 * <i> ) by Def5;
A12: Im g is_integrable_on M by A2, Def4;
then (Im g) | B is_integrable_on M by MESFUNC6:91;
then A13: Im (g | B) is_integrable_on M by Th7;
then A14: -infty < Integral M,(Im (g | B)) by MESFUNC6:90;
A15: Re g is_integrable_on M by A2, Def4;
then (Re g) | B is_integrable_on M by MESFUNC6:91;
then A16: Re (g | B) is_integrable_on M by Th7;
then A17: Integral M,(Re (g | B)) < +infty by MESFUNC6:90;
B c= dom (Im (f + g)) by A3, COMSEQ_3:def 4;
then A18: B c= dom ((Im f) + (Im g)) by Th5;
then Integral_on M,B,((Im f) + (Im g)) = (Integral_on M,B,(Im f)) + (Integral_on M,B,(Im g)) by A7, A12, MESFUNC6:103;
then A19: Integral M,((Im (f + g)) | B) = (Integral M,((Im f) | B)) + (Integral M,((Im g) | B)) by Th5;
A20: Integral M,(Im (g | B)) < +infty by A13, MESFUNC6:90;
-infty < Integral M,(Re (g | B)) by A16, MESFUNC6:90;
then reconsider R2 = Integral M,(Re (g | B)), I2 = Integral M,(Im (g | B)) as Real by A17, A14, A20, XXREAL_0:14;
g | B is_integrable_on M by A16, A13, Def4;
then A21: Integral M,(g | B) = R2 + (I2 * <i> ) by Def5;
A22: Integral M,((Im g) | B) = I2 by Th7;
(Im f) + (Im g) is_integrable_on M by A7, A12, A18, MESFUNC6:103;
then A23: Im (f + g) is_integrable_on M by Th5;
then (Im (f + g)) | B is_integrable_on M by MESFUNC6:91;
then A24: Im ((f + g) | B) is_integrable_on M by Th7;
then A25: -infty < Integral M,(Im ((f + g) | B)) by MESFUNC6:90;
B c= dom (Re (f + g)) by A3, COMSEQ_3:def 3;
then A26: B c= dom ((Re f) + (Re g)) by Th5;
then Integral_on M,B,((Re f) + (Re g)) = (Integral_on M,B,(Re f)) + (Integral_on M,B,(Re g)) by A4, A15, MESFUNC6:103;
then A27: Integral M,((Re (f + g)) | B) = (Integral M,((Re f) | B)) + (Integral M,((Re g) | B)) by Th5;
(Re f) + (Re g) is_integrable_on M by A4, A15, A26, MESFUNC6:103;
then A28: Re (f + g) is_integrable_on M by Th5;
then (Re (f + g)) | B is_integrable_on M by MESFUNC6:91;
then A29: Re ((f + g) | B) is_integrable_on M by Th7;
then A30: Integral M,(Re ((f + g) | B)) < +infty by MESFUNC6:90;
A31: Integral M,(Im ((f + g) | B)) < +infty by A24, MESFUNC6:90;
-infty < Integral M,(Re ((f + g) | B)) by A29, MESFUNC6:90;
then reconsider R = Integral M,(Re ((f + g) | B)), I = Integral M,(Im ((f + g) | B)) as Real by A30, A25, A31, XXREAL_0:14;
A32: Integral M,((Re g) | B) = R2 by Th7;
Integral M,((Im f) | B) = I1 by Th7;
then R_EAL I = (R_EAL I1) + (R_EAL I2) by A19, A22, Th7;
then A33: I = I1 + I2 by SUPINF_2:1;
Integral M,((Re f) | B) = R1 by Th7;
then R_EAL R = (R_EAL R1) + (R_EAL R2) by A27, A32, Th7;
then A34: R = R1 + R2 by SUPINF_2:1;
(f + g) | B is_integrable_on M by A29, A24, Def4;
then Integral_on M,B,(f + g) = R + (I * <i> ) by Def5
.= (Integral_on M,B,f) + (Integral_on M,B,g) by A34, A33, A11, A21 ;
hence ( f + g is_integrable_on M & Integral_on M,B,(f + g) = (Integral_on M,B,f) + (Integral_on M,B,g) ) by A28, A23, Def4; :: thesis: verum