let X be non empty set ; :: thesis: for S being SigmaField of X
for M being sigma_Measure of S
for f being PartFunc of X,ExtREAL
for A being Element of S st ex E being Element of S st
( E = dom f & f is_measurable_on E ) & M . A = 0 holds
f | A is_integrable_on M
let S be SigmaField of X; :: thesis: for M being sigma_Measure of S
for f being PartFunc of X,ExtREAL
for A being Element of S st ex E being Element of S st
( E = dom f & f is_measurable_on E ) & M . A = 0 holds
f | A is_integrable_on M
let M be sigma_Measure of S; :: thesis: for f being PartFunc of X,ExtREAL
for A being Element of S st ex E being Element of S st
( E = dom f & f is_measurable_on E ) & M . A = 0 holds
f | A is_integrable_on M
let f be PartFunc of X,ExtREAL ; :: thesis: for A being Element of S st ex E being Element of S st
( E = dom f & f is_measurable_on E ) & M . A = 0 holds
f | A is_integrable_on M
let A be Element of S; :: thesis: ( ex E being Element of S st
( E = dom f & f is_measurable_on E ) & M . A = 0 implies f | A is_integrable_on M )
assume that
A1: ex E being Element of S st
( E = dom f & f is_measurable_on E ) and
A2: M . A = 0 ; :: thesis: f | A is_integrable_on M
A3: dom f = dom (max+ f) by MESFUNC2:def 2;
max+ f is nonnegative by Lm1;
then integral+ M,((max+ f) | A) = 0 by A1, A2, A3, MESFUNC2:27, MESFUNC5:88;
then A4: integral+ M,(max+ (f | A)) < +infty by MESFUNC5:34;
consider E being Element of S such that
A5: E = dom f and
A6: f is_measurable_on E by A1;
A7: (dom f) /\ (A /\ E) = A /\ E by A5, XBOOLE_1:17, XBOOLE_1:28;
A8: dom f = dom (max- f) by MESFUNC2:def 3;
max- f is nonnegative by Lm1;
then integral+ M,((max- f) | A) = 0 by A1, A2, A8, MESFUNC2:28, MESFUNC5:88;
then A9: integral+ M,(max- (f | A)) < +infty by MESFUNC5:34;
A10: dom (f | A) = (dom f) /\ A by RELAT_1:90;
f is_measurable_on A /\ E by A6, MESFUNC1:34, XBOOLE_1:17;
then A11: f | (A /\ E) is_measurable_on A /\ E by A7, MESFUNC5:48;
f | (A /\ E) = (f | A) /\ (f | E) by RELAT_1:108
.= (f | A) /\ f by A5, RELAT_1:98
.= f | A by RELAT_1:88, XBOOLE_1:28 ;
hence f | A is_integrable_on M by A5, A11, A10, A4, A9, MESFUNC5:def 17; :: thesis: verum