let Z be open Subset of REAL ; :: thesis: ( not 0 in Z & Z c= dom (ln * ((id Z) ^ )) implies ( ln * ((id Z) ^ ) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * ((id Z) ^ )) `| Z) . x = - (1 / x) ) ) )
set f = id Z;
assume that
A1: not 0 in Z and
A2: Z c= dom (ln * ((id Z) ^ )) ; :: thesis: ( ln * ((id Z) ^ ) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * ((id Z) ^ )) `| Z) . x = - (1 / x) ) )
dom (ln * ((id Z) ^ )) c= dom ((id Z) ^ ) by RELAT_1:44;
then A3: Z c= dom ((id Z) ^ ) by A2, XBOOLE_1:1;
A4: for x being Real st x in Z holds
((id Z) ^ ) . x > 0

proof

let x be Real; :: thesis: ( x in Z implies ((id Z) ^ ) . x > 0 )
assume A5: x in Z ; :: thesis: ((id Z) ^ ) . x > 0
then A6: ((id Z) ^ ) . x = ((id Z) . x) " by A3, RFUNCT_1:def 8
.= 1 / x by A5, FUNCT_1:35 ;
((id Z) ^ ) . x in right_open_halfline 0 by A2, A5, FUNCT_1:21, TAYLOR_1:18;
then ex g being Real st
( 1 / x = g & 0 < g ) by A6, Lm1;
hence ((id Z) ^ ) . x > 0 by A6; :: thesis: verum

end;

A7: for x being Real st x in Z holds
(id Z) . x > 0

proof

let x be Real; :: thesis: ( x in Z implies (id Z) . x > 0 )
assume A8: x in Z ; :: thesis: (id Z) . x > 0
then ((id Z) ^ ) . x > 0 by A4;
then ((id Z) . x) " > 0 by A3, A8, RFUNCT_1:def 8;
hence (id Z) . x > 0 by XREAL_1:124; :: thesis: verum

end;

A9: (id Z) ^ is_differentiable_on Z by A1, FDIFF_5:4;
A10: for x being Real st x in Z holds
( ln * ((id Z) ^ ) is_differentiable_in x & diff (ln * ((id Z) ^ )),x = (diff ((id Z) ^ ),x) / (((id Z) ^ ) . x) )

proof

let x be Real; :: thesis: ( x in Z implies ( ln * ((id Z) ^ ) is_differentiable_in x & diff (ln * ((id Z) ^ )),x = (diff ((id Z) ^ ),x) / (((id Z) ^ ) . x) ) )
assume x in Z ; :: thesis: ( ln * ((id Z) ^ ) is_differentiable_in x & diff (ln * ((id Z) ^ )),x = (diff ((id Z) ^ ),x) / (((id Z) ^ ) . x) )
then ( (id Z) ^ is_differentiable_in x & ((id Z) ^ ) . x > 0 ) by A4, A9, FDIFF_1:16;
hence ( ln * ((id Z) ^ ) is_differentiable_in x & diff (ln * ((id Z) ^ )),x = (diff ((id Z) ^ ),x) / (((id Z) ^ ) . x) ) by TAYLOR_1:20; :: thesis: verum

end;

then A11: for x being Real st x in Z holds
ln * ((id Z) ^ ) is_differentiable_in x ;
then A12: ln * ((id Z) ^ ) is_differentiable_on Z by A2, FDIFF_1:16;
for x being Real st x in Z holds
((ln * ((id Z) ^ )) `| Z) . x = - (1 / x)

proof

let x be Real; :: thesis: ( x in Z implies ((ln * ((id Z) ^ )) `| Z) . x = - (1 / x) )
assume A13: x in Z ; :: thesis: ((ln * ((id Z) ^ )) `| Z) . x = - (1 / x)
then (id Z) . x <> 0 by A7;
then A14: x <> 0 by A13, FUNCT_1:35;
diff (ln * ((id Z) ^ )),x = (diff ((id Z) ^ ),x) / (((id Z) ^ ) . x) by A10, A13
.= ((((id Z) ^ ) `| Z) . x) / (((id Z) ^ ) . x) by A9, A13, FDIFF_1:def 8
.= ((((id Z) ^ ) `| Z) . x) / (((id Z) . x) " ) by A3, A13, RFUNCT_1:def 8
.= ((((id Z) ^ ) `| Z) . x) / (1 * (x " )) by A13, FUNCT_1:35
.= (- (1 / (x ^2 ))) / (1 * (x " )) by A1, A13, FDIFF_5:4
.= - (x / (x ^2 ))
.= - ((x / x) / x) by XCMPLX_1:79
.= - (1 / x) by A14, XCMPLX_1:60 ;
hence ((ln * ((id Z) ^ )) `| Z) . x = - (1 / x) by A12, A13, FDIFF_1:def 8; :: thesis: verum

end;

hence ( ln * ((id Z) ^ ) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * ((id Z) ^ )) `| Z) . x = - (1 / x) ) ) by A2, A11, FDIFF_1:16; :: thesis: verum