let X be RealNormSpace; :: thesis: for A being closed-interval Subset of REAL
for r being Real
for f, h being Function of A,the carrier of X st h = r (#) f & f is integrable holds
( h is integrable & integral h = r * (integral f) )
let A be closed-interval Subset of REAL ; :: thesis: for r being Real
for f, h being Function of A,the carrier of X st h = r (#) f & f is integrable holds
( h is integrable & integral h = r * (integral f) )
let r be Real; :: thesis: for f, h being Function of A,the carrier of X st h = r (#) f & f is integrable holds
( h is integrable & integral h = r * (integral f) )
let f, h be Function of A,the carrier of X; :: thesis: ( h = r (#) f & f is integrable implies ( h is integrable & integral h = r * (integral f) ) )
assume AS: ( h = r (#) f & f is integrable ) ; :: thesis: ( h is integrable & integral h = r * (integral f) )
P01: ( dom h = A & dom f = A ) by FUNCT_2:def 1;
P0: now
let T be DivSequence of A; :: thesis: for S being middle_volume_Sequence of h,T st delta T is convergent & lim (delta T) = 0 holds
( middle_sum h,S is convergent & lim (middle_sum h,S) = r * (integral f) )
let S be middle_volume_Sequence of h,T; :: thesis: ( delta T is convergent & lim (delta T) = 0 implies ( middle_sum h,S is convergent & lim (middle_sum h,S) = r * (integral f) ) )
assume AS1: ( delta T is convergent & lim (delta T) = 0 ) ; :: thesis: ( middle_sum h,S is convergent & lim (middle_sum h,S) = r * (integral f) )
defpred S1[ Element of NAT , set ] means ex p being FinSequence of REAL st
( p = $2 & len p = len (T . $1) & ( for i being Nat st i in dom (T . $1) holds
( p . i in dom (h | (divset (T . $1),i)) & ex z being Point of X st
( z = (h | (divset (T . $1),i)) . (p . i) & (S . $1) . i = (vol (divset (T . $1),i)) * z ) ) ) );
P1: for k being Element of NAT ex p being Element of REAL * st S1[k,p]
proof
let k be Element of NAT ; :: thesis: ex p being Element of REAL * st S1[k,p]
defpred S2[ Nat, set ] means ( $2 in dom (h | (divset (T . k),$1)) & ex c being Point of X st
( c = (h | (divset (T . k),$1)) . $2 & (S . k) . $1 = (vol (divset (T . k),$1)) * c ) );
A1: Seg (len (T . k)) = dom (T . k) by FINSEQ_1:def 3;
A2: for i being Nat st i in Seg (len (T . k)) holds
ex x being Element of REAL st S2[i,x]
proof
let i be Nat; :: thesis: ( i in Seg (len (T . k)) implies ex x being Element of REAL st S2[i,x] )
assume i in Seg (len (T . k)) ; :: thesis: ex x being Element of REAL st S2[i,x]
then i in dom (T . k) by FINSEQ_1:def 3;
then consider c being Point of X such that
A21: ( c in rng (h | (divset (T . k),i)) & (S . k) . i = (vol (divset (T . k),i)) * c ) by Def5;
consider x being set such that
A22: ( x in dom (h | (divset (T . k),i)) & c = (h | (divset (T . k),i)) . x ) by A21, FUNCT_1:def 5;
( x in dom h & x in divset (T . k),i ) by A22, RELAT_1:86;
then reconsider x = x as Element of REAL ;
take x ; :: thesis: S2[i,x]
thus S2[i,x] by A21, A22; :: thesis: verum
end;
consider p being FinSequence of REAL such that
A3: ( dom p = Seg (len (T . k)) & ( for i being Nat st i in Seg (len (T . k)) holds
S2[i,p . i] ) ) from FINSEQ_1:sch 5(A2);
 take p ; :: thesis: ( p is Element of REAL * & S1[k,p] )
len p = len (T . k) by A3, FINSEQ_1:def 3;
hence ( p is Element of REAL * & S1[k,p] ) by A3, A1, FINSEQ_1:def 11; :: thesis: verum
end;
consider F being Function of NAT ,(REAL * ) such that
P2: for x being Element of NAT holds S1[x,F . x] from FUNCT_2:sch 10(P1);
defpred S2[ Element of NAT , set ] means ex q being middle_volume of f,T . $1 st
( q = $2 & ( for i being Nat st i in dom (T . $1) holds
ex z being Point of X st
( (F . $1) . i in dom (f | (divset (T . $1),i)) & z = (f | (divset (T . $1),i)) . ((F . $1) . i) & q . i = (vol (divset (T . $1),i)) * z ) ) );
P3: for k being Element of NAT ex y being Element of the carrier of X * st S2[k,y]
proof
let k be Element of NAT ; :: thesis: ex y being Element of the carrier of X * st S2[k,y]
defpred S3[ Nat, set ] means ex c being Point of X st
( (F . k) . $1 in dom (f | (divset (T . k),$1)) & c = (f | (divset (T . k),$1)) . ((F . k) . $1) & $2 = (vol (divset (T . k),$1)) * c );
A1: Seg (len (T . k)) = dom (T . k) by FINSEQ_1:def 3;
A2: for i being Nat st i in Seg (len (T . k)) holds
ex x being Element of the carrier of X st S3[i,x]
proof
let i be Nat; :: thesis: ( i in Seg (len (T . k)) implies ex x being Element of the carrier of X st S3[i,x] )
assume i in Seg (len (T . k)) ; :: thesis: ex x being Element of the carrier of X st S3[i,x]
then A21: i in dom (T . k) by FINSEQ_1:def 3;
consider p being FinSequence of REAL such that
A22: ( p = F . k & len p = len (T . k) & ( for i being Nat st i in dom (T . k) holds
( p . i in dom (h | (divset (T . k),i)) & ex z being Point of X st
( z = (h | (divset (T . k),i)) . (p . i) & (S . k) . i = (vol (divset (T . k),i)) * z ) ) ) ) by P2;
p . i in dom (h | (divset (T . k),i)) by A21, A22;
then A23: ( p . i in dom h & p . i in divset (T . k),i ) by RELAT_1:86;
then p . i in dom (f | (divset (T . k),i)) by RELAT_1:86, P01;
then (f | (divset (T . k),i)) . (p . i) in rng (f | (divset (T . k),i)) by FUNCT_1:12;
then reconsider x = (f | (divset (T . k),i)) . (p . i) as Element of the carrier of X ;
A24: (F . k) . i in dom (f | (divset (T . k),i)) by A22, A23, RELAT_1:86, P01;
(vol (divset (T . k),i)) * x is Element of the carrier of X ;
hence ex x being Element of the carrier of X st S3[i,x] by A22, A24; :: thesis: verum
end;
consider q being FinSequence of the carrier of X such that
A3: ( dom q = Seg (len (T . k)) & ( for i being Nat st i in Seg (len (T . k)) holds
S3[i,q . i] ) ) from FINSEQ_1:sch 5(A2);
 A4: len q = len (T . k) by A3, FINSEQ_1:def 3;
now
let i be Nat; :: thesis: ( i in dom (T . k) implies ex c being Point of X st
( c in rng (f | (divset (T . k),i)) & q . i = (vol (divset (T . k),i)) * c ) )
assume i in dom (T . k) ; :: thesis: ex c being Point of X st
( c in rng (f | (divset (T . k),i)) & q . i = (vol (divset (T . k),i)) * c )
then i in Seg (len (T . k)) by FINSEQ_1:def 3;
then consider c being Point of X such that
A41: ( (F . k) . i in dom (f | (divset (T . k),i)) & c = (f | (divset (T . k),i)) . ((F . k) . i) & q . i = (vol (divset (T . k),i)) * c ) by A3;
thus ex c being Point of X st
( c in rng (f | (divset (T . k),i)) & q . i = (vol (divset (T . k),i)) * c ) by A41, FUNCT_1:12; :: thesis: verum
end;
then reconsider q = q as middle_volume of f,T . k by A4, Def5;
q is Element of the carrier of X * by FINSEQ_1:def 11;
hence ex y being Element of the carrier of X * st S2[k,y] by A1, A3; :: thesis: verum
end;
consider Sf being Function of NAT ,(the carrier of X * ) such that
P4: for x being Element of NAT holds S2[x,Sf . x] from FUNCT_2:sch 10(P3);
now
let k be Element of NAT ; :: thesis: Sf . k is middle_volume of f,T . k
ex q being middle_volume of f,T . k st
( q = Sf . k & ( for i being Nat st i in dom (T . k) holds
ex z being Point of X st
( (F . k) . i in dom (f | (divset (T . k),i)) & z = (f | (divset (T . k),i)) . ((F . k) . i) & q . i = (vol (divset (T . k),i)) * z ) ) ) by P4;
hence Sf . k is middle_volume of f,T . k ; :: thesis: verum
end;
then reconsider Sf = Sf as middle_volume_Sequence of f,T by Def7;
integral f is Point of X ;
then P5: middle_sum f,Sf is convergent by Def14, AS, AS1;
P6: r * (middle_sum f,Sf) = middle_sum h,S
proof
now
let n be Element of NAT ; :: thesis: r * ((middle_sum f,Sf) . n) = (middle_sum h,S) . n
consider p being FinSequence of REAL such that
A01: ( p = F . n & len p = len (T . n) & ( for i being Nat st i in dom (T . n) holds
( p . i in dom (h | (divset (T . n),i)) & ex z being Point of X st
( z = (h | (divset (T . n),i)) . (p . i) & (S . n) . i = (vol (divset (T . n),i)) * z ) ) ) ) by P2;
consider q being middle_volume of f,T . n such that
A02: ( q = Sf . n & ( for i being Nat st i in dom (T . n) holds
ex z being Point of X st
( (F . n) . i in dom (f | (divset (T . n),i)) & z = (f | (divset (T . n),i)) . ((F . n) . i) & q . i = (vol (divset (T . n),i)) * z ) ) ) by P4;
( len (Sf . n) = len (T . n) & len (S . n) = len (T . n) ) by Def5;
then A04: ( dom (Sf . n) = dom (T . n) & dom (S . n) = dom (T . n) ) by FINSEQ_3:31;
now
let x be Element of NAT ; :: thesis: ( x in dom (S . n) implies (S . n) /. x = r * ((Sf . n) /. x) )
assume K715: x in dom (S . n) ; :: thesis: (S . n) /. x = r * ((Sf . n) /. x)
reconsider i = x as Nat ;
consider t being Point of X such that
K001: ( t = (h | (divset (T . n),i)) . ((F . n) . i) & (S . n) . i = (vol (divset (T . n),i)) * t ) by K715, A04, A01;
consider z being Point of X such that
K002: ( (F . n) . i in dom (f | (divset (T . n),i)) & z = (f | (divset (T . n),i)) . ((F . n) . i) & q . i = (vol (divset (T . n),i)) * z ) by A02, K715, A04;
K003: (F . n) . i in divset (T . n),i by K002, RELAT_1:86;
(F . n) . i in A by K002;
then K004: (F . n) . i in dom h by FUNCT_2:def 1;
K005: (F . n) . i in dom f by K002, RELAT_1:86;
K006: f /. ((F . n) . i) = f . ((F . n) . i) by PARTFUN1:def 8, K005
.= z by K002, K003, FUNCT_1:72 ;
K007: t = (h | (divset (T . n),i)) . ((F . n) . i) by K001
.= h . ((F . n) . i) by K003, FUNCT_1:72
.= h /. ((F . n) . i) by PARTFUN1:def 8, K004
.= r * (f /. ((F . n) . i)) by VFUNCT_1:def 4, K004, AS
.= r * z by K006 ;
K008: (vol (divset (T . n),i)) * z = (Sf . n) . x by K002, A02
.= (Sf . n) /. x by K715, A04, PARTFUN1:def 8 ;
thus (S . n) /. x = (S . n) . x by K715, PARTFUN1:def 8
.= (vol (divset (T . n),i)) * t by K001
.= (vol (divset (T . n),i)) * (r * z) by K007
.= ((vol (divset (T . n),i)) * r) * z by RLVECT_1:def 10
.= r * ((vol (divset (T . n),i)) * z) by RLVECT_1:def 10
.= r * ((Sf . n) /. x) by K008 ; :: thesis: verum
end;
then A05: r (#) (Sf . n) = S . n by VFUNCT_1:def 4, A04;
thus r * ((middle_sum f,Sf) . n) = r * (middle_sum f,(Sf . n)) by Def8
.= r * (Sum (Sf . n))
.= Sum (S . n) by A05, SM3
.= middle_sum h,(S . n)
.= (middle_sum h,S) . n by Def8 ; :: thesis: verum
end;
hence r * (middle_sum f,Sf) = middle_sum h,S by NORMSP_1:def 8; :: thesis: verum
end;
P7: lim (r * (middle_sum f,Sf)) = r * (lim (middle_sum f,Sf)) by NORMSP_1:45, P5
.= r * (integral f) by Def14, AS, AS1 ;
thus middle_sum h,S is convergent by P5, P6, NORMSP_1:37; :: thesis: lim (middle_sum h,S) = r * (integral f)
thus lim (middle_sum h,S) = r * (integral f) by P6, P7; :: thesis: verum
end;
hence h is integrable by Def13; :: thesis: integral h = r * (integral f)
hence integral h = r * (integral f) by Def14, P0; :: thesis: verum