let A be closed-interval Subset of REAL ; :: thesis: for f being PartFunc of REAL ,REAL
for Z being open Subset of REAL st A c= Z & Z = dom f & f = exp_R (#) (cos * exp_R ) holds
integral f,A = ((sin * exp_R ) . (upper_bound A)) - ((sin * exp_R ) . (lower_bound A))
let f be PartFunc of REAL ,REAL ; :: thesis: for Z being open Subset of REAL st A c= Z & Z = dom f & f = exp_R (#) (cos * exp_R ) holds
integral f,A = ((sin * exp_R ) . (upper_bound A)) - ((sin * exp_R ) . (lower_bound A))
let Z be open Subset of REAL ; :: thesis: ( A c= Z & Z = dom f & f = exp_R (#) (cos * exp_R ) implies integral f,A = ((sin * exp_R ) . (upper_bound A)) - ((sin * exp_R ) . (lower_bound A)) )
assume A1: ( A c= Z & Z = dom f & f = exp_R (#) (cos * exp_R ) ) ; :: thesis: integral f,A = ((sin * exp_R ) . (upper_bound A)) - ((sin * exp_R ) . (lower_bound A))
then Z = (dom exp_R ) /\ (dom (cos * exp_R )) by VALUED_1:def 4;
then A4: ( Z c= dom exp_R & Z c= dom (cos * exp_R ) ) by XBOOLE_1:18;
for y being set st y in Z holds
y in dom (sin * exp_R )

proof

let y be set ; :: thesis: ( y in Z implies y in dom (sin * exp_R ) )
assume y in Z ; :: thesis: y in dom (sin * exp_R )
then ( y in dom exp_R & exp_R . y in dom sin ) by A4, SIN_COS:27;
hence y in dom (sin * exp_R ) by FUNCT_1:21; :: thesis: verum

end;

then B6: Z c= dom (sin * exp_R ) by TARSKI:def 3;
A5: cos * exp_R is_differentiable_on Z by A4, FDIFF_7:35;
exp_R is_differentiable_on Z by FDIFF_1:34, TAYLOR_1:16;
then f | Z is continuous by FDIFF_1:33, A1, A5, FDIFF_1:29;
then f | A is continuous by A1, FCONT_1:17;
then A9: ( f is_integrable_on A & f | A is bounded ) by A1, INTEGRA5:10, INTEGRA5:11;
A10: sin * exp_R is_differentiable_on Z by B6, FDIFF_7:34;
B7: for x being Real st x in Z holds
f . x = (exp_R . x) * (cos . (exp_R . x))

proof

let x be Real; :: thesis: ( x in Z implies f . x = (exp_R . x) * (cos . (exp_R . x)) )
assume B8: x in Z ; :: thesis: f . x = (exp_R . x) * (cos . (exp_R . x))
then (exp_R (#) (cos * exp_R )) . x = (exp_R . x) * ((cos * exp_R ) . x) by A1, VALUED_1:def 4
.= (exp_R . x) * (cos . (exp_R . x)) by FUNCT_1:22, A4, B8 ;
hence f . x = (exp_R . x) * (cos . (exp_R . x)) by A1; :: thesis: verum

end;

A11: for x being Real st x in dom ((sin * exp_R ) `| Z) holds
((sin * exp_R ) `| Z) . x = f . x

proof

let x be Real; :: thesis: ( x in dom ((sin * exp_R ) `| Z) implies ((sin * exp_R ) `| Z) . x = f . x )
assume x in dom ((sin * exp_R ) `| Z) ; :: thesis: ((sin * exp_R ) `| Z) . x = f . x
then A12: x in Z by A10, FDIFF_1:def 8;
then ((sin * exp_R ) `| Z) . x = (exp_R . x) * (cos . (exp_R . x)) by B6, FDIFF_7:34
.= f . x by A12, B7 ;
hence ((sin * exp_R ) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((sin * exp_R ) `| Z) = dom f by A1, A10, FDIFF_1:def 8;
then (sin * exp_R ) `| Z = f by A11, PARTFUN1:34;
hence integral f,A = ((sin * exp_R ) . (upper_bound A)) - ((sin * exp_R ) . (lower_bound A)) by A1, A9, B6, FDIFF_7:34, INTEGRA5:13; :: thesis: verum