let Z be open Subset of REAL ; :: thesis: for f, f1 being PartFunc of REAL ,REAL st Z c= dom (ln * f) & f = exp_R + (exp_R * f1) & ( for x being Real st x in Z holds
f1 . x = - x ) holds
( ln * f is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x))) ) )
let f, f1 be PartFunc of REAL ,REAL ; :: thesis: ( Z c= dom (ln * f) & f = exp_R + (exp_R * f1) & ( for x being Real st x in Z holds
f1 . x = - x ) implies ( ln * f is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x))) ) ) )
assume that
A1: Z c= dom (ln * f) and
A2: f = exp_R + (exp_R * f1) and
A3: for x being Real st x in Z holds
f1 . x = - x ; :: thesis: ( ln * f is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x))) ) )
for y being set st y in Z holds
y in dom f by A1, FUNCT_1:21;
then A4: Z c= dom (exp_R + (exp_R * f1)) by A2, TARSKI:def 3;
then Z c= (dom exp_R ) /\ (dom (exp_R * f1)) by VALUED_1:def 1;
then A5: Z c= dom (exp_R * f1) by XBOOLE_1:18;
then A6: exp_R * f1 is_differentiable_on Z by A3, Th14;
A7: exp_R is_differentiable_on Z by FDIFF_1:34, TAYLOR_1:16;
then A8: f is_differentiable_on Z by A2, A4, A6, FDIFF_1:26;
A9: for x being Real st x in Z holds
((exp_R + (exp_R * f1)) `| Z) . x = (exp_R x) - (exp_R (- x))

proof

let x be Real; :: thesis: ( x in Z implies ((exp_R + (exp_R * f1)) `| Z) . x = (exp_R x) - (exp_R (- x)) )
assume A10: x in Z ; :: thesis: ((exp_R + (exp_R * f1)) `| Z) . x = (exp_R x) - (exp_R (- x))
hence ((exp_R + (exp_R * f1)) `| Z) . x = (diff exp_R ,x) + (diff (exp_R * f1),x) by A4, A6, A7, FDIFF_1:26
.= (exp_R . x) + (diff (exp_R * f1),x) by SIN_COS:70
.= (exp_R . x) + (((exp_R * f1) `| Z) . x) by A6, A10, FDIFF_1:def 8
.= (exp_R . x) + (- (exp_R (- x))) by A3, A5, A10, Th14
.= (exp_R x) + (- (exp_R (- x))) by SIN_COS:def 27
.= (exp_R x) - (exp_R (- x)) ;
:: thesis: verum

end;

A11: for x being Real st x in Z holds
(exp_R + (exp_R * f1)) . x > 0

proof

let x be Real; :: thesis: ( x in Z implies (exp_R + (exp_R * f1)) . x > 0 )
A12: exp_R x > 0 by SIN_COS:60;
assume A13: x in Z ; :: thesis: (exp_R + (exp_R * f1)) . x > 0
then (exp_R + (exp_R * f1)) . x = (exp_R . x) + ((exp_R * f1) . x) by A4, VALUED_1:def 1
.= (exp_R . x) + (exp_R . (f1 . x)) by A5, A13, FUNCT_1:22
.= (exp_R . x) + (exp_R . (- x)) by A3, A13
.= (exp_R x) + (exp_R . (- x)) by SIN_COS:def 27
.= (exp_R x) + (exp_R (- x)) by SIN_COS:def 27 ;
hence (exp_R + (exp_R * f1)) . x > 0 by A12, SIN_COS:60, XREAL_1:36; :: thesis: verum

end;

A14: for x being Real st x in Z holds
ln * f is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies ln * f is_differentiable_in x )
assume x in Z ; :: thesis: ln * f is_differentiable_in x
then ( f is_differentiable_in x & f . x > 0 ) by A2, A8, A11, FDIFF_1:16;
hence ln * f is_differentiable_in x by TAYLOR_1:20; :: thesis: verum

end;

then A15: ln * f is_differentiable_on Z by A1, FDIFF_1:16;
for x being Real st x in Z holds
((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x)))

proof

let x be Real; :: thesis: ( x in Z implies ((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x))) )
assume A16: x in Z ; :: thesis: ((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x)))
then A17: f . x = (exp_R . x) + ((exp_R * f1) . x) by A2, A4, VALUED_1:def 1
.= (exp_R . x) + (exp_R . (f1 . x)) by A5, A16, FUNCT_1:22
.= (exp_R . x) + (exp_R . (- x)) by A3, A16
.= (exp_R x) + (exp_R . (- x)) by SIN_COS:def 27
.= (exp_R x) + (exp_R (- x)) by SIN_COS:def 27 ;
( f is_differentiable_in x & f . x > 0 ) by A2, A8, A11, A16, FDIFF_1:16;
then diff (ln * f),x = (diff f,x) / (f . x) by TAYLOR_1:20
.= ((f `| Z) . x) / (f . x) by A8, A16, FDIFF_1:def 8
.= ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x))) by A2, A9, A16, A17 ;
hence ((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x))) by A15, A16, FDIFF_1:def 8; :: thesis: verum

end;

hence ( ln * f is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * f) `| Z) . x = ((exp_R x) - (exp_R (- x))) / ((exp_R x) + (exp_R (- x))) ) ) by A1, A14, FDIFF_1:16; :: thesis: verum