let x0 be Real; :: thesis: for f being PartFunc of REAL ,REAL st f is_convergent_in x0 & f " {0 } = {} & lim f,x0 <> 0 holds
( f ^ is_convergent_in x0 & lim (f ^ ),x0 = (lim f,x0) " )
let f be PartFunc of REAL ,REAL ; :: thesis: ( f is_convergent_in x0 & f " {0 } = {} & lim f,x0 <> 0 implies ( f ^ is_convergent_in x0 & lim (f ^ ),x0 = (lim f,x0) " ) )
assume that
A1: f is_convergent_in x0 and
A2: f " {0 } = {} and
A3: lim f,x0 <> 0 ; :: thesis: ( f ^ is_convergent_in x0 & lim (f ^ ),x0 = (lim f,x0) " )
A4: dom f = (dom f) \ (f " {0 }) by A2
.= dom (f ^ ) by RFUNCT_1:def 8 ;

A5: now

let seq be Real_Sequence; :: thesis: ( seq is convergent & lim seq = x0 & rng seq c= (dom (f ^ )) \ {x0} implies ( (f ^ ) /* seq is convergent & lim ((f ^ ) /* seq) = (lim f,x0) " ) )
assume that
A6: seq is convergent and
A7: lim seq = x0 and
A8: rng seq c= (dom (f ^ )) \ {x0} ; :: thesis: ( (f ^ ) /* seq is convergent & lim ((f ^ ) /* seq) = (lim f,x0) " )
A9: lim (f /* seq) = lim f,x0 by A1, A4, A6, A7, A8, Def4;
A10: (f /* seq) " = (f ^ ) /* seq by A8, RFUNCT_2:27, XBOOLE_1:1;
A11: rng seq c= dom f by A4, A8, XBOOLE_1:1;
A12: f /* seq is convergent by A1, A3, A4, A6, A7, A8, Def4;
hence (f ^ ) /* seq is convergent by A3, A4, A9, A11, A10, RFUNCT_2:26, SEQ_2:35; :: thesis: lim ((f ^ ) /* seq) = (lim f,x0) "
thus lim ((f ^ ) /* seq) = (lim f,x0) " by A3, A4, A12, A9, A11, A10, RFUNCT_2:26, SEQ_2:36; :: thesis: verum

end;

for r1, r2 being Real st r1 < x0 & x0 < r2 holds
ex g1, g2 being Real st
( r1 < g1 & g1 < x0 & g1 in dom (f ^ ) & g2 < r2 & x0 < g2 & g2 in dom (f ^ ) ) by A1, A4, Def1;
hence f ^ is_convergent_in x0 by A5, Def1; :: thesis: lim (f ^ ),x0 = (lim f,x0) "
hence lim (f ^ ),x0 = (lim f,x0) " by A5, Def4; :: thesis: verum