let Z be open Subset of REAL ; :: thesis: ( not 0 in Z & Z c= dom (cos * ((id Z) ^ )) implies ( cos * ((id Z) ^ ) is_differentiable_on Z & ( for x being Real st x in Z holds
((cos * ((id Z) ^ )) `| Z) . x = (1 / (x ^2 )) * (sin . (1 / x)) ) ) )
set f = id Z;
assume that
A1: not 0 in Z and
A2: Z c= dom (cos * ((id Z) ^ )) ; :: thesis: ( cos * ((id Z) ^ ) is_differentiable_on Z & ( for x being Real st x in Z holds
((cos * ((id Z) ^ )) `| Z) . x = (1 / (x ^2 )) * (sin . (1 / x)) ) )
for y being set st y in Z holds
y in dom ((id Z) ^ ) by A2, FUNCT_1:21;
then A3: Z c= dom ((id Z) ^ ) by TARSKI:def 3;
A4: (id Z) ^ is_differentiable_on Z by A1, Th4;
A5: for x being Real st x in Z holds
cos * ((id Z) ^ ) is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies cos * ((id Z) ^ ) is_differentiable_in x )
assume x in Z ; :: thesis: cos * ((id Z) ^ ) is_differentiable_in x
then A6: (id Z) ^ is_differentiable_in x by A4, FDIFF_1:16;
cos is_differentiable_in ((id Z) ^ ) . x by SIN_COS:68;
hence cos * ((id Z) ^ ) is_differentiable_in x by A6, FDIFF_2:13; :: thesis: verum

end;

then A7: cos * ((id Z) ^ ) is_differentiable_on Z by A2, FDIFF_1:16;
for x being Real st x in Z holds
((cos * ((id Z) ^ )) `| Z) . x = (1 / (x ^2 )) * (sin . (1 / x))

proof

let x be Real; :: thesis: ( x in Z implies ((cos * ((id Z) ^ )) `| Z) . x = (1 / (x ^2 )) * (sin . (1 / x)) )
A8: diff cos ,(((id Z) ^ ) . x) = - (sin . (((id Z) ^ ) . x)) by SIN_COS:68;
A9: cos is_differentiable_in ((id Z) ^ ) . x by SIN_COS:68;
assume A10: x in Z ; :: thesis: ((cos * ((id Z) ^ )) `| Z) . x = (1 / (x ^2 )) * (sin . (1 / x))
then (id Z) ^ is_differentiable_in x by A4, FDIFF_1:16;
then diff (cos * ((id Z) ^ )),x = (diff cos ,(((id Z) ^ ) . x)) * (diff ((id Z) ^ ),x) by A9, FDIFF_2:13
.= - ((sin . (((id Z) ^ ) . x)) * (diff ((id Z) ^ ),x)) by A8
.= - ((sin . (((id Z) . x) " )) * (diff ((id Z) ^ ),x)) by A3, A10, RFUNCT_1:def 8
.= - ((sin . (((id Z) . x) " )) * ((((id Z) ^ ) `| Z) . x)) by A4, A10, FDIFF_1:def 8
.= - ((sin . (((id Z) . x) " )) * (- (1 / (x ^2 )))) by A1, A10, Th4
.= - ((sin . (1 * (x " ))) * (- (1 / (x ^2 )))) by A10, FUNCT_1:35
.= - ((sin . (1 / x)) * (- (1 / (x ^2 )))) by XCMPLX_0:def 9
.= (sin . (1 / x)) * (1 / (x ^2 )) ;
hence ((cos * ((id Z) ^ )) `| Z) . x = (1 / (x ^2 )) * (sin . (1 / x)) by A7, A10, FDIFF_1:def 8; :: thesis: verum

end;

hence ( cos * ((id Z) ^ ) is_differentiable_on Z & ( for x being Real st x in Z holds
((cos * ((id Z) ^ )) `| Z) . x = (1 / (x ^2 )) * (sin . (1 / x)) ) ) by A2, A5, FDIFF_1:16; :: thesis: verum