let a be Real; :: thesis: for Z being open Subset of REAL
for f1, f2 being PartFunc of REAL ,REAL st Z c= dom (ln * (f1 / f2)) & ( for x being Real st x in Z holds
( f1 . x = a + x & f1 . x > 0 & f2 . x = a - x & f2 . x > 0 ) ) holds
( ln * (f1 / f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 )) ) )
let Z be open Subset of REAL ; :: thesis: for f1, f2 being PartFunc of REAL ,REAL st Z c= dom (ln * (f1 / f2)) & ( for x being Real st x in Z holds
( f1 . x = a + x & f1 . x > 0 & f2 . x = a - x & f2 . x > 0 ) ) holds
( ln * (f1 / f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 )) ) )
let f1, f2 be PartFunc of REAL ,REAL ; :: thesis: ( Z c= dom (ln * (f1 / f2)) & ( for x being Real st x in Z holds
( f1 . x = a + x & f1 . x > 0 & f2 . x = a - x & f2 . x > 0 ) ) implies ( ln * (f1 / f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 )) ) ) )
assume that
A1: Z c= dom (ln * (f1 / f2)) and
A2: for x being Real st x in Z holds
( f1 . x = a + x & f1 . x > 0 & f2 . x = a - x & f2 . x > 0 ) ; :: thesis: ( ln * (f1 / f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 )) ) )
for y being set st y in Z holds
y in dom (f1 / f2) by A1, FUNCT_1:21;
then Z c= dom (f1 / f2) by TARSKI:def 3;
then A3: Z c= (dom f1) /\ ((dom f2) \ (f2 " {0 })) by RFUNCT_1:def 4;
then A4: Z c= dom f1 by XBOOLE_1:18;
A5: for x being Real st x in Z holds
f1 . x = (1 * x) + a by A2;
then A6: f1 is_differentiable_on Z by A4, FDIFF_1:31;
A7: for x being Real st x in Z holds
f2 . x = ((- 1) * x) + a

proof

let x be Real; :: thesis: ( x in Z implies f2 . x = ((- 1) * x) + a )
assume x in Z ; :: thesis: f2 . x = ((- 1) * x) + a
then f2 . x = a - x by A2;
hence f2 . x = ((- 1) * x) + a ; :: thesis: verum

end;

A8: Z c= dom f2 by A3, XBOOLE_1:1;
then A9: f2 is_differentiable_on Z by A7, FDIFF_1:31;
for x being Real st x in Z holds
f2 . x <> 0 by A2;
then A10: f1 / f2 is_differentiable_on Z by A6, A9, FDIFF_2:21;
A11: for x being Real st x in Z holds
((f1 / f2) `| Z) . x = (2 * a) / ((a - x) ^2 )

proof

let x be Real; :: thesis: ( x in Z implies ((f1 / f2) `| Z) . x = (2 * a) / ((a - x) ^2 ) )
assume A12: x in Z ; :: thesis: ((f1 / f2) `| Z) . x = (2 * a) / ((a - x) ^2 )
then A13: f2 . x <> 0 by A2;
A14: ( f1 . x = a + x & f2 . x = a - x ) by A2, A12;
( f1 is_differentiable_in x & f2 is_differentiable_in x ) by A6, A9, A12, FDIFF_1:16;
then diff (f1 / f2),x = (((diff f1,x) * (f2 . x)) - ((diff f2,x) * (f1 . x))) / ((f2 . x) ^2 ) by A13, FDIFF_2:14
.= ((((f1 `| Z) . x) * (f2 . x)) - ((diff f2,x) * (f1 . x))) / ((f2 . x) ^2 ) by A6, A12, FDIFF_1:def 8
.= ((((f1 `| Z) . x) * (f2 . x)) - (((f2 `| Z) . x) * (f1 . x))) / ((f2 . x) ^2 ) by A9, A12, FDIFF_1:def 8
.= ((1 * (f2 . x)) - (((f2 `| Z) . x) * (f1 . x))) / ((f2 . x) ^2 ) by A4, A5, A12, FDIFF_1:31
.= ((1 * (f2 . x)) - ((- 1) * (f1 . x))) / ((f2 . x) ^2 ) by A8, A7, A12, FDIFF_1:31
.= (2 * a) / ((a - x) ^2 ) by A14 ;
hence ((f1 / f2) `| Z) . x = (2 * a) / ((a - x) ^2 ) by A10, A12, FDIFF_1:def 8; :: thesis: verum

end;

A15: for x being Real st x in Z holds
(f1 / f2) . x > 0

proof

let x be Real; :: thesis: ( x in Z implies (f1 / f2) . x > 0 )
assume A16: x in Z ; :: thesis: (f1 / f2) . x > 0
then x in dom (f1 / f2) by A1, FUNCT_1:21;
then A17: (f1 / f2) . x = (f1 . x) * ((f2 . x) " ) by RFUNCT_1:def 4
.= (f1 . x) / (f2 . x) by XCMPLX_0:def 9 ;
( f1 . x > 0 & f2 . x > 0 ) by A2, A16;
hence (f1 / f2) . x > 0 by A17, XREAL_1:141; :: thesis: verum

end;

A18: for x being Real st x in Z holds
ln * (f1 / f2) is_differentiable_in x

proof

let x be Real; :: thesis: ( x in Z implies ln * (f1 / f2) is_differentiable_in x )
assume x in Z ; :: thesis: ln * (f1 / f2) is_differentiable_in x
then ( f1 / f2 is_differentiable_in x & (f1 / f2) . x > 0 ) by A10, A15, FDIFF_1:16;
hence ln * (f1 / f2) is_differentiable_in x by TAYLOR_1:20; :: thesis: verum

end;

then A19: ln * (f1 / f2) is_differentiable_on Z by A1, FDIFF_1:16;
for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 ))

proof

let x be Real; :: thesis: ( x in Z implies ((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 )) )
assume A20: x in Z ; :: thesis: ((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 ))
then A21: ( f2 . x = a - x & f2 . x > 0 ) by A2;
A22: ( f1 . x = a + x & f2 . x = a - x ) by A2, A20;
A23: x in dom (f1 / f2) by A1, A20, FUNCT_1:21;
( f1 / f2 is_differentiable_in x & (f1 / f2) . x > 0 ) by A10, A15, A20, FDIFF_1:16;
then diff (ln * (f1 / f2)),x = (diff (f1 / f2),x) / ((f1 / f2) . x) by TAYLOR_1:20
.= (((f1 / f2) `| Z) . x) / ((f1 / f2) . x) by A10, A20, FDIFF_1:def 8
.= ((2 * a) / ((a - x) ^2 )) / ((f1 / f2) . x) by A11, A20
.= ((2 * a) / ((a - x) ^2 )) / ((f1 . x) * ((f2 . x) " )) by A23, RFUNCT_1:def 4
.= ((2 * a) / ((a - x) * (a - x))) / ((a + x) / (a - x)) by A22, XCMPLX_0:def 9
.= (((2 * a) / (a - x)) / (a - x)) / ((a + x) / (a - x)) by XCMPLX_1:79
.= (((2 * a) / (a - x)) / ((a + x) / (a - x))) / (a - x) by XCMPLX_1:48
.= ((2 * a) / (a + x)) / (a - x) by A21, XCMPLX_1:55
.= (2 * a) / ((a + x) * (a - x)) by XCMPLX_1:79
.= (2 * a) / ((a ^2 ) - (x ^2 )) ;
hence ((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 )) by A19, A20, FDIFF_1:def 8; :: thesis: verum

end;

hence ( ln * (f1 / f2) is_differentiable_on Z & ( for x being Real st x in Z holds
((ln * (f1 / f2)) `| Z) . x = (2 * a) / ((a ^2 ) - (x ^2 )) ) ) by A1, A18, FDIFF_1:16; :: thesis: verum