let A be closed-interval Subset of REAL ; :: thesis: for f being PartFunc of REAL ,REAL
for Z being open Subset of REAL st A c= Z & Z = dom f & f = (exp_R * cos ) (#) sin holds
integral f,A = ((- (exp_R * cos )) . (upper_bound A)) - ((- (exp_R * cos )) . (lower_bound A))
let f be PartFunc of REAL ,REAL ; :: thesis: for Z being open Subset of REAL st A c= Z & Z = dom f & f = (exp_R * cos ) (#) sin holds
integral f,A = ((- (exp_R * cos )) . (upper_bound A)) - ((- (exp_R * cos )) . (lower_bound A))
let Z be open Subset of REAL ; :: thesis: ( A c= Z & Z = dom f & f = (exp_R * cos ) (#) sin implies integral f,A = ((- (exp_R * cos )) . (upper_bound A)) - ((- (exp_R * cos )) . (lower_bound A)) )
assume A1: ( A c= Z & Z = dom f & f = (exp_R * cos ) (#) sin ) ; :: thesis: integral f,A = ((- (exp_R * cos )) . (upper_bound A)) - ((- (exp_R * cos )) . (lower_bound A))
then Z = (dom (exp_R * cos )) /\ (dom sin ) by VALUED_1:def 4;
then A4: Z c= dom (exp_R * cos ) by XBOOLE_1:18;
then A5: exp_R * cos is_differentiable_on Z by FDIFF_7:36;
sin is_differentiable_on Z by FDIFF_1:34, SIN_COS:73;
then f | Z is continuous by FDIFF_1:33, A1, A5, FDIFF_1:29;
then f | A is continuous by A1, FCONT_1:17;
then AA: ( f is_integrable_on A & f | A is bounded ) by A1, INTEGRA5:10, INTEGRA5:11;
A9: Z c= dom (- (exp_R * cos )) by A4, VALUED_1:8;
then A10: (- 1) (#) (exp_R * cos ) is_differentiable_on Z by A5, FDIFF_1:28, X;
A11: for x being Real st x in Z holds
((- (exp_R * cos )) `| Z) . x = (exp_R . (cos . x)) * (sin . x)

proof

let x be Real; :: thesis: ( x in Z implies ((- (exp_R * cos )) `| Z) . x = (exp_R . (cos . x)) * (sin . x) )
assume A12: x in Z ; :: thesis: ((- (exp_R * cos )) `| Z) . x = (exp_R . (cos . x)) * (sin . x)
A13: cos is_differentiable_in x by SIN_COS:68;
A14: exp_R is_differentiable_in cos . x by SIN_COS:70;
A15: exp_R * cos is_differentiable_in x by A5, A12, FDIFF_1:16;
((- (exp_R * cos )) `| Z) . x = diff (- (exp_R * cos )),x by A10, A12, FDIFF_1:def 8
.= (- 1) * (diff (exp_R * cos ),x) by A15, FDIFF_1:23, X
.= (- 1) * ((diff exp_R ,(cos . x)) * (diff cos ,x)) by A13, A14, FDIFF_2:13
.= (- 1) * ((diff exp_R ,(cos . x)) * (- (sin . x))) by SIN_COS:68
.= (- 1) * ((exp_R . (cos . x)) * (- (sin . x))) by SIN_COS:70
.= (exp_R . (cos . x)) * (sin . x) ;
hence ((- (exp_R * cos )) `| Z) . x = (exp_R . (cos . x)) * (sin . x) ; :: thesis: verum

end;

B1: for x being Real st x in Z holds
f . x = (exp_R . (cos . x)) * (sin . x)

proof

let x be Real; :: thesis: ( x in Z implies f . x = (exp_R . (cos . x)) * (sin . x) )
assume B2: x in Z ; :: thesis: f . x = (exp_R . (cos . x)) * (sin . x)
then ((exp_R * cos ) (#) sin ) . x = ((exp_R * cos ) . x) * (sin . x) by A1, VALUED_1:def 4
.= (exp_R . (cos . x)) * (sin . x) by FUNCT_1:22, A4, B2 ;
hence f . x = (exp_R . (cos . x)) * (sin . x) by A1; :: thesis: verum

end;

A16: for x being Real st x in dom ((- (exp_R * cos )) `| Z) holds
((- (exp_R * cos )) `| Z) . x = f . x

proof

let x be Real; :: thesis: ( x in dom ((- (exp_R * cos )) `| Z) implies ((- (exp_R * cos )) `| Z) . x = f . x )
assume x in dom ((- (exp_R * cos )) `| Z) ; :: thesis: ((- (exp_R * cos )) `| Z) . x = f . x
then A17: x in Z by A10, FDIFF_1:def 8;
then ((- (exp_R * cos )) `| Z) . x = (exp_R . (cos . x)) * (sin . x) by A11
.= f . x by A17, B1 ;
hence ((- (exp_R * cos )) `| Z) . x = f . x ; :: thesis: verum

end;

dom ((- (exp_R * cos )) `| Z) = dom f by A1, A10, FDIFF_1:def 8;
then (- (exp_R * cos )) `| Z = f by A16, PARTFUN1:34;
hence integral f,A = ((- (exp_R * cos )) . (upper_bound A)) - ((- (exp_R * cos )) . (lower_bound A)) by A1, AA, A5, A9, FDIFF_1:28, X, INTEGRA5:13; :: thesis: verum