let A be closed-interval Subset of REAL ; :: thesis: for f being PartFunc of REAL ,REAL
for Z being open Subset of REAL st A c= Z & Z = dom f & f = exp_R (#) (sin * exp_R ) holds
integral f,A = ((- (cos * exp_R )) . (upper_bound A)) - ((- (cos * exp_R )) . (lower_bound A))
let f be PartFunc of REAL ,REAL ; :: thesis: for Z being open Subset of REAL st A c= Z & Z = dom f & f = exp_R (#) (sin * exp_R ) holds
integral f,A = ((- (cos * exp_R )) . (upper_bound A)) - ((- (cos * exp_R )) . (lower_bound A))
let Z be open Subset of REAL ; :: thesis: ( A c= Z & Z = dom f & f = exp_R (#) (sin * exp_R ) implies integral f,A = ((- (cos * exp_R )) . (upper_bound A)) - ((- (cos * exp_R )) . (lower_bound A)) )
assume A1: ( A c= Z & Z = dom f & f = exp_R (#) (sin * exp_R ) ) ; :: thesis: integral f,A = ((- (cos * exp_R )) . (upper_bound A)) - ((- (cos * exp_R )) . (lower_bound A))
then Z = (dom exp_R ) /\ (dom (sin * exp_R )) by VALUED_1:def 4;
then A4: ( Z c= dom exp_R & Z c= dom (sin * exp_R ) ) by XBOOLE_1:18;
for y being set st y in Z holds
y in dom (cos * exp_R )

proof

let y be set ; :: thesis: ( y in Z implies y in dom (cos * exp_R ) )
assume y in Z ; :: thesis: y in dom (cos * exp_R )
then ( y in dom exp_R & exp_R . y in dom cos ) by A4, SIN_COS:27;
hence y in dom (cos * exp_R ) by FUNCT_1:21; :: thesis: verum

end;

then B6: Z c= dom (cos * exp_R ) by TARSKI:def 3;
A5: sin * exp_R is_differentiable_on Z by A4, FDIFF_7:34;
exp_R is_differentiable_on Z by FDIFF_1:34, TAYLOR_1:16;
then f | Z is continuous by FDIFF_1:33, A1, A5, FDIFF_1:29;
then f | A is continuous by A1, FCONT_1:17;
then A9: ( f is_integrable_on A & f | A is bounded ) by A1, INTEGRA5:10, INTEGRA5:11;
A10: cos * exp_R is_differentiable_on Z by B6, FDIFF_7:35;
A11: Z c= dom (- (cos * exp_R )) by B6, VALUED_1:8;
then A12: (- 1) (#) (cos * exp_R ) is_differentiable_on Z by A10, FDIFF_1:28, X;
A13: for x being Real st x in Z holds
((- (cos * exp_R )) `| Z) . x = (exp_R . x) * (sin . (exp_R . x))

proof

let x be Real; :: thesis: ( x in Z implies ((- (cos * exp_R )) `| Z) . x = (exp_R . x) * (sin . (exp_R . x)) )
assume A14: x in Z ; :: thesis: ((- (cos * exp_R )) `| Z) . x = (exp_R . x) * (sin . (exp_R . x))
A15: exp_R is_differentiable_in x by SIN_COS:70;
A16: cos is_differentiable_in exp_R . x by SIN_COS:68;
A17: cos * exp_R is_differentiable_in x by A10, A14, FDIFF_1:16;
((- (cos * exp_R )) `| Z) . x = diff (- (cos * exp_R )),x by A12, A14, FDIFF_1:def 8
.= (- 1) * (diff (cos * exp_R ),x) by A17, FDIFF_1:23, X
.= (- 1) * ((diff cos ,(exp_R . x)) * (diff exp_R ,x)) by A15, A16, FDIFF_2:13
.= (- 1) * ((- (sin . (exp_R . x))) * (diff exp_R ,x)) by SIN_COS:68
.= (- 1) * ((- (sin . (exp_R . x))) * (exp_R . x)) by SIN_COS:70
.= (exp_R . x) * (sin . (exp_R . x)) ;
hence ((- (cos * exp_R )) `| Z) . x = (exp_R . x) * (sin . (exp_R . x)) ; :: thesis: verum

end;

B7: for x being Real st x in Z holds
f . x = (exp_R . x) * (sin . (exp_R . x))

proof

let x be Real; :: thesis: ( x in Z implies f . x = (exp_R . x) * (sin . (exp_R . x)) )
assume B8: x in Z ; :: thesis: f . x = (exp_R . x) * (sin . (exp_R . x))
then (exp_R (#) (sin * exp_R )) . x = (exp_R . x) * ((sin * exp_R ) . x) by A1, VALUED_1:def 4
.= (exp_R . x) * (sin . (exp_R . x)) by FUNCT_1:22, A4, B8 ;
hence f . x = (exp_R . x) * (sin . (exp_R . x)) by A1; :: thesis: verum

end;

A18: for x being Real st x in dom ((- (cos * exp_R )) `| Z) holds
((- (cos * exp_R )) `| Z) . x = f . x

proof

let x be Real; :: thesis: ( x in dom ((- (cos * exp_R )) `| Z) implies ((- (cos * exp_R )) `| Z) . x = f . x )
assume x in dom ((- (cos * exp_R )) `| Z) ; :: thesis: ((- (cos * exp_R )) `| Z) . x = f . x
then A19: x in Z by A12, FDIFF_1:def 8;
then ((- (cos * exp_R )) `| Z) . x = (exp_R . x) * (sin . (exp_R . x)) by A13
.= f . x by A19, B7 ;
hence ((- (cos * exp_R )) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((- (cos * exp_R )) `| Z) = dom f by A1, A12, FDIFF_1:def 8;
then (- (cos * exp_R )) `| Z = f by A18, PARTFUN1:34;
hence integral f,A = ((- (cos * exp_R )) . (upper_bound A)) - ((- (cos * exp_R )) . (lower_bound A)) by A1, A9, A10, A11, FDIFF_1:28, X, INTEGRA5:13; :: thesis: verum