let A be closed-interval Subset of REAL ; :: thesis: for f1, f being PartFunc of REAL ,REAL
for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
( f1 . x = 1 & arctan . x > 0 ) ) & f = ((f1 + (#Z 2)) (#) arctan ) ^ & Z c= ].(- 1),1.[ & Z c= dom (ln * arctan ) & Z = dom f & f | A is continuous holds
integral f,A = ((ln * arctan ) . (upper_bound A)) - ((ln * arctan ) . (lower_bound A))
let f1, f be PartFunc of REAL ,REAL ; :: thesis: for Z being open Subset of REAL st A c= Z & ( for x being Real st x in Z holds
( f1 . x = 1 & arctan . x > 0 ) ) & f = ((f1 + (#Z 2)) (#) arctan ) ^ & Z c= ].(- 1),1.[ & Z c= dom (ln * arctan ) & Z = dom f & f | A is continuous holds
integral f,A = ((ln * arctan ) . (upper_bound A)) - ((ln * arctan ) . (lower_bound A))
let Z be open Subset of REAL ; :: thesis: ( A c= Z & ( for x being Real st x in Z holds
( f1 . x = 1 & arctan . x > 0 ) ) & f = ((f1 + (#Z 2)) (#) arctan ) ^ & Z c= ].(- 1),1.[ & Z c= dom (ln * arctan ) & Z = dom f & f | A is continuous implies integral f,A = ((ln * arctan ) . (upper_bound A)) - ((ln * arctan ) . (lower_bound A)) )
assume A1: ( A c= Z & ( for x being Real st x in Z holds
( f1 . x = 1 & arctan . x > 0 ) ) & f = ((f1 + (#Z 2)) (#) arctan ) ^ & Z c= ].(- 1),1.[ & Z c= dom (ln * arctan ) & Z = dom f & f | A is continuous ) ; :: thesis: integral f,A = ((ln * arctan ) . (upper_bound A)) - ((ln * arctan ) . (lower_bound A))
then A2: ( f is_integrable_on A & f | A is bounded ) by INTEGRA5:10, INTEGRA5:11;
A3: for x being Real st x in Z holds
arctan . x > 0 by A1;
then A4: ln * arctan is_differentiable_on Z by A1, SIN_COS9:89;
Z c= dom ((f1 + (#Z 2)) (#) arctan ) by RFUNCT_1:11, A1;
then Z c= (dom (f1 + (#Z 2))) /\ (dom arctan ) by VALUED_1:def 4;
then A5: Z c= dom (f1 + (#Z 2)) by XBOOLE_1:18;
B: for x being Real st x in Z holds
f . x = 1 / ((1 + (x ^2 )) * (arctan . x))

proof

let x be Real; :: thesis: ( x in Z implies f . x = 1 / ((1 + (x ^2 )) * (arctan . x)) )
assume C: x in Z ; :: thesis: f . x = 1 / ((1 + (x ^2 )) * (arctan . x))
then (((f1 + (#Z 2)) (#) arctan ) ^ ) . x = 1 / (((f1 + (#Z 2)) (#) arctan ) . x) by RFUNCT_1:def 8, A1
.= 1 / (((f1 + (#Z 2)) . x) * (arctan . x)) by VALUED_1:5
.= 1 / (((f1 . x) + ((#Z 2) . x)) * (arctan . x)) by VALUED_1:def 1, A5, C
.= 1 / (((f1 . x) + (x #Z 2)) * (arctan . x)) by TAYLOR_1:def 1
.= 1 / ((1 + (x #Z 2)) * (arctan . x)) by A1, C
.= 1 / ((1 + (x ^2 )) * (arctan . x)) by FDIFF_7:1 ;
hence f . x = 1 / ((1 + (x ^2 )) * (arctan . x)) by A1; :: thesis: verum

end;

A6: for x being Real st x in dom ((ln * arctan ) `| Z) holds
((ln * arctan ) `| Z) . x = f . x

proof

let x be Real; :: thesis: ( x in dom ((ln * arctan ) `| Z) implies ((ln * arctan ) `| Z) . x = f . x )
assume x in dom ((ln * arctan ) `| Z) ; :: thesis: ((ln * arctan ) `| Z) . x = f . x
then A7: x in Z by A4, FDIFF_1:def 8;
then ((ln * arctan ) `| Z) . x = 1 / ((1 + (x ^2 )) * (arctan . x)) by A1, A3, SIN_COS9:89
.= f . x by B, A7 ;
hence ((ln * arctan ) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((ln * arctan ) `| Z) = dom f by A1, A4, FDIFF_1:def 8;
then (ln * arctan ) `| Z = f by A6, PARTFUN1:34;
hence integral f,A = ((ln * arctan ) . (upper_bound A)) - ((ln * arctan ) . (lower_bound A)) by A1, A2, A4, INTEGRA5:13; :: thesis: verum