let A be closed-interval Subset of REAL ; :: thesis: for f1, f2, f being PartFunc of REAL ,REAL
for Z being open Subset of REAL st A c= Z & Z c= dom (ln * (f1 + f2)) & f = (id Z) / (f1 + f2) & f2 = #Z 2 & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z = dom f & f | A is continuous holds
integral f,A = (((1 / 2) (#) (ln * (f1 + f2))) . (upper_bound A)) - (((1 / 2) (#) (ln * (f1 + f2))) . (lower_bound A))
let f1, f2, f be PartFunc of REAL ,REAL ; :: thesis: for Z being open Subset of REAL st A c= Z & Z c= dom (ln * (f1 + f2)) & f = (id Z) / (f1 + f2) & f2 = #Z 2 & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z = dom f & f | A is continuous holds
integral f,A = (((1 / 2) (#) (ln * (f1 + f2))) . (upper_bound A)) - (((1 / 2) (#) (ln * (f1 + f2))) . (lower_bound A))
let Z be open Subset of REAL ; :: thesis: ( A c= Z & Z c= dom (ln * (f1 + f2)) & f = (id Z) / (f1 + f2) & f2 = #Z 2 & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z = dom f & f | A is continuous implies integral f,A = (((1 / 2) (#) (ln * (f1 + f2))) . (upper_bound A)) - (((1 / 2) (#) (ln * (f1 + f2))) . (lower_bound A)) )
assume A1: ( A c= Z & Z c= dom (ln * (f1 + f2)) & f = (id Z) / (f1 + f2) & f2 = #Z 2 & ( for x being Real st x in Z holds
f1 . x = 1 ) & Z = dom f & f | A is continuous ) ; :: thesis: integral f,A = (((1 / 2) (#) (ln * (f1 + f2))) . (upper_bound A)) - (((1 / 2) (#) (ln * (f1 + f2))) . (lower_bound A))
then A2: ( f is_integrable_on A & f | A is bounded ) by INTEGRA5:10, INTEGRA5:11;
B: Z c= dom ((1 / 2) (#) (ln * (f1 + f2))) by A1, VALUED_1:def 5;
Z c= (dom (id Z)) /\ ((dom (f1 + f2)) \ ((f1 + f2) " {0 })) by A1, RFUNCT_1:def 4;
then Z c= (dom (f1 + f2)) \ ((f1 + f2) " {0 }) by XBOOLE_1:18;
then AB: Z c= dom ((f1 + f2) ^ ) by RFUNCT_1:def 8;
dom ((f1 + f2) ^ ) c= dom (f1 + f2) by RFUNCT_1:11;
then BB: Z c= dom (f1 + f2) by XBOOLE_1:1, AB;
A3: (1 / 2) (#) (ln * (f1 + f2)) is_differentiable_on Z by A1, B, SIN_COS9:102;
B1: for x being Real st x in Z holds
f . x = x / (1 + (x ^2 ))

proof

let x be Real; :: thesis: ( x in Z implies f . x = x / (1 + (x ^2 )) )
assume B2: x in Z ; :: thesis: f . x = x / (1 + (x ^2 ))
then ((id Z) / (f1 + f2)) . x = ((id Z) . x) / ((f1 + f2) . x) by RFUNCT_1:def 4, A1
.= x / ((f1 + f2) . x) by B2, FUNCT_1:35
.= x / ((f1 . x) + (f2 . x)) by VALUED_1:def 1, BB, B2
.= x / (1 + ((#Z 2) . x)) by A1, B2
.= x / (1 + (x #Z 2)) by TAYLOR_1:def 1
.= x / (1 + (x ^2 )) by FDIFF_7:1 ;
hence f . x = x / (1 + (x ^2 )) by A1; :: thesis: verum

end;

A4: for x being Real st x in dom (((1 / 2) (#) (ln * (f1 + f2))) `| Z) holds
(((1 / 2) (#) (ln * (f1 + f2))) `| Z) . x = f . x

proof

let x be Real; :: thesis: ( x in dom (((1 / 2) (#) (ln * (f1 + f2))) `| Z) implies (((1 / 2) (#) (ln * (f1 + f2))) `| Z) . x = f . x )
assume x in dom (((1 / 2) (#) (ln * (f1 + f2))) `| Z) ; :: thesis: (((1 / 2) (#) (ln * (f1 + f2))) `| Z) . x = f . x
then A5: x in Z by A3, FDIFF_1:def 8;
then (((1 / 2) (#) (ln * (f1 + f2))) `| Z) . x = x / (1 + (x ^2 )) by A1, B, SIN_COS9:102
.= f . x by A5, B1 ;
hence (((1 / 2) (#) (ln * (f1 + f2))) `| Z) . x = f . x ; :: thesis: verum

end;

dom (((1 / 2) (#) (ln * (f1 + f2))) `| Z) = dom f by A1, A3, FDIFF_1:def 8;
then ((1 / 2) (#) (ln * (f1 + f2))) `| Z = f by A4, PARTFUN1:34;
hence integral f,A = (((1 / 2) (#) (ln * (f1 + f2))) . (upper_bound A)) - (((1 / 2) (#) (ln * (f1 + f2))) . (lower_bound A)) by A1, A2, A3, INTEGRA5:13; :: thesis: verum