let Z be open Subset of REAL ; :: thesis: ( Z c= dom (((id Z) + cot ) - cosec ) & ( for x being Real st x in Z holds
( 1 + (cos . x) <> 0 & 1 - (cos . x) <> 0 ) ) implies ( ((id Z) + cot ) - cosec is_differentiable_on Z & ( for x being Real st x in Z holds
((((id Z) + cot ) - cosec ) `| Z) . x = (cos . x) / (1 + (cos . x)) ) ) )
assume that
A1: Z c= dom (((id Z) + cot ) - cosec ) and
A2: for x being Real st x in Z holds
( 1 + (cos . x) <> 0 & 1 - (cos . x) <> 0 ) ; :: thesis: ( ((id Z) + cot ) - cosec is_differentiable_on Z & ( for x being Real st x in Z holds
((((id Z) + cot ) - cosec ) `| Z) . x = (cos . x) / (1 + (cos . x)) ) )
A3: Z c= (dom ((id Z) + cot )) /\ (dom cosec ) by A1, VALUED_1:12;
then A4: Z c= dom ((id Z) + cot ) by XBOOLE_1:18;
then A5: Z c= (dom (id Z)) /\ (dom cot ) by VALUED_1:def 1;
then A6: Z c= dom cot by XBOOLE_1:18;
A7: for x being Real st x in Z holds
(id Z) . x = (1 * x) + 0 by FUNCT_1:35;
A8: Z c= dom (id Z) by A5, XBOOLE_1:18;
then A9: id Z is_differentiable_on Z by A7, FDIFF_1:31;
for x being Real st x in Z holds
cot is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies cot is_differentiable_in x )
assume x in Z ; :: thesis: cot is_differentiable_in x
then sin . x <> 0 by A6, FDIFF_8:2;
hence cot is_differentiable_in x by FDIFF_7:47; :: thesis: verum

end;

then A10: cot is_differentiable_on Z by A6, FDIFF_1:16;
then A11: (id Z) + cot is_differentiable_on Z by A4, A9, FDIFF_1:26;
A12: Z c= dom cosec by A3, XBOOLE_1:18;
then A13: cosec is_differentiable_on Z by FDIFF_9:5;
A14: for x being Real st x in Z holds
(((id Z) + cot ) `| Z) . x = - (((cos . x) ^2 ) / ((sin . x) ^2 ))

proof

let x be Real; :: thesis: ( x in Z implies (((id Z) + cot ) `| Z) . x = - (((cos . x) ^2 ) / ((sin . x) ^2 )) )
assume A15: x in Z ; :: thesis: (((id Z) + cot ) `| Z) . x = - (((cos . x) ^2 ) / ((sin . x) ^2 ))
then A16: sin . x <> 0 by A6, FDIFF_8:2;
then A17: (sin . x) ^2 > 0 by SQUARE_1:74;
(((id Z) + cot ) `| Z) . x = (diff (id Z),x) + (diff cot ,x) by A4, A10, A9, A15, FDIFF_1:26
.= (((id Z) `| Z) . x) + (diff cot ,x) by A9, A15, FDIFF_1:def 8
.= 1 + (diff cot ,x) by A8, A7, A15, FDIFF_1:31
.= 1 + (- (1 / ((sin . x) ^2 ))) by A16, FDIFF_7:47
.= 1 - (1 / ((sin . x) ^2 ))
.= (((sin . x) ^2 ) / ((sin . x) ^2 )) - (1 / ((sin . x) ^2 )) by A17, XCMPLX_1:60
.= (((sin . x) ^2 ) - 1) / ((sin . x) ^2 ) by XCMPLX_1:121
.= (((sin . x) ^2 ) - (((sin . x) ^2 ) + ((cos . x) ^2 ))) / ((sin . x) ^2 ) by SIN_COS:31
.= (- ((cos . x) ^2 )) / ((sin . x) ^2 )
.= - (((cos . x) ^2 ) / ((sin . x) ^2 )) by XCMPLX_1:188 ;
hence (((id Z) + cot ) `| Z) . x = - (((cos . x) ^2 ) / ((sin . x) ^2 )) ; :: thesis: verum

end;

for x being Real st x in Z holds
((((id Z) + cot ) - cosec ) `| Z) . x = (cos . x) / (1 + (cos . x))

proof

let x be Real; :: thesis: ( x in Z implies ((((id Z) + cot ) - cosec ) `| Z) . x = (cos . x) / (1 + (cos . x)) )
assume A18: x in Z ; :: thesis: ((((id Z) + cot ) - cosec ) `| Z) . x = (cos . x) / (1 + (cos . x))
then A19: 1 - (cos . x) <> 0 by A2;
((((id Z) + cot ) - cosec ) `| Z) . x = (diff ((id Z) + cot ),x) - (diff cosec ,x) by A1, A13, A11, A18, FDIFF_1:27
.= ((((id Z) + cot ) `| Z) . x) - (diff cosec ,x) by A11, A18, FDIFF_1:def 8
.= (- (((cos . x) ^2 ) / ((sin . x) ^2 ))) - (diff cosec ,x) by A14, A18
.= (- (((cos . x) ^2 ) / ((sin . x) ^2 ))) - ((cosec `| Z) . x) by A13, A18, FDIFF_1:def 8
.= (- (((cos . x) ^2 ) / ((sin . x) ^2 ))) - (- ((cos . x) / ((sin . x) ^2 ))) by A12, A18, FDIFF_9:5
.= ((cos . x) / ((sin . x) ^2 )) - (((cos . x) ^2 ) / ((sin . x) ^2 ))
.= ((cos . x) - ((cos . x) * (cos . x))) / ((sin . x) ^2 ) by XCMPLX_1:121
.= ((cos . x) * (1 - (cos . x))) / ((((sin . x) ^2 ) + ((cos . x) ^2 )) - ((cos . x) ^2 ))
.= ((cos . x) * (1 - (cos . x))) / (1 - ((cos . x) ^2 )) by SIN_COS:31
.= ((cos . x) * (1 - (cos . x))) / ((1 - (cos . x)) * (1 + (cos . x)))
.= (((cos . x) * (1 - (cos . x))) / (1 - (cos . x))) / (1 + (cos . x)) by XCMPLX_1:79
.= ((cos . x) * ((1 - (cos . x)) / (1 - (cos . x)))) / (1 + (cos . x)) by XCMPLX_1:75
.= ((cos . x) * 1) / (1 + (cos . x)) by A19, XCMPLX_1:60
.= (cos . x) / (1 + (cos . x)) ;
hence ((((id Z) + cot ) - cosec ) `| Z) . x = (cos . x) / (1 + (cos . x)) ; :: thesis: verum

end;

hence ( ((id Z) + cot ) - cosec is_differentiable_on Z & ( for x being Real st x in Z holds
((((id Z) + cot ) - cosec ) `| Z) . x = (cos . x) / (1 + (cos . x)) ) ) by A1, A13, A11, FDIFF_1:27; :: thesis: verum