reconsider D = NonZero (TOP-REAL 2) as non empty Subset of (TOP-REAL 2) by JGRAPH_2:19;
let sn be Real; :: thesis: ( - 1 < sn & sn < 1 implies ex h being Function of (TOP-REAL 2),(TOP-REAL 2) st
( h = sn -FanMorphE & h is continuous ) )
assume that
A1: - 1 < sn and
A2: sn < 1 ; :: thesis: ex h being Function of (TOP-REAL 2),(TOP-REAL 2) st
( h = sn -FanMorphE & h is continuous )
reconsider f = sn -FanMorphE as Function of (TOP-REAL 2),(TOP-REAL 2) ;
A3: f . (0. (TOP-REAL 2)) = 0. (TOP-REAL 2) by Th89, JGRAPH_2:11;
A4: for p being Point of ((TOP-REAL 2) | D) holds f . p <> f . (0. (TOP-REAL 2))

proof

let p be Point of ((TOP-REAL 2) | D); :: thesis: f . p <> f . (0. (TOP-REAL 2))
A5: [#] ((TOP-REAL 2) | D) = D by PRE_TOPC:def 10;
then reconsider q = p as Point of (TOP-REAL 2) by XBOOLE_0:def 5;
not p in {(0. (TOP-REAL 2))} by A5, XBOOLE_0:def 5;
then A6: not p = 0. (TOP-REAL 2) by TARSKI:def 1;

now

per cases ( ( (q `2 ) / |.q.| >= sn & q `1 >= 0 ) or ( (q `2 ) / |.q.| < sn & q `1 >= 0 ) or q `1 < 0 ) ;

case A7: ( (q `2 ) / |.q.| >= sn & q `1 >= 0 ) ; :: thesis: f . p <> f . (0. (TOP-REAL 2))

set q9 = |[(|.q.| * (sqrt (1 - (((((q `2 ) / |.q.|) - sn) / (1 - sn)) ^2 )))),(|.q.| * ((((q `2 ) / |.q.|) - sn) / (1 - sn)))]|;
A8: |[(|.q.| * (sqrt (1 - (((((q `2 ) / |.q.|) - sn) / (1 - sn)) ^2 )))),(|.q.| * ((((q `2 ) / |.q.|) - sn) / (1 - sn)))]| `2 = |.q.| * ((((q `2 ) / |.q.|) - sn) / (1 - sn)) by EUCLID:56;

now

assume A9: |[(|.q.| * (sqrt (1 - (((((q `2 ) / |.q.|) - sn) / (1 - sn)) ^2 )))),(|.q.| * ((((q `2 ) / |.q.|) - sn) / (1 - sn)))]| = 0. (TOP-REAL 2) ; :: thesis: contradiction
A10: |.q.| <> 0 by A6, TOPRNS_1:25;
then sqrt (1 - (((((q `2 ) / |.q.|) - sn) / (1 - sn)) ^2 )) = sqrt (1 - (0 ^2 )) by A8, A9, JGRAPH_2:11, XCMPLX_1:6
.= 1 by SQUARE_1:83 ;
hence contradiction by A9, A10, EUCLID:56, JGRAPH_2:11; :: thesis: verum

end;

hence f . p <> f . (0. (TOP-REAL 2)) by A1, A2, A3, A6, A7, Th91; :: thesis: verum

end;

case A11: ( (q `2 ) / |.q.| < sn & q `1 >= 0 ) ; :: thesis: f . p <> f . (0. (TOP-REAL 2))

set q9 = |[(|.q.| * (sqrt (1 - (((((q `2 ) / |.q.|) - sn) / (1 + sn)) ^2 )))),(|.q.| * ((((q `2 ) / |.q.|) - sn) / (1 + sn)))]|;
A12: |[(|.q.| * (sqrt (1 - (((((q `2 ) / |.q.|) - sn) / (1 + sn)) ^2 )))),(|.q.| * ((((q `2 ) / |.q.|) - sn) / (1 + sn)))]| `2 = |.q.| * ((((q `2 ) / |.q.|) - sn) / (1 + sn)) by EUCLID:56;

now

assume A13: |[(|.q.| * (sqrt (1 - (((((q `2 ) / |.q.|) - sn) / (1 + sn)) ^2 )))),(|.q.| * ((((q `2 ) / |.q.|) - sn) / (1 + sn)))]| = 0. (TOP-REAL 2) ; :: thesis: contradiction
A14: |.q.| <> 0 by A6, TOPRNS_1:25;
then sqrt (1 - (((((q `2 ) / |.q.|) - sn) / (1 + sn)) ^2 )) = sqrt (1 - (0 ^2 )) by A12, A13, JGRAPH_2:11, XCMPLX_1:6
.= 1 by SQUARE_1:83 ;
hence contradiction by A13, A14, EUCLID:56, JGRAPH_2:11; :: thesis: verum

end;

hence f . p <> f . (0. (TOP-REAL 2)) by A1, A2, A3, A6, A11, Th91; :: thesis: verum

end;

case q `1 < 0 ; :: thesis: f . p <> f . (0. (TOP-REAL 2))

then f . p = p by Th89;
hence f . p <> f . (0. (TOP-REAL 2)) by A6, Th89, JGRAPH_2:11; :: thesis: verum

end;

end;

end;

hence f . p <> f . (0. (TOP-REAL 2)) ; :: thesis: verum

end;

A15: for V being Subset of (TOP-REAL 2) st f . (0. (TOP-REAL 2)) in V & V is open holds
ex W being Subset of (TOP-REAL 2) st
( 0. (TOP-REAL 2) in W & W is open & f .: W c= V )

proof

reconsider u0 = 0. (TOP-REAL 2) as Point of (Euclid 2) by EUCLID:71;
let V be Subset of (TOP-REAL 2); :: thesis: ( f . (0. (TOP-REAL 2)) in V & V is open implies ex W being Subset of (TOP-REAL 2) st
( 0. (TOP-REAL 2) in W & W is open & f .: W c= V ) )
reconsider VV = V as Subset of (TopSpaceMetr (Euclid 2)) by Lm11;
assume that
A16: f . (0. (TOP-REAL 2)) in V and
A17: V is open ; :: thesis: ex W being Subset of (TOP-REAL 2) st
( 0. (TOP-REAL 2) in W & W is open & f .: W c= V )
VV is open by A17, Lm11, PRE_TOPC:60;
then consider r being real number such that
A18: r > 0 and
A19: Ball u0,r c= V by A3, A16, TOPMETR:22;
reconsider r = r as Real by XREAL_0:def 1;
TopStruct(# the carrier of (TOP-REAL 2),the topology of (TOP-REAL 2) #) = TopSpaceMetr (Euclid 2) by EUCLID:def 8;
then reconsider W1 = Ball u0,r as Subset of (TOP-REAL 2) ;
A20: W1 is open by GOBOARD6:6;
A21: f .: W1 c= W1

proof

let z be set ; :: according to TARSKI:def 3 :: thesis: ( not z in f .: W1 or z in W1 )
assume z in f .: W1 ; :: thesis: z in W1
then consider y being set such that
A22: y in dom f and
A23: y in W1 and
A24: z = f . y by FUNCT_1:def 12;
z in rng f by A22, A24, FUNCT_1:def 5;
then reconsider qz = z as Point of (TOP-REAL 2) ;
reconsider q = y as Point of (TOP-REAL 2) by A22;
reconsider qy = q as Point of (Euclid 2) by EUCLID:71;
reconsider pz = qz as Point of (Euclid 2) by EUCLID:71;
dist u0,qy < r by A23, METRIC_1:12;
then A25: |.((0. (TOP-REAL 2)) - q).| < r by JGRAPH_1:45;

now

per cases ( q `1 <= 0 or ( q <> 0. (TOP-REAL 2) & (q `2 ) / |.q.| >= sn & q `1 >= 0 ) or ( q <> 0. (TOP-REAL 2) & (q `2 ) / |.q.| < sn & q `1 >= 0 ) ) by JGRAPH_2:11;

case q `1 <= 0 ; :: thesis: z in W1

hence z in W1 by A23, A24, Th89; :: thesis: verum

end;

case A26: ( q <> 0. (TOP-REAL 2) & (q `2 ) / |.q.| >= sn & q `1 >= 0 ) ; :: thesis: z in W1

then A27: ((q `2 ) / |.q.|) - sn >= 0 by XREAL_1:50;
0 <= (q `1 ) ^2 by XREAL_1:65;
then ( |.q.| ^2 = ((q `1 ) ^2 ) + ((q `2 ) ^2 ) & 0 + ((q `2 ) ^2 ) <= ((q `1 ) ^2 ) + ((q `2 ) ^2 ) ) by JGRAPH_3:10, XREAL_1:9;
then A28: ((q `2 ) ^2 ) / (|.q.| ^2 ) <= (|.q.| ^2 ) / (|.q.| ^2 ) by XREAL_1:74;
A29: 1 - sn > 0 by A2, XREAL_1:151;
|.q.| <> 0 by A26, TOPRNS_1:25;
then |.q.| ^2 > 0 by SQUARE_1:74;
then ((q `2 ) ^2 ) / (|.q.| ^2 ) <= 1 by A28, XCMPLX_1:60;
then ((q `2 ) / |.q.|) ^2 <= 1 by XCMPLX_1:77;
then 1 >= (q `2 ) / |.q.| by SQUARE_1:121;
then 1 - sn >= ((q `2 ) / |.q.|) - sn by XREAL_1:11;
then - (1 - sn) <= - (((q `2 ) / |.q.|) - sn) by XREAL_1:26;
then (- (1 - sn)) / (1 - sn) <= (- (((q `2 ) / |.q.|) - sn)) / (1 - sn) by A29, XREAL_1:74;
then - 1 <= (- (((q `2 ) / |.q.|) - sn)) / (1 - sn) by A29, XCMPLX_1:198;
then ((- (((q `2 ) / |.q.|) - sn)) / (1 - sn)) ^2 <= 1 ^2 by A29, A27, SQUARE_1:119;
then 1 - (((- (((q `2 ) / |.q.|) - sn)) / (1 - sn)) ^2 ) >= 0 by XREAL_1:50;
then A30: 1 - ((- ((((q `2 ) / |.q.|) - sn) / (1 - sn))) ^2 ) >= 0 by XCMPLX_1:188;
A31: (sn -FanMorphE ) . q = |[(|.q.| * (sqrt (1 - (((((q `2 ) / |.q.|) - sn) / (1 - sn)) ^2 )))),(|.q.| * ((((q `2 ) / |.q.|) - sn) / (1 - sn)))]| by A1, A2, A26, Th91;
then A32: qz `2 = |.q.| * ((((q `2 ) / |.q.|) - sn) / (1 - sn)) by A24, EUCLID:56;
qz `1 = |.q.| * (sqrt (1 - (((((q `2 ) / |.q.|) - sn) / (1 - sn)) ^2 ))) by A24, A31, EUCLID:56;
then A33: (qz `1 ) ^2 = (|.q.| ^2 ) * ((sqrt (1 - (((((q `2 ) / |.q.|) - sn) / (1 - sn)) ^2 ))) ^2 )
.= (|.q.| ^2 ) * (1 - (((((q `2 ) / |.q.|) - sn) / (1 - sn)) ^2 )) by A30, SQUARE_1:def 4 ;
|.qz.| ^2 = ((qz `1 ) ^2 ) + ((qz `2 ) ^2 ) by JGRAPH_3:10
.= |.q.| ^2 by A32, A33 ;
then sqrt (|.qz.| ^2 ) = |.q.| by SQUARE_1:89;
then A34: |.qz.| = |.q.| by SQUARE_1:89;
|.(- q).| < r by A25, EUCLID:31;
then |.q.| < r by TOPRNS_1:27;
then |.(- qz).| < r by A34, TOPRNS_1:27;
then |.((0. (TOP-REAL 2)) - qz).| < r by EUCLID:31;
then dist u0,pz < r by JGRAPH_1:45;
hence z in W1 by METRIC_1:12; :: thesis: verum

end;

case A35: ( q <> 0. (TOP-REAL 2) & (q `2 ) / |.q.| < sn & q `1 >= 0 ) ; :: thesis: z in W1

0 <= (q `1 ) ^2 by XREAL_1:65;
then ( |.q.| ^2 = ((q `1 ) ^2 ) + ((q `2 ) ^2 ) & 0 + ((q `2 ) ^2 ) <= ((q `1 ) ^2 ) + ((q `2 ) ^2 ) ) by JGRAPH_3:10, XREAL_1:9;
then A36: ((q `2 ) ^2 ) / (|.q.| ^2 ) <= (|.q.| ^2 ) / (|.q.| ^2 ) by XREAL_1:74;
A37: 1 + sn > 0 by A1, XREAL_1:150;
|.q.| <> 0 by A35, TOPRNS_1:25;
then |.q.| ^2 > 0 by SQUARE_1:74;
then ((q `2 ) ^2 ) / (|.q.| ^2 ) <= 1 by A36, XCMPLX_1:60;
then ((q `2 ) / |.q.|) ^2 <= 1 by XCMPLX_1:77;
then - 1 <= (q `2 ) / |.q.| by SQUARE_1:121;
then - (- 1) >= - ((q `2 ) / |.q.|) by XREAL_1:26;
then 1 + sn >= (- ((q `2 ) / |.q.|)) + sn by XREAL_1:9;
then A38: (- (((q `2 ) / |.q.|) - sn)) / (1 + sn) <= 1 by A37, XREAL_1:187;
sn - ((q `2 ) / |.q.|) >= 0 by A35, XREAL_1:50;
then - 1 <= (- (((q `2 ) / |.q.|) - sn)) / (1 + sn) by A37;
then ((- (((q `2 ) / |.q.|) - sn)) / (1 + sn)) ^2 <= 1 ^2 by A38, SQUARE_1:119;
then 1 - (((- (((q `2 ) / |.q.|) - sn)) / (1 + sn)) ^2 ) >= 0 by XREAL_1:50;
then A39: 1 - ((- ((((q `2 ) / |.q.|) - sn) / (1 + sn))) ^2 ) >= 0 by XCMPLX_1:188;
A40: (sn -FanMorphE ) . q = |[(|.q.| * (sqrt (1 - (((((q `2 ) / |.q.|) - sn) / (1 + sn)) ^2 )))),(|.q.| * ((((q `2 ) / |.q.|) - sn) / (1 + sn)))]| by A1, A2, A35, Th91;
then A41: qz `2 = |.q.| * ((((q `2 ) / |.q.|) - sn) / (1 + sn)) by A24, EUCLID:56;
qz `1 = |.q.| * (sqrt (1 - (((((q `2 ) / |.q.|) - sn) / (1 + sn)) ^2 ))) by A24, A40, EUCLID:56;
then A42: (qz `1 ) ^2 = (|.q.| ^2 ) * ((sqrt (1 - (((((q `2 ) / |.q.|) - sn) / (1 + sn)) ^2 ))) ^2 )
.= (|.q.| ^2 ) * (1 - (((((q `2 ) / |.q.|) - sn) / (1 + sn)) ^2 )) by A39, SQUARE_1:def 4 ;
|.qz.| ^2 = ((qz `1 ) ^2 ) + ((qz `2 ) ^2 ) by JGRAPH_3:10
.= |.q.| ^2 by A41, A42 ;
then sqrt (|.qz.| ^2 ) = |.q.| by SQUARE_1:89;
then A43: |.qz.| = |.q.| by SQUARE_1:89;
|.(- q).| < r by A25, EUCLID:31;
then |.q.| < r by TOPRNS_1:27;
then |.(- qz).| < r by A43, TOPRNS_1:27;
then |.((0. (TOP-REAL 2)) - qz).| < r by EUCLID:31;
then dist u0,pz < r by JGRAPH_1:45;
hence z in W1 by METRIC_1:12; :: thesis: verum

end;

end;

end;

hence z in W1 ; :: thesis: verum

end;

u0 in W1 by A18, GOBOARD6:4;
hence ex W being Subset of (TOP-REAL 2) st
( 0. (TOP-REAL 2) in W & W is open & f .: W c= V ) by A19, A20, A21, XBOOLE_1:1; :: thesis: verum

end;

A44: D ` = {(0. (TOP-REAL 2))} by JGRAPH_3:30;
then ex h being Function of ((TOP-REAL 2) | D),((TOP-REAL 2) | D) st
( h = (sn -FanMorphE ) | D & h is continuous ) by A1, A2, Th107;
hence ex h being Function of (TOP-REAL 2),(TOP-REAL 2) st
( h = sn -FanMorphE & h is continuous ) by A3, A44, A4, A15, JGRAPH_3:13; :: thesis: verum