let A be closed-interval Subset of REAL ; :: thesis: for f, f1 being PartFunc of REAL ,REAL
for Z being open Subset of REAL st A c= Z & f = (- ((cos / sin ) / f1)) - (((id Z) ^ ) / (sin ^2 )) & f1 = #Z 2 & Z c= dom (((id Z) ^ ) (#) cot ) & Z = dom f & f | A is continuous holds
integral f,A = ((((id Z) ^ ) (#) cot ) . (upper_bound A)) - ((((id Z) ^ ) (#) cot ) . (lower_bound A))
let f, f1 be PartFunc of REAL ,REAL ; :: thesis: for Z being open Subset of REAL st A c= Z & f = (- ((cos / sin ) / f1)) - (((id Z) ^ ) / (sin ^2 )) & f1 = #Z 2 & Z c= dom (((id Z) ^ ) (#) cot ) & Z = dom f & f | A is continuous holds
integral f,A = ((((id Z) ^ ) (#) cot ) . (upper_bound A)) - ((((id Z) ^ ) (#) cot ) . (lower_bound A))
let Z be open Subset of REAL ; :: thesis: ( A c= Z & f = (- ((cos / sin ) / f1)) - (((id Z) ^ ) / (sin ^2 )) & f1 = #Z 2 & Z c= dom (((id Z) ^ ) (#) cot ) & Z = dom f & f | A is continuous implies integral f,A = ((((id Z) ^ ) (#) cot ) . (upper_bound A)) - ((((id Z) ^ ) (#) cot ) . (lower_bound A)) )
assume A1: ( A c= Z & f = (- ((cos / sin ) / f1)) - (((id Z) ^ ) / (sin ^2 )) & f1 = #Z 2 & Z c= dom (((id Z) ^ ) (#) cot ) & Z = dom f & f | A is continuous ) ; :: thesis: integral f,A = ((((id Z) ^ ) (#) cot ) . (upper_bound A)) - ((((id Z) ^ ) (#) cot ) . (lower_bound A))
then A2: ( f is_integrable_on A & f | A is bounded ) by INTEGRA5:10, INTEGRA5:11;
set g = id Z;
Z c= dom (((id Z) ^ ) (#) cot ) by A1;
then Z c= (dom ((id Z) ^ )) /\ (dom cot ) by VALUED_1:def 4;
then B2: Z c= dom ((id Z) ^ ) by XBOOLE_1:18;
A3: not 0 in Z

proof

assume K: 0 in Z ; :: thesis: contradiction
dom ((id Z) ^ ) = (dom (id Z)) \ ((id Z) " {0 }) by RFUNCT_1:def 8
.= (dom (id Z)) \ {0 } by Lm0, K ;
then not 0 in {0 } by XBOOLE_0:def 5, K, B2;
hence contradiction by TARSKI:def 1; :: thesis: verum

end;

then A4: ((id Z) ^ ) (#) cot is_differentiable_on Z by A1, FDIFF_8:35;
dom f = (dom (- ((cos / sin ) / f1))) /\ (dom (((id Z) ^ ) / (sin ^2 ))) by VALUED_1:12, A1;
then A5: ( dom f c= dom (- ((cos / sin ) / f1)) & dom f c= dom (((id Z) ^ ) / (sin ^2 )) ) by XBOOLE_1:18;
then dom f c= dom ((cos / sin ) / f1) by VALUED_1:8;
then A7: ( Z c= dom ((cos / sin ) / f1) & Z c= dom (((id Z) ^ ) / (sin ^2 )) ) by A1, A5;
dom ((cos / sin ) / f1) = (dom (cos / sin )) /\ ((dom f1) \ (f1 " {0 })) by RFUNCT_1:def 4;
then A8: Z c= dom (cos / sin ) by A7, XBOOLE_1:18;
dom (((id Z) ^ ) / (sin ^2 )) c= (dom ((id Z) ^ )) /\ ((dom (sin ^2 )) \ ((sin ^2 ) " {0 })) by RFUNCT_1:def 4;
then ( dom (((id Z) ^ ) / (sin ^2 )) c= dom ((id Z) ^ ) & dom (((id Z) ^ ) / (sin ^2 )) c= (dom (sin ^2 )) \ ((sin ^2 ) " {0 }) ) by XBOOLE_1:18;
then A9: ( Z c= dom ((id Z) ^ ) & Z c= (dom (sin ^2 )) \ ((sin ^2 ) " {0 }) ) by A7, XBOOLE_1:1;
B3: for x being Real st x in Z holds
f . x = (- (((cos . x) / (sin . x)) / (x ^2 ))) - ((1 / x) / ((sin . x) ^2 ))

proof

let x be Real; :: thesis: ( x in Z implies f . x = (- (((cos . x) / (sin . x)) / (x ^2 ))) - ((1 / x) / ((sin . x) ^2 )) )
assume B4: x in Z ; :: thesis: f . x = (- (((cos . x) / (sin . x)) / (x ^2 ))) - ((1 / x) / ((sin . x) ^2 ))
then ((- ((cos / sin ) / f1)) - (((id Z) ^ ) / (sin ^2 ))) . x = ((- ((cos / sin ) / f1)) . x) - ((((id Z) ^ ) / (sin ^2 )) . x) by VALUED_1:13, A1
.= (- (((cos / sin ) / f1) . x)) - ((((id Z) ^ ) / (sin ^2 )) . x) by VALUED_1:8
.= (- (((cos / sin ) . x) / (f1 . x))) - ((((id Z) ^ ) / (sin ^2 )) . x) by RFUNCT_1:def 4, B4, A7
.= (- (((cos . x) / (sin . x)) / (f1 . x))) - ((((id Z) ^ ) / (sin ^2 )) . x) by A8, RFUNCT_1:def 4, B4
.= (- (((cos . x) / (sin . x)) / (f1 . x))) - ((((id Z) ^ ) . x) / ((sin ^2 ) . x)) by A7, RFUNCT_1:def 4, B4
.= (- (((cos . x) / (sin . x)) / (f1 . x))) - ((((id Z) . x) " ) / ((sin ^2 ) . x)) by RFUNCT_1:def 8, A9, B4
.= (- (((cos . x) / (sin . x)) / (f1 . x))) - ((1 / x) / ((sin ^2 ) . x)) by FUNCT_1:35, B4
.= (- (((cos . x) / (sin . x)) / (f1 . x))) - ((1 / x) / ((sin . x) ^2 )) by VALUED_1:11
.= (- (((cos . x) / (sin . x)) / (x #Z 2))) - ((1 / x) / ((sin . x) ^2 )) by TAYLOR_1:def 1, A1
.= (- (((cos . x) / (sin . x)) / (x ^2 ))) - ((1 / x) / ((sin . x) ^2 )) by FDIFF_7:1 ;
hence f . x = (- (((cos . x) / (sin . x)) / (x ^2 ))) - ((1 / x) / ((sin . x) ^2 )) by A1; :: thesis: verum

end;

A10: for x being Real st x in dom ((((id Z) ^ ) (#) cot ) `| Z) holds
((((id Z) ^ ) (#) cot ) `| Z) . x = f . x

proof

let x be Real; :: thesis: ( x in dom ((((id Z) ^ ) (#) cot ) `| Z) implies ((((id Z) ^ ) (#) cot ) `| Z) . x = f . x )
assume x in dom ((((id Z) ^ ) (#) cot ) `| Z) ; :: thesis: ((((id Z) ^ ) (#) cot ) `| Z) . x = f . x
then A11: x in Z by A4, FDIFF_1:def 8;
then ((((id Z) ^ ) (#) cot ) `| Z) . x = (- (((cos . x) / (sin . x)) / (x ^2 ))) - ((1 / x) / ((sin . x) ^2 )) by A1, A3, FDIFF_8:35
.= f . x by B3, A11 ;
hence ((((id Z) ^ ) (#) cot ) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((((id Z) ^ ) (#) cot ) `| Z) = dom f by A1, A4, FDIFF_1:def 8;
then (((id Z) ^ ) (#) cot ) `| Z = f by A10, PARTFUN1:34;
hence integral f,A = ((((id Z) ^ ) (#) cot ) . (upper_bound A)) - ((((id Z) ^ ) (#) cot ) . (lower_bound A)) by A1, A2, A4, INTEGRA5:13; :: thesis: verum