let n be Element of NAT ; :: thesis: for h, x being Real
for f1, f2 being Function of REAL ,REAL holds ((bdif (f1 - f2),h) . (n + 1)) . x = (((bdif f1,h) . (n + 1)) . x) - (((bdif f2,h) . (n + 1)) . x)
let h, x be Real; :: thesis: for f1, f2 being Function of REAL ,REAL holds ((bdif (f1 - f2),h) . (n + 1)) . x = (((bdif f1,h) . (n + 1)) . x) - (((bdif f2,h) . (n + 1)) . x)
let f1, f2 be Function of REAL ,REAL ; :: thesis: ((bdif (f1 - f2),h) . (n + 1)) . x = (((bdif f1,h) . (n + 1)) . x) - (((bdif f2,h) . (n + 1)) . x)
defpred S₁[ Element of NAT ] means for x being Real holds ((bdif (f1 - f2),h) . ($1 + 1)) . x = (((bdif f1,h) . ($1 + 1)) . x) - (((bdif f2,h) . ($1 + 1)) . x);
A1: S₁[ 0 ]

proof

let x be Real; :: thesis: ((bdif (f1 - f2),h) . (0 + 1)) . x = (((bdif f1,h) . (0 + 1)) . x) - (((bdif f2,h) . (0 + 1)) . x)
x in REAL ;
then ( x in dom f1 & x in dom f2 ) by FUNCT_2:def 1;
then x in (dom f1) /\ (dom f2) by XBOOLE_0:def 4;
then A2: x in dom (f1 - f2) by VALUED_1:12;
x - h in REAL ;
then ( x - h in dom f1 & x - h in dom f2 ) by FUNCT_2:def 1;
then x - h in (dom f1) /\ (dom f2) by XBOOLE_0:def 4;
then A3: x - h in dom (f1 - f2) by VALUED_1:12;
((bdif (f1 - f2),h) . (0 + 1)) . x = (bD ((bdif (f1 - f2),h) . 0 ),h) . x by Def7
.= (bD (f1 - f2),h) . x by Def7
.= ((f1 - f2) . x) - ((f1 - f2) . (x - h)) by Th4
.= ((f1 . x) - (f2 . x)) - ((f1 - f2) . (x - h)) by A2, VALUED_1:13
.= ((f1 . x) - (f2 . x)) - ((f1 . (x - h)) - (f2 . (x - h))) by A3, VALUED_1:13
.= ((f1 . x) - (f1 . (x - h))) - ((f2 . x) - (f2 . (x - h)))
.= ((bD f1,h) . x) - ((f2 . x) - (f2 . (x - h))) by Th4
.= ((bD f1,h) . x) - ((bD f2,h) . x) by Th4
.= ((bD ((bdif f1,h) . 0 ),h) . x) - ((bD f2,h) . x) by Def7
.= ((bD ((bdif f1,h) . 0 ),h) . x) - ((bD ((bdif f2,h) . 0 ),h) . x) by Def7
.= (((bdif f1,h) . (0 + 1)) . x) - ((bD ((bdif f2,h) . 0 ),h) . x) by Def7
.= (((bdif f1,h) . (0 + 1)) . x) - (((bdif f2,h) . (0 + 1)) . x) by Def7 ;
hence ((bdif (f1 - f2),h) . (0 + 1)) . x = (((bdif f1,h) . (0 + 1)) . x) - (((bdif f2,h) . (0 + 1)) . x) ; :: thesis: verum

end;

A4: for k being Element of NAT st S₁[k] holds
S₁[k + 1]

proof

let k be Element of NAT ; :: thesis: ( S₁[k] implies S₁[k + 1] )
assume A5: for x being Real holds ((bdif (f1 - f2),h) . (k + 1)) . x = (((bdif f1,h) . (k + 1)) . x) - (((bdif f2,h) . (k + 1)) . x) ; :: thesis: S₁[k + 1]
let x be Real; :: thesis: ((bdif (f1 - f2),h) . ((k + 1) + 1)) . x = (((bdif f1,h) . ((k + 1) + 1)) . x) - (((bdif f2,h) . ((k + 1) + 1)) . x)
A6: ( ((bdif (f1 - f2),h) . (k + 1)) . x = (((bdif f1,h) . (k + 1)) . x) - (((bdif f2,h) . (k + 1)) . x) & ((bdif (f1 - f2),h) . (k + 1)) . (x - h) = (((bdif f1,h) . (k + 1)) . (x - h)) - (((bdif f2,h) . (k + 1)) . (x - h)) ) by A5;
A7: (bdif (f1 - f2),h) . (k + 1) is Function of REAL ,REAL by Th12;
A8: (bdif f2,h) . (k + 1) is Function of REAL ,REAL by Th12;
A9: (bdif f1,h) . (k + 1) is Function of REAL ,REAL by Th12;
((bdif (f1 - f2),h) . ((k + 1) + 1)) . x = (bD ((bdif (f1 - f2),h) . (k + 1)),h) . x by Def7
.= (((bdif (f1 - f2),h) . (k + 1)) . x) - (((bdif (f1 - f2),h) . (k + 1)) . (x - h)) by A7, Th4
.= ((((bdif f1,h) . (k + 1)) . x) - (((bdif f1,h) . (k + 1)) . (x - h))) - ((((bdif f2,h) . (k + 1)) . x) - (((bdif f2,h) . (k + 1)) . (x - h))) by A6
.= ((bD ((bdif f1,h) . (k + 1)),h) . x) - ((((bdif f2,h) . (k + 1)) . x) - (((bdif f2,h) . (k + 1)) . (x - h))) by A9, Th4
.= ((bD ((bdif f1,h) . (k + 1)),h) . x) - ((bD ((bdif f2,h) . (k + 1)),h) . x) by A8, Th4
.= (((bdif f1,h) . ((k + 1) + 1)) . x) - ((bD ((bdif f2,h) . (k + 1)),h) . x) by Def7
.= (((bdif f1,h) . ((k + 1) + 1)) . x) - (((bdif f2,h) . ((k + 1) + 1)) . x) by Def7 ;
hence ((bdif (f1 - f2),h) . ((k + 1) + 1)) . x = (((bdif f1,h) . ((k + 1) + 1)) . x) - (((bdif f2,h) . ((k + 1) + 1)) . x) ; :: thesis: verum

end;

for n being Element of NAT holds S₁[n] from NAT_1:sch 1(A1, A4);
hence ((bdif (f1 - f2),h) . (n + 1)) . x = (((bdif f1,h) . (n + 1)) . x) - (((bdif f2,h) . (n + 1)) . x) ; :: thesis: verum