let G be Go-board; :: thesis: LSeg ((G * (len G),1) + |[1,(- 1)]|),((G * (len G),1) + |[1,0 ]|) c= (Int (cell G,(len G),0 )) \/ {((G * (len G),1) + |[1,0 ]|)}
let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in LSeg ((G * (len G),1) + |[1,(- 1)]|),((G * (len G),1) + |[1,0 ]|) or x in (Int (cell G,(len G),0 )) \/ {((G * (len G),1) + |[1,0 ]|)} )
set r1 = (G * (len G),1) `1 ;
set s1 = (G * 1,1) `2 ;
assume A1: x in LSeg ((G * (len G),1) + |[1,(- 1)]|),((G * (len G),1) + |[1,0 ]|) ; :: thesis: x in (Int (cell G,(len G),0 )) \/ {((G * (len G),1) + |[1,0 ]|)}
then reconsider p = x as Point of (TOP-REAL 2) ;
consider r being Real such that
A2: p = ((1 - r) * ((G * (len G),1) + |[1,(- 1)]|)) + (r * ((G * (len G),1) + |[1,0 ]|)) and
0 <= r and
A3: r <= 1 by A1;

now

per cases ( r = 1 or r < 1 ) by A3, XXREAL_0:1;

case r = 1 ; :: thesis: p in {((G * (len G),1) + |[1,0 ]|)}

then p = (0. (TOP-REAL 2)) + (1 * ((G * (len G),1) + |[1,0 ]|)) by A2, EUCLID:33
.= 1 * ((G * (len G),1) + |[1,0 ]|) by EUCLID:31
.= (G * (len G),1) + |[1,0 ]| by EUCLID:33 ;
hence p in {((G * (len G),1) + |[1,0 ]|)} by TARSKI:def 1; :: thesis: verum

end;

case r < 1 ; :: thesis: p in Int (cell G,(len G),0 )

then 1 - r > 0 by XREAL_1:52;
then A4: (G * 1,1) `2 < ((G * 1,1) `2 ) + (1 - r) by XREAL_1:31;
((G * 1,1) `2 ) + (r - 1) = ((G * 1,1) `2 ) - (1 - r) ;
then A5: ((G * 1,1) `2 ) + (r - 1) < (G * 1,1) `2 by A4, XREAL_1:21;
A6: (G * (len G),1) `1 < ((G * (len G),1) `1 ) + 1 by XREAL_1:31;
0 <> len G by GOBOARD1:def 5;
then A7: 1 <= len G by NAT_1:14;
0 <> width G by GOBOARD1:def 5;
then A8: 1 <= width G by NAT_1:14;
A9: G * (len G),1 = |[((G * (len G),1) `1 ),((G * (len G),1) `2 )]| by EUCLID:57
.= |[((G * (len G),1) `1 ),((G * 1,1) `2 )]| by A8, A7, GOBOARD5:2 ;
A10: Int (cell G,(len G),0 ) = { |[r9,s9]| where r9, s9 is Real : ( (G * (len G),1) `1 < r9 & s9 < (G * 1,1) `2 ) } by Th24;
p = (((1 - r) * (G * (len G),1)) + ((1 - r) * |[1,(- 1)]|)) + (r * ((G * (len G),1) + |[1,0 ]|)) by A2, EUCLID:36
.= (((1 - r) * (G * (len G),1)) + ((1 - r) * |[1,(- 1)]|)) + ((r * (G * (len G),1)) + (r * |[1,0 ]|)) by EUCLID:36
.= ((r * (G * (len G),1)) + (((1 - r) * (G * (len G),1)) + ((1 - r) * |[1,(- 1)]|))) + (r * |[1,0 ]|) by EUCLID:30
.= (((r * (G * (len G),1)) + ((1 - r) * (G * (len G),1))) + ((1 - r) * |[1,(- 1)]|)) + (r * |[1,0 ]|) by EUCLID:30
.= (((r + (1 - r)) * (G * (len G),1)) + ((1 - r) * |[1,(- 1)]|)) + (r * |[1,0 ]|) by EUCLID:37
.= ((G * (len G),1) + ((1 - r) * |[1,(- 1)]|)) + (r * |[1,0 ]|) by EUCLID:33
.= ((G * (len G),1) + |[((1 - r) * 1),((1 - r) * (- 1))]|) + (r * |[1,0 ]|) by EUCLID:62
.= ((G * (len G),1) + |[(1 - r),(r - 1)]|) + |[(r * 1),(r * 0 )]| by EUCLID:62
.= |[(((G * (len G),1) `1 ) + (1 - r)),(((G * 1,1) `2 ) + (r - 1))]| + |[r,0 ]| by A9, EUCLID:60
.= |[((((G * (len G),1) `1 ) + (1 - r)) + r),((((G * 1,1) `2 ) + (r - 1)) + 0 )]| by EUCLID:60
.= |[(((G * (len G),1) `1 ) + 1),(((G * 1,1) `2 ) + (r - 1))]| ;
hence p in Int (cell G,(len G),0 ) by A5, A6, A10; :: thesis: verum

end;

end;

end;

hence x in (Int (cell G,(len G),0 )) \/ {((G * (len G),1) + |[1,0 ]|)} by XBOOLE_0:def 3; :: thesis: verum