let f1, f2 be PartFunc of REAL ,REAL ; :: thesis: for x0 being Real st f1 is_right_differentiable_in x0 & f2 is_right_differentiable_in x0 & ex r0 being Real st
( r0 > 0 & ( for g being Real st g in dom f2 & g in [.x0,(x0 + r0).] holds
f2 . g <> 0 ) ) holds
( f1 / f2 is_right_differentiable_in x0 & Rdiff (f1 / f2),x0 = (((Rdiff f1,x0) * (f2 . x0)) - ((Rdiff f2,x0) * (f1 . x0))) / ((f2 . x0) ^2 ) )
let x0 be Real; :: thesis: ( f1 is_right_differentiable_in x0 & f2 is_right_differentiable_in x0 & ex r0 being Real st
( r0 > 0 & ( for g being Real st g in dom f2 & g in [.x0,(x0 + r0).] holds
f2 . g <> 0 ) ) implies ( f1 / f2 is_right_differentiable_in x0 & Rdiff (f1 / f2),x0 = (((Rdiff f1,x0) * (f2 . x0)) - ((Rdiff f2,x0) * (f1 . x0))) / ((f2 . x0) ^2 ) ) )
assume that
A1: f1 is_right_differentiable_in x0 and
A2: f2 is_right_differentiable_in x0 ; :: thesis: ( for r0 being Real holds
( not r0 > 0 or ex g being Real st
( g in dom f2 & g in [.x0,(x0 + r0).] & not f2 . g <> 0 ) ) or ( f1 / f2 is_right_differentiable_in x0 & Rdiff (f1 / f2),x0 = (((Rdiff f1,x0) * (f2 . x0)) - ((Rdiff f2,x0) * (f1 . x0))) / ((f2 . x0) ^2 ) ) )
consider r2 being Real such that
A3: 0 < r2 and
A4: [.x0,(x0 + r2).] c= dom f2 by A2, Def3;
consider r1 being Real such that
A5: 0 < r1 and
A6: [.x0,(x0 + r1).] c= dom f1 by A1, Def3;
given r0 being Real such that A7: r0 > 0 and
A8: for g being Real st g in dom f2 & g in [.x0,(x0 + r0).] holds
f2 . g <> 0 ; :: thesis: ( f1 / f2 is_right_differentiable_in x0 & Rdiff (f1 / f2),x0 = (((Rdiff f1,x0) * (f2 . x0)) - ((Rdiff f2,x0) * (f1 . x0))) / ((f2 . x0) ^2 ) )
A9: 0 + x0 = x0 ;
set r3 = min r0,r2;
0 <= min r0,r2 by A7, A3, XXREAL_0:15;
then A10: x0 <= x0 + (min r0,r2) by A9, XREAL_1:8;
min r0,r2 <= r2 by XXREAL_0:17;
then A11: x0 + (min r0,r2) <= x0 + r2 by XREAL_1:9;
then x0 <= x0 + r2 by A10, XXREAL_0:2;
then A12: x0 in [.x0,(x0 + r2).] by XXREAL_1:1;
x0 + (min r0,r2) in { g where g is Real : ( x0 <= g & g <= x0 + r2 ) } by A10, A11;
then x0 + (min r0,r2) in [.x0,(x0 + r2).] by RCOMP_1:def 1;
then [.x0,(x0 + (min r0,r2)).] c= [.x0,(x0 + r2).] by A12, XXREAL_2:def 12;
then A13: [.x0,(x0 + (min r0,r2)).] c= dom f2 by A4, XBOOLE_1:1;
min r0,r2 <= r0 by XXREAL_0:17;
then A14: x0 + (min r0,r2) <= x0 + r0 by XREAL_1:9;
then x0 <= x0 + r0 by A10, XXREAL_0:2;
then A15: x0 in [.x0,(x0 + r0).] by XXREAL_1:1;
A16: x0 + 0 = x0 ;
set r = min r1,(min r0,r2);
A17: 0 < min r0,r2 by A7, A3, XXREAL_0:15;
then 0 <= min r1,(min r0,r2) by A5, XXREAL_0:15;
then A18: x0 <= x0 + (min r1,(min r0,r2)) by A16, XREAL_1:9;
min r1,(min r0,r2) <= min r0,r2 by XXREAL_0:17;
then A19: x0 + (min r1,(min r0,r2)) <= x0 + (min r0,r2) by XREAL_1:9;
then x0 <= x0 + (min r0,r2) by A18, XXREAL_0:2;
then A20: x0 in [.x0,(x0 + (min r0,r2)).] by XXREAL_1:1;
x0 + (min r0,r2) in { g where g is Real : ( x0 <= g & g <= x0 + r0 ) } by A10, A14;
then x0 + (min r0,r2) in [.x0,(x0 + r0).] by RCOMP_1:def 1;
then A21: [.x0,(x0 + (min r0,r2)).] c= [.x0,(x0 + r0).] by A15, XXREAL_2:def 12;
x0 + (min r1,(min r0,r2)) in { g where g is Real : ( x0 <= g & g <= x0 + (min r0,r2) ) } by A18, A19;
then x0 + (min r1,(min r0,r2)) in [.x0,(x0 + (min r0,r2)).] by RCOMP_1:def 1;
then A22: [.x0,(x0 + (min r1,(min r0,r2))).] c= [.x0,(x0 + (min r0,r2)).] by A20, XXREAL_2:def 12;
[.x0,(x0 + (min r1,(min r0,r2))).] c= dom (f2 ^ )

proof

assume not [.x0,(x0 + (min r1,(min r0,r2))).] c= dom (f2 ^ ) ; :: thesis: contradiction
then consider x being set such that
A23: x in [.x0,(x0 + (min r1,(min r0,r2))).] and
A24: not x in dom (f2 ^ ) by TARSKI:def 3;
reconsider x = x as Real by A23;
A25: x in [.x0,(x0 + (min r0,r2)).] by A22, A23;
A26: not x in (dom f2) \ (f2 " {0 }) by A24, RFUNCT_1:def 8;

now

per cases ( not x in dom f2 or x in f2 " {0 } ) by A26, XBOOLE_0:def 5;

suppose not x in dom f2 ; :: thesis: contradiction

hence contradiction by A13, A25; :: thesis: verum

end;

suppose A27: x in f2 " {0 } ; :: thesis: contradiction

then f2 . x in {0 } by FUNCT_1:def 13;
then A28: f2 . x = 0 by TARSKI:def 1;
x in dom f2 by A27, FUNCT_1:def 13;
hence contradiction by A8, A21, A25, A28; :: thesis: verum

end;

end;

end;

hence contradiction ; :: thesis: verum

end;

then A29: [.x0,(x0 + (min r1,(min r0,r2))).] c= (dom f2) \ (f2 " {0 }) by RFUNCT_1:def 8;
min r1,(min r0,r2) <= r1 by XXREAL_0:17;
then A30: x0 + (min r1,(min r0,r2)) <= x0 + r1 by XREAL_1:9;
then x0 <= x0 + r1 by A18, XXREAL_0:2;
then A31: x0 in [.x0,(x0 + r1).] by XXREAL_1:1;
x0 + (min r1,(min r0,r2)) in { g where g is Real : ( x0 <= g & g <= x0 + r1 ) } by A18, A30;
then x0 + (min r1,(min r0,r2)) in [.x0,(x0 + r1).] by RCOMP_1:def 1;
then [.x0,(x0 + (min r1,(min r0,r2))).] c= [.x0,(x0 + r1).] by A31, XXREAL_2:def 12;
then A32: [.x0,(x0 + (min r1,(min r0,r2))).] c= dom f1 by A6, XBOOLE_1:1;
then [.x0,(x0 + (min r1,(min r0,r2))).] c= (dom f1) /\ ((dom f2) \ (f2 " {0 })) by A29, XBOOLE_1:19;
then A33: [.x0,(x0 + (min r1,(min r0,r2))).] c= dom (f1 / f2) by RFUNCT_1:def 4;
A34: for h being convergent_to_0 Real_Sequence
for c being V8() Real_Sequence st rng c = {x0} & rng (h + c) c= dom (f1 / f2) & ( for n being Element of NAT holds h . n > 0 ) holds
( (h " ) (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c)) is convergent & lim ((h " ) (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c))) = (((Rdiff f1,x0) * (f2 . x0)) - ((Rdiff f2,x0) * (f1 . x0))) / ((f2 . x0) ^2 ) )

proof

let h be convergent_to_0 Real_Sequence; :: thesis: for c being V8() Real_Sequence st rng c = {x0} & rng (h + c) c= dom (f1 / f2) & ( for n being Element of NAT holds h . n > 0 ) holds
( (h " ) (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c)) is convergent & lim ((h " ) (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c))) = (((Rdiff f1,x0) * (f2 . x0)) - ((Rdiff f2,x0) * (f1 . x0))) / ((f2 . x0) ^2 ) )
let c be V8() Real_Sequence; :: thesis: ( rng c = {x0} & rng (h + c) c= dom (f1 / f2) & ( for n being Element of NAT holds h . n > 0 ) implies ( (h " ) (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c)) is convergent & lim ((h " ) (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c))) = (((Rdiff f1,x0) * (f2 . x0)) - ((Rdiff f2,x0) * (f1 . x0))) / ((f2 . x0) ^2 ) ) )
assume that
A35: rng c = {x0} and
A36: rng (h + c) c= dom (f1 / f2) and
A37: for n being Element of NAT holds h . n > 0 ; :: thesis: ( (h " ) (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c)) is convergent & lim ((h " ) (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c))) = (((Rdiff f1,x0) * (f2 . x0)) - ((Rdiff f2,x0) * (f1 . x0))) / ((f2 . x0) ^2 ) )
A38: rng (h + c) c= (dom f1) /\ ((dom f2) \ (f2 " {0 })) by A36, RFUNCT_1:def 4;
( 0 <= min r1,(min r0,r2) & x0 + 0 = x0 ) by A5, A17, XXREAL_0:15;
then x0 <= x0 + (min r1,(min r0,r2)) by XREAL_1:9;
then A39: x0 in [.x0,(x0 + (min r1,(min r0,r2))).] by XXREAL_1:1;
then A40: x0 in dom f1 by A32;
A41: rng c c= dom f1

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in rng c or x in dom f1 )
assume x in rng c ; :: thesis: x in dom f1
hence x in dom f1 by A35, A40, TARSKI:def 1; :: thesis: verum

end;

(dom f1) /\ ((dom f2) \ (f2 " {0 })) c= dom f1 by XBOOLE_1:17;
then A42: rng (h + c) c= dom f1 by A38, XBOOLE_1:1;
then A43: lim ((h " ) (#) ((f1 /* (h + c)) - (f1 /* c))) = Rdiff f1,x0 by A1, A35, A37, Th15;
A44: x0 in (dom f2) \ (f2 " {0 }) by A29, A39;
rng c c= (dom f2) \ (f2 " {0 })

proof

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in rng c or x in (dom f2) \ (f2 " {0 }) )
assume x in rng c ; :: thesis: x in (dom f2) \ (f2 " {0 })
hence x in (dom f2) \ (f2 " {0 }) by A35, A44, TARSKI:def 1; :: thesis: verum

end;

then A45: rng c c= dom (f2 ^ ) by RFUNCT_1:def 8;
then A46: rng c c= (dom f1) /\ (dom (f2 ^ )) by A41, XBOOLE_1:19;
A47: (h " ) (#) ((f1 /* (h + c)) - (f1 /* c)) is convergent by A1, A35, A37, A42, Def3;
A48: f2 /* c is non-zero by A45, RFUNCT_2:26;

A49: now

let n be Element of NAT ; :: thesis: ((h " ) (#) (((f1 /* (h + c)) (#) (f2 /* c)) - ((f1 /* c) (#) (f2 /* (h + c))))) . n = ((((h " ) (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c)) - ((f1 /* c) (#) ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c))))) . n
thus ((h " ) (#) (((f1 /* (h + c)) (#) (f2 /* c)) - ((f1 /* c) (#) (f2 /* (h + c))))) . n = ((h " ) . n) * ((((f1 /* (h + c)) (#) (f2 /* c)) - ((f1 /* c) (#) (f2 /* (h + c)))) . n) by SEQ_1:12
.= ((h " ) . n) * ((((f1 /* (h + c)) (#) (f2 /* c)) . n) - (((f1 /* c) (#) (f2 /* (h + c))) . n)) by RFUNCT_2:6
.= ((h " ) . n) * ((((f1 /* (h + c)) . n) * ((f2 /* c) . n)) - (((f1 /* c) (#) (f2 /* (h + c))) . n)) by SEQ_1:12
.= ((h " ) . n) * ((((((f1 /* (h + c)) . n) - ((f1 /* c) . n)) * ((f2 /* c) . n)) + (((f1 /* c) . n) * ((f2 /* c) . n))) - (((f1 /* c) . n) * ((f2 /* (h + c)) . n))) by SEQ_1:12
.= ((((h " ) . n) * (((f1 /* (h + c)) . n) - ((f1 /* c) . n))) * ((f2 /* c) . n)) - (((f1 /* c) . n) * (((h " ) . n) * (((f2 /* (h + c)) . n) - ((f2 /* c) . n))))
.= ((((h " ) . n) * (((f1 /* (h + c)) - (f1 /* c)) . n)) * ((f2 /* c) . n)) - (((f1 /* c) . n) * (((h " ) . n) * (((f2 /* (h + c)) . n) - ((f2 /* c) . n)))) by RFUNCT_2:6
.= ((((h " ) . n) * (((f1 /* (h + c)) - (f1 /* c)) . n)) * ((f2 /* c) . n)) - (((f1 /* c) . n) * (((h " ) . n) * (((f2 /* (h + c)) - (f2 /* c)) . n))) by RFUNCT_2:6
.= ((((h " ) (#) ((f1 /* (h + c)) - (f1 /* c))) . n) * ((f2 /* c) . n)) - (((f1 /* c) . n) * (((h " ) . n) * (((f2 /* (h + c)) - (f2 /* c)) . n))) by SEQ_1:12
.= ((((h " ) (#) ((f1 /* (h + c)) - (f1 /* c))) . n) * ((f2 /* c) . n)) - (((f1 /* c) . n) * (((h " ) (#) ((f2 /* (h + c)) - (f2 /* c))) . n)) by SEQ_1:12
.= ((((h " ) (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c)) . n) - (((f1 /* c) . n) * (((h " ) (#) ((f2 /* (h + c)) - (f2 /* c))) . n)) by SEQ_1:12
.= ((((h " ) (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c)) . n) - (((f1 /* c) (#) ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c)))) . n) by SEQ_1:12
.= ((((h " ) (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c)) - ((f1 /* c) (#) ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c))))) . n by RFUNCT_2:6 ; :: thesis: verum

end;

now

let n be Element of NAT ; :: thesis: ((f2 /* c) + ((f2 /* (h + c)) - (f2 /* c))) . n = (f2 /* (h + c)) . n
thus ((f2 /* c) + ((f2 /* (h + c)) - (f2 /* c))) . n = ((f2 /* c) . n) + (((f2 /* (h + c)) - (f2 /* c)) . n) by SEQ_1:11
.= ((f2 /* c) . n) + (((f2 /* (h + c)) . n) - ((f2 /* c) . n)) by RFUNCT_2:6
.= (f2 /* (h + c)) . n ; :: thesis: verum

end;

then A50: (f2 /* c) + ((f2 /* (h + c)) - (f2 /* c)) = f2 /* (h + c) by FUNCT_2:113;
A51: lim h = 0 by FDIFF_1:def 1;
(dom f1) /\ ((dom f2) \ (f2 " {0 })) c= (dom f2) \ (f2 " {0 }) by XBOOLE_1:17;
then A52: rng (h + c) c= (dom f2) \ (f2 " {0 }) by A38, XBOOLE_1:1;
then A53: rng (h + c) c= dom (f2 ^ ) by RFUNCT_1:def 8;
then A54: rng (h + c) c= (dom f1) /\ (dom (f2 ^ )) by A42, XBOOLE_1:19;
A55: f2 /* (h + c) is non-zero by A53, RFUNCT_2:26;
then A56: (f2 /* (h + c)) (#) (f2 /* c) is non-zero by A48, SEQ_1:43;
(h " ) (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c)) = (h " ) (#) (((f1 (#) (f2 ^ )) /* (h + c)) - ((f1 / f2) /* c)) by RFUNCT_1:47
.= (h " ) (#) (((f1 (#) (f2 ^ )) /* (h + c)) - ((f1 (#) (f2 ^ )) /* c)) by RFUNCT_1:47
.= (h " ) (#) (((f1 /* (h + c)) (#) ((f2 ^ ) /* (h + c))) - ((f1 (#) (f2 ^ )) /* c)) by A54, RFUNCT_2:23
.= (h " ) (#) (((f1 /* (h + c)) /" (f2 /* (h + c))) - ((f1 (#) (f2 ^ )) /* c)) by A53, RFUNCT_2:27
.= (h " ) (#) (((f1 /* (h + c)) /" (f2 /* (h + c))) - ((f1 /* c) (#) ((f2 ^ ) /* c))) by A46, RFUNCT_2:23
.= (h " ) (#) (((f1 /* (h + c)) /" (f2 /* (h + c))) - ((f1 /* c) /" (f2 /* c))) by A45, RFUNCT_2:27
.= (h " ) (#) ((((f1 /* (h + c)) (#) (f2 /* c)) - ((f1 /* c) (#) (f2 /* (h + c)))) /" ((f2 /* (h + c)) (#) (f2 /* c))) by A55, A48, SEQ_1:58
.= ((h " ) (#) (((f1 /* (h + c)) (#) (f2 /* c)) - ((f1 /* c) (#) (f2 /* (h + c))))) /" ((f2 /* (h + c)) (#) (f2 /* c)) by SEQ_1:49 ;
then A57: (h " ) (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c)) = ((((h " ) (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c)) - ((f1 /* c) (#) ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c))))) /" ((f2 /* (h + c)) (#) (f2 /* c)) by A49, FUNCT_2:113;
(dom f2) \ (f2 " {0 }) c= dom f2 by XBOOLE_1:36;
then A58: rng (h + c) c= dom f2 by A52, XBOOLE_1:1;
then A59: lim ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c))) = Rdiff f2,x0 by A2, A35, A37, Th15;
Rdiff f2,x0 = Rdiff f2,x0 ;
then A60: (h " ) (#) ((f2 /* (h + c)) - (f2 /* c)) is convergent by A2, A35, A37, A58, Th15;

now

let n be Element of NAT ; :: thesis: (h (#) ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c)))) . n = ((f2 /* (h + c)) - (f2 /* c)) . n
A61: h . n <> 0 by A37;
thus (h (#) ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c)))) . n = ((h (#) (h " )) (#) ((f2 /* (h + c)) - (f2 /* c))) . n by SEQ_1:22
.= ((h (#) (h " )) . n) * (((f2 /* (h + c)) - (f2 /* c)) . n) by SEQ_1:12
.= ((h . n) * ((h " ) . n)) * (((f2 /* (h + c)) - (f2 /* c)) . n) by SEQ_1:12
.= ((h . n) * ((h . n) " )) * (((f2 /* (h + c)) - (f2 /* c)) . n) by VALUED_1:10
.= 1 * (((f2 /* (h + c)) - (f2 /* c)) . n) by A61, XCMPLX_0:def 7
.= ((f2 /* (h + c)) - (f2 /* c)) . n ; :: thesis: verum

end;

then A62: h (#) ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c))) = (f2 /* (h + c)) - (f2 /* c) by FUNCT_2:113;
A63: for m being Element of NAT holds c . m = x0

proof

let m be Element of NAT ; :: thesis: c . m = x0
c . m in rng c by VALUED_0:28;
hence c . m = x0 by A35, TARSKI:def 1; :: thesis: verum

end;

A64: for g being real number st 0 < g holds
ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs (((f1 /* c) . m) - (f1 . x0)) < g

proof

let g be real number ; :: thesis: ( 0 < g implies ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs (((f1 /* c) . m) - (f1 . x0)) < g )
assume A65: 0 < g ; :: thesis: ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs (((f1 /* c) . m) - (f1 . x0)) < g
take n = 0 ; :: thesis: for m being Element of NAT st n <= m holds
abs (((f1 /* c) . m) - (f1 . x0)) < g
let m be Element of NAT ; :: thesis: ( n <= m implies abs (((f1 /* c) . m) - (f1 . x0)) < g )
assume n <= m ; :: thesis: abs (((f1 /* c) . m) - (f1 . x0)) < g
abs (((f1 /* c) . m) - (f1 . x0)) = abs ((f1 . (c . m)) - (f1 . x0)) by A41, FUNCT_2:185
.= abs ((f1 . x0) - (f1 . x0)) by A63
.= 0 by ABSVALUE:def 1 ;
hence abs (((f1 /* c) . m) - (f1 . x0)) < g by A65; :: thesis: verum

end;

then A66: f1 /* c is convergent by SEQ_2:def 6;
then A67: lim (f1 /* c) = f1 . x0 by A64, SEQ_2:def 7;
dom (f2 ^ ) = (dom f2) \ (f2 " {0 }) by RFUNCT_1:def 8;
then A68: dom (f2 ^ ) c= dom f2 by XBOOLE_1:36;
A69: for g being real number st 0 < g holds
ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs (((f2 /* c) . m) - (f2 . x0)) < g

proof

let g be real number ; :: thesis: ( 0 < g implies ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs (((f2 /* c) . m) - (f2 . x0)) < g )
assume A70: 0 < g ; :: thesis: ex n being Element of NAT st
for m being Element of NAT st n <= m holds
abs (((f2 /* c) . m) - (f2 . x0)) < g
take n = 0 ; :: thesis: for m being Element of NAT st n <= m holds
abs (((f2 /* c) . m) - (f2 . x0)) < g
let m be Element of NAT ; :: thesis: ( n <= m implies abs (((f2 /* c) . m) - (f2 . x0)) < g )
assume n <= m ; :: thesis: abs (((f2 /* c) . m) - (f2 . x0)) < g
abs (((f2 /* c) . m) - (f2 . x0)) = abs ((f2 . (c . m)) - (f2 . x0)) by A45, A68, FUNCT_2:185, XBOOLE_1:1
.= abs ((f2 . x0) - (f2 . x0)) by A63
.= 0 by ABSVALUE:def 1 ;
hence abs (((f2 /* c) . m) - (f2 . x0)) < g by A70; :: thesis: verum

end;

then A71: f2 /* c is convergent by SEQ_2:def 6;
then A72: lim (f2 /* c) = f2 . x0 by A69, SEQ_2:def 7;
A73: h is convergent by FDIFF_1:def 1;
then h (#) ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c))) is convergent by A60, SEQ_2:28;
then A74: f2 /* (h + c) is convergent by A71, A62, A50, SEQ_2:19;
then A75: (f2 /* (h + c)) (#) (f2 /* c) is convergent by A71, SEQ_2:28;
(h " ) (#) ((f2 /* (h + c)) - (f2 /* c)) is convergent by A2, A35, A37, A58, Def3;
then lim (h (#) ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c)))) = (lim h) * (lim ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c)))) by A73, SEQ_2:29
.= 0 by A51 ;
then 0 = (lim (f2 /* (h + c))) - (f2 . x0) by A71, A72, A62, A74, SEQ_2:26;
then A76: lim ((f2 /* (h + c)) (#) (f2 /* c)) = (f2 . x0) ^2 by A71, A72, A74, SEQ_2:29;
A77: lim ((f2 /* (h + c)) (#) (f2 /* c)) <> 0

proof

assume not lim ((f2 /* (h + c)) (#) (f2 /* c)) <> 0 ; :: thesis: contradiction
then f2 . x0 = 0 by A76, XCMPLX_1:6;
hence contradiction by A8, A4, A15, A12; :: thesis: verum

end;

Rdiff f1,x0 = Rdiff f1,x0 ;
then (h " ) (#) ((f1 /* (h + c)) - (f1 /* c)) is convergent by A1, A35, A37, A42, Th15;
then A78: ((h " ) (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c) is convergent by A71, SEQ_2:28;
A79: (f1 /* c) (#) ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c))) is convergent by A60, A66, SEQ_2:28;
then A80: (((h " ) (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c)) - ((f1 /* c) (#) ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c)))) is convergent by A78, SEQ_2:25;
then lim ((h " ) (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c))) = (lim ((((h " ) (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c)) - ((f1 /* c) (#) ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c)))))) / (lim ((f2 /* (h + c)) (#) (f2 /* c))) by A56, A75, A77, A57, SEQ_2:38
.= ((lim (((h " ) (#) ((f1 /* (h + c)) - (f1 /* c))) (#) (f2 /* c))) - (lim ((f1 /* c) (#) ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c)))))) / (lim ((f2 /* (h + c)) (#) (f2 /* c))) by A79, A78, SEQ_2:26
.= (((lim ((h " ) (#) ((f1 /* (h + c)) - (f1 /* c)))) * (lim (f2 /* c))) - (lim ((f1 /* c) (#) ((h " ) (#) ((f2 /* (h + c)) - (f2 /* c)))))) / (lim ((f2 /* (h + c)) (#) (f2 /* c))) by A47, A71, SEQ_2:29
.= (((Rdiff f1,x0) * (f2 . x0)) - ((Rdiff f2,x0) * (f1 . x0))) / ((f2 . x0) ^2 ) by A43, A60, A59, A66, A67, A72, A76, SEQ_2:29 ;
hence ( (h " ) (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c)) is convergent & lim ((h " ) (#) (((f1 / f2) /* (h + c)) - ((f1 / f2) /* c))) = (((Rdiff f1,x0) * (f2 . x0)) - ((Rdiff f2,x0) * (f1 . x0))) / ((f2 . x0) ^2 ) ) by A56, A75, A77, A80, A57, SEQ_2:37; :: thesis: verum

end;

0 < min r1,(min r0,r2) by A5, A17, XXREAL_0:15;
hence ( f1 / f2 is_right_differentiable_in x0 & Rdiff (f1 / f2),x0 = (((Rdiff f1,x0) * (f2 . x0)) - ((Rdiff f2,x0) * (f1 . x0))) / ((f2 . x0) ^2 ) ) by A33, A34, Th15; :: thesis: verum