let n be Element of NAT ; :: thesis: ex f being Function of (TOP-REAL n),R^1 st
( ( for q being Point of (TOP-REAL n) holds f . q = |.q.| ) & f is continuous )
defpred S₁[ set , set ] means ex q being Point of (TOP-REAL n) st
( q = $1 & $2 = |.q.| );
A1: for x being set st x in the carrier of (TOP-REAL n) holds
ex y being set st S₁[x,y]

proof

let x be set ; :: thesis: ( x in the carrier of (TOP-REAL n) implies ex y being set st S₁[x,y] )
assume x in the carrier of (TOP-REAL n) ; :: thesis: ex y being set st S₁[x,y]
then reconsider q3 = x as Point of (TOP-REAL n) ;
take |.q3.| ; :: thesis: S₁[x,|.q3.|]
thus S₁[x,|.q3.|] ; :: thesis: verum

end;

consider f1 being Function such that
A2: ( dom f1 = the carrier of (TOP-REAL n) & ( for x being set st x in the carrier of (TOP-REAL n) holds
S₁[x,f1 . x] ) ) from CLASSES1:sch 1(A1);
rng f1 c= the carrier of R^1

proof

let z be set ; :: according to TARSKI:def 3 :: thesis: ( not z in rng f1 or z in the carrier of R^1 )
assume z in rng f1 ; :: thesis: z in the carrier of R^1
then consider xz being set such that
A3: xz in dom f1 and
A4: z = f1 . xz by FUNCT_1:def 5;
ex q4 being Point of (TOP-REAL n) st
( q4 = xz & f1 . xz = |.q4.| ) by A2, A3;
hence z in the carrier of R^1 by A4, TOPMETR:24; :: thesis: verum

end;

then reconsider f2 = f1 as Function of (TOP-REAL n),R^1 by A2, FUNCT_2:def 1, RELSET_1:11;
A5: for q being Point of (TOP-REAL n) holds f1 . q = |.q.|

proof

let q be Point of (TOP-REAL n); :: thesis: f1 . q = |.q.|
ex q2 being Point of (TOP-REAL n) st
( q2 = q & f1 . q = |.q2.| ) by A2;
hence f1 . q = |.q.| ; :: thesis: verum

end;

then f2 is continuous by Th91;
hence ex f being Function of (TOP-REAL n),R^1 st
( ( for q being Point of (TOP-REAL n) holds f . q = |.q.| ) & f is continuous ) by A5; :: thesis: verum