let x0 be Real; :: thesis: for f1, f2 being PartFunc of REAL ,REAL st f1 is_right_convergent_in x0 & f2 is_left_divergent_to-infty_in lim_right f1,x0 & ( for r being Real st x0 < r holds
ex g being Real st
( g < r & x0 < g & g in dom (f2 * f1) ) ) & ex g being Real st
( 0 < g & ( for r being Real st r in (dom f1) /\ ].x0,(x0 + g).[ holds
f1 . r < lim_right f1,x0 ) ) holds
f2 * f1 is_right_divergent_to-infty_in x0
let f1, f2 be PartFunc of REAL ,REAL ; :: thesis: ( f1 is_right_convergent_in x0 & f2 is_left_divergent_to-infty_in lim_right f1,x0 & ( for r being Real st x0 < r holds
ex g being Real st
( g < r & x0 < g & g in dom (f2 * f1) ) ) & ex g being Real st
( 0 < g & ( for r being Real st r in (dom f1) /\ ].x0,(x0 + g).[ holds
f1 . r < lim_right f1,x0 ) ) implies f2 * f1 is_right_divergent_to-infty_in x0 )
assume that
A1: f1 is_right_convergent_in x0 and
A2: f2 is_left_divergent_to-infty_in lim_right f1,x0 and
A3: for r being Real st x0 < r holds
ex g being Real st
( g < r & x0 < g & g in dom (f2 * f1) ) ; :: thesis: ( for g being Real holds
( not 0 < g or ex r being Real st
( r in (dom f1) /\ ].x0,(x0 + g).[ & not f1 . r < lim_right f1,x0 ) ) or f2 * f1 is_right_divergent_to-infty_in x0 )
given g being Real such that A4: 0 < g and
A5: for r being Real st r in (dom f1) /\ ].x0,(x0 + g).[ holds
f1 . r < lim_right f1,x0 ; :: thesis: f2 * f1 is_right_divergent_to-infty_in x0

now

let s be Real_Sequence; :: thesis: ( s is convergent & lim s = x0 & rng s c= (dom (f2 * f1)) /\ (right_open_halfline x0) implies (f2 * f1) /* s is divergent_to-infty )
assume that
A6: ( s is convergent & lim s = x0 ) and
A7: rng s c= (dom (f2 * f1)) /\ (right_open_halfline x0) ; :: thesis: (f2 * f1) /* s is divergent_to-infty
consider k being Element of NAT such that
A8: for n being Element of NAT st k <= n holds
s . n < x0 + g by A4, A6, Lm1, LIMFUNC2:2;
set q = (f1 /* s) ^\ k;
A9: rng s c= dom (f2 * f1) by A7, Th1;
rng (f1 /* s) c= dom f2 by A7, Th1;
then A10: f2 /* ((f1 /* s) ^\ k) = (f2 /* (f1 /* s)) ^\ k by VALUED_0:27
.= ((f2 * f1) /* s) ^\ k by A9, VALUED_0:31 ;
A11: rng s c= (dom f1) /\ (right_open_halfline x0) by A7, Th1;
then A12: f1 /* s is convergent by A1, A2, A6, LIMFUNC2:def 8;
A13: rng s c= dom f1 by A7, Th1;
A14: rng s c= right_open_halfline x0 by A7, Th1;

now

let x be set ; :: thesis: ( x in rng ((f1 /* s) ^\ k) implies x in (dom f2) /\ (left_open_halfline (lim_right f1,x0)) )
assume x in rng ((f1 /* s) ^\ k) ; :: thesis: x in (dom f2) /\ (left_open_halfline (lim_right f1,x0))
then consider n being Element of NAT such that
A15: ((f1 /* s) ^\ k) . n = x by FUNCT_2:190;
A16: f1 . (s . (n + k)) = (f1 /* s) . (n + k) by A13, FUNCT_2:185
.= x by A15, NAT_1:def 3 ;
A17: s . (n + k) < x0 + g by A8, NAT_1:12;
A18: s . (n + k) in rng s by VALUED_0:28;
then s . (n + k) in right_open_halfline x0 by A14;
then s . (n + k) in { g1 where g1 is Real : x0 < g1 } by XXREAL_1:230;
then ex g1 being Real st
( g1 = s . (n + k) & x0 < g1 ) ;
then s . (n + k) in { g2 where g2 is Real : ( x0 < g2 & g2 < x0 + g ) } by A17;
then s . (n + k) in ].x0,(x0 + g).[ by RCOMP_1:def 2;
then s . (n + k) in (dom f1) /\ ].x0,(x0 + g).[ by A13, A18, XBOOLE_0:def 4;
then f1 . (s . (n + k)) < lim_right f1,x0 by A5;
then f1 . (s . (n + k)) in { r1 where r1 is Real : r1 < lim_right f1,x0 } ;
then A19: f1 . (s . (n + k)) in left_open_halfline (lim_right f1,x0) by XXREAL_1:229;
f1 . (s . (n + k)) in dom f2 by A9, A18, FUNCT_1:21;
hence x in (dom f2) /\ (left_open_halfline (lim_right f1,x0)) by A19, A16, XBOOLE_0:def 4; :: thesis: verum

end;

then A20: rng ((f1 /* s) ^\ k) c= (dom f2) /\ (left_open_halfline (lim_right f1,x0)) by TARSKI:def 3;
lim (f1 /* s) = lim_right f1,x0 by A1, A6, A11, LIMFUNC2:def 8;
then lim ((f1 /* s) ^\ k) = lim_right f1,x0 by A12, SEQ_4:33;
then f2 /* ((f1 /* s) ^\ k) is divergent_to-infty by A2, A12, A20, LIMFUNC2:def 3;
hence (f2 * f1) /* s is divergent_to-infty by A10, LIMFUNC1:34; :: thesis: verum

end;

hence f2 * f1 is_right_divergent_to-infty_in x0 by A3, LIMFUNC2:def 6; :: thesis: verum