let n be Nat; :: thesis: for K being Field
for f being FinSequence of K
for M being Matrix of n,K
for p being Element of Permutations n
for i being Nat st len f = n & i in Seg n holds
mlt (Line (Matrix_of_Cofactor M),i),f = LaplaceExpL (RLine M,i,f),i
let K be Field; :: thesis: for f being FinSequence of K
for M being Matrix of n,K
for p being Element of Permutations n
for i being Nat st len f = n & i in Seg n holds
mlt (Line (Matrix_of_Cofactor M),i),f = LaplaceExpL (RLine M,i,f),i
let f be FinSequence of K; :: thesis: for M being Matrix of n,K
for p being Element of Permutations n
for i being Nat st len f = n & i in Seg n holds
mlt (Line (Matrix_of_Cofactor M),i),f = LaplaceExpL (RLine M,i,f),i
let M be Matrix of n,K; :: thesis: for p being Element of Permutations n
for i being Nat st len f = n & i in Seg n holds
mlt (Line (Matrix_of_Cofactor M),i),f = LaplaceExpL (RLine M,i,f),i
let p be Element of Permutations n; :: thesis: for i being Nat st len f = n & i in Seg n holds
mlt (Line (Matrix_of_Cofactor M),i),f = LaplaceExpL (RLine M,i,f),i
let i be Nat; :: thesis: ( len f = n & i in Seg n implies mlt (Line (Matrix_of_Cofactor M),i),f = LaplaceExpL (RLine M,i,f),i )
assume that
A1: len f = n and
A2: i in Seg n ; :: thesis: mlt (Line (Matrix_of_Cofactor M),i),f = LaplaceExpL (RLine M,i,f),i
reconsider N = n as Element of NAT by ORDINAL1:def 13;
set KK = the carrier of K;
set C = Matrix_of_Cofactor M;
reconsider Tp = f, TL = Line (Matrix_of_Cofactor M),i as Element of N -tuples_on the carrier of K by A1, FINSEQ_2:110, MATRIX_1:25;
set R = RLine M,i,f;
set LL = LaplaceExpL (RLine M,i,f),i;
set MLT = mlt TL,Tp;
A3: len (LaplaceExpL (RLine M,i,f),i) = n by Def7;

A4: now

A5: dom (LaplaceExpL (RLine M,i,f),i) = Seg n by A3, FINSEQ_1:def 3;
A6: n = width M by MATRIX_1:25;
let j be Nat; :: thesis: ( 1 <= j & j <= n implies (mlt TL,Tp) . j = (LaplaceExpL (RLine M,i,f),i) . j )
assume that
A7: 1 <= j and
A8: j <= n ; :: thesis: (mlt TL,Tp) . j = (LaplaceExpL (RLine M,i,f),i) . j
j in NAT by ORDINAL1:def 13;
then A9: j in Seg n by A7, A8;
n = width (Matrix_of_Cofactor M) by MATRIX_1:25;
then A10: (Line (Matrix_of_Cofactor M),i) . j = (Matrix_of_Cofactor M) * i,j by A9, MATRIX_1:def 8;
Indices M = [:(Seg n),(Seg n):] by MATRIX_1:25;
then [i,j] in Indices M by A2, A9, ZFMISC_1:106;
then A11: (RLine M,i,f) * i,j = f . j by A1, A6, MATRIX11:def 3;
Indices (Matrix_of_Cofactor M) = [:(Seg n),(Seg n):] by MATRIX_1:25;
then [i,j] in Indices (Matrix_of_Cofactor M) by A2, A9, ZFMISC_1:106;
then (Line (Matrix_of_Cofactor M),i) . j = Cofactor M,i,j by A10, Def6;
then A12: (mlt TL,Tp) . j = (Cofactor M,i,j) * ((RLine M,i,f) * i,j) by A9, A11, FVSUM_1:74;
Cofactor M,i,j = Cofactor (RLine M,i,f),i,j by A2, A9, Th15;
hence (mlt TL,Tp) . j = (LaplaceExpL (RLine M,i,f),i) . j by A9, A5, A12, Def7; :: thesis: verum

end;

len (mlt TL,Tp) = n by FINSEQ_1:def 18;
hence mlt (Line (Matrix_of_Cofactor M),i),f = LaplaceExpL (RLine M,i,f),i by A3, A4, FINSEQ_1:18; :: thesis: verum