let A be closed-interval Subset of REAL ; :: thesis: for f being PartFunc of REAL ,REAL
for Z being open Subset of REAL st A c= Z & f = ((cos / sin ) / (id Z)) - (ln / (sin ^2 )) & Z c= dom (ln (#) cot ) & Z = dom f & f | A is continuous holds
integral f,A = ((ln (#) cot ) . (upper_bound A)) - ((ln (#) cot ) . (lower_bound A))
let f be PartFunc of REAL ,REAL ; :: thesis: for Z being open Subset of REAL st A c= Z & f = ((cos / sin ) / (id Z)) - (ln / (sin ^2 )) & Z c= dom (ln (#) cot ) & Z = dom f & f | A is continuous holds
integral f,A = ((ln (#) cot ) . (upper_bound A)) - ((ln (#) cot ) . (lower_bound A))
let Z be open Subset of REAL ; :: thesis: ( A c= Z & f = ((cos / sin ) / (id Z)) - (ln / (sin ^2 )) & Z c= dom (ln (#) cot ) & Z = dom f & f | A is continuous implies integral f,A = ((ln (#) cot ) . (upper_bound A)) - ((ln (#) cot ) . (lower_bound A)) )
assume A1: ( A c= Z & f = ((cos / sin ) / (id Z)) - (ln / (sin ^2 )) & Z c= dom (ln (#) cot ) & Z = dom f & f | A is continuous ) ; :: thesis: integral f,A = ((ln (#) cot ) . (upper_bound A)) - ((ln (#) cot ) . (lower_bound A))
then A2: ( f is_integrable_on A & f | A is bounded ) by INTEGRA5:10, INTEGRA5:11;
A3: ln (#) cot is_differentiable_on Z by A1, FDIFF_8:33;
Z = (dom ((cos / sin ) / (id Z))) /\ (dom (ln / (sin ^2 ))) by VALUED_1:12, A1;
then A4: ( Z c= dom ((cos / sin ) / (id Z)) & Z c= dom (ln / (sin ^2 )) ) by XBOOLE_1:18;
dom ((cos / sin ) / (id Z)) c= (dom (cos / sin )) /\ ((dom (id Z)) \ ((id Z) " {0 })) by RFUNCT_1:def 4;
then dom ((cos / sin ) / (id Z)) c= dom (cos / sin ) by XBOOLE_1:18;
then A5: Z c= dom (cos / sin ) by A4, XBOOLE_1:1;
B1: for x being Real st x in Z holds
f . x = (((cos . x) / (sin . x)) / x) - ((ln . x) / ((sin . x) ^2 ))

proof

let x be Real; :: thesis: ( x in Z implies f . x = (((cos . x) / (sin . x)) / x) - ((ln . x) / ((sin . x) ^2 )) )
assume B2: x in Z ; :: thesis: f . x = (((cos . x) / (sin . x)) / x) - ((ln . x) / ((sin . x) ^2 ))
then (((cos / sin ) / (id Z)) - (ln / (sin ^2 ))) . x = (((cos / sin ) / (id Z)) . x) - ((ln / (sin ^2 )) . x) by VALUED_1:13, A1
.= (((cos / sin ) . x) / ((id Z) . x)) - ((ln / (sin ^2 )) . x) by RFUNCT_1:def 4, B2, A4
.= (((cos . x) / (sin . x)) / ((id Z) . x)) - ((ln / (sin ^2 )) . x) by A5, RFUNCT_1:def 4, B2
.= (((cos . x) / (sin . x)) / x) - ((ln / (sin ^2 )) . x) by FUNCT_1:35, B2
.= (((cos . x) / (sin . x)) / x) - ((ln . x) / ((sin ^2 ) . x)) by RFUNCT_1:def 4, B2, A4
.= (((cos . x) / (sin . x)) / x) - ((ln . x) / ((sin . x) ^2 )) by VALUED_1:11 ;
hence f . x = (((cos . x) / (sin . x)) / x) - ((ln . x) / ((sin . x) ^2 )) by A1; :: thesis: verum

end;

A6: for x being Real st x in dom ((ln (#) cot ) `| Z) holds
((ln (#) cot ) `| Z) . x = f . x

proof

let x be Real; :: thesis: ( x in dom ((ln (#) cot ) `| Z) implies ((ln (#) cot ) `| Z) . x = f . x )
assume x in dom ((ln (#) cot ) `| Z) ; :: thesis: ((ln (#) cot ) `| Z) . x = f . x
then A7: x in Z by A3, FDIFF_1:def 8;
then ((ln (#) cot ) `| Z) . x = (((cos . x) / (sin . x)) / x) - ((ln . x) / ((sin . x) ^2 )) by A1, FDIFF_8:33
.= f . x by A7, B1 ;
hence ((ln (#) cot ) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((ln (#) cot ) `| Z) = dom f by A1, A3, FDIFF_1:def 8;
then (ln (#) cot ) `| Z = f by A6, PARTFUN1:34;
hence integral f,A = ((ln (#) cot ) . (upper_bound A)) - ((ln (#) cot ) . (lower_bound A)) by A1, A2, FDIFF_8:33, INTEGRA5:13; :: thesis: verum