let s be Complex_Sequence; :: thesis: ( s is convergent & lim s <> 0c & s is non-empty implies lim (s " ) = (lim s) " )
assume that
A1: s is convergent and
A2: lim s <> 0c and
A3: s is non-empty ; :: thesis: lim (s " ) = (lim s) "
consider n1 being Element of NAT such that
A4: for m being Element of NAT st n1 <= m holds
|.(lim s).| / 2 < |.(s . m).| by A1, A2, Th33;
A5: 0 < |.(lim s).| by A2, COMPLEX1:133;
then 0 * 0 < |.(lim s).| * |.(lim s).| by XREAL_1:98;
then A6: 0 < (|.(lim s).| * |.(lim s).|) / 2 by XREAL_1:217;
A7: 0 <> |.(lim s).| by A2, COMPLEX1:133;

A8: now

let p be Real; :: thesis: ( 0 < p implies ex n being Element of NAT st
for m being Element of NAT st n <= m holds
|.(((s " ) . m) - ((lim s) " )).| < p )
A9: 0 <> |.(lim s).| / 2 by A2, COMPLEX1:133;
A10: (p * (|.(lim s).| / 2)) / (|.(lim s).| / 2) = (p * (|.(lim s).| / 2)) * ((|.(lim s).| / 2) " ) by XCMPLX_0:def 9
.= p * ((|.(lim s).| / 2) * ((|.(lim s).| / 2) " ))
.= p * 1 by A9, XCMPLX_0:def 7
.= p ;
assume A11: 0 < p ; :: thesis: ex n being Element of NAT st
for m being Element of NAT st n <= m holds
|.(((s " ) . m) - ((lim s) " )).| < p
then 0 * 0 < p * ((|.(lim s).| * |.(lim s).|) / 2) by A6, XREAL_1:98;
then consider n2 being Element of NAT such that
A12: for m being Element of NAT st n2 <= m holds
|.((s . m) - (lim s)).| < p * ((|.(lim s).| * |.(lim s).|) / 2) by A1, Def5;
take n = n1 + n2; :: thesis: for m being Element of NAT st n <= m holds
|.(((s " ) . m) - ((lim s) " )).| < p
let m be Element of NAT ; :: thesis: ( n <= m implies |.(((s " ) . m) - ((lim s) " )).| < p )
assume A13: n <= m ; :: thesis: |.(((s " ) . m) - ((lim s) " )).| < p
n1 <= n1 + n2 by NAT_1:12;
then n1 <= m by A13, XXREAL_0:2;
then A14: |.(lim s).| / 2 < |.(s . m).| by A4;
A15: 0 < |.(lim s).| / 2 by A5, XREAL_1:217;
then 0 * 0 < p * (|.(lim s).| / 2) by A11, XREAL_1:98;
then A16: (p * (|.(lim s).| / 2)) / |.(s . m).| < (p * (|.(lim s).| / 2)) / (|.(lim s).| / 2) by A14, A15, XREAL_1:78;
A17: (p * ((|.(lim s).| * |.(lim s).|) / 2)) / (|.(s . m).| * |.(lim s).|) = (p * ((2 " ) * (|.(lim s).| * |.(lim s).|))) * ((|.(s . m).| * |.(lim s).|) " ) by XCMPLX_0:def 9
.= (p * (2 " )) * ((|.(lim s).| * |.(lim s).|) * ((|.(lim s).| * |.(s . m).|) " ))
.= (p * (2 " )) * ((|.(lim s).| * |.(lim s).|) * ((|.(lim s).| " ) * (|.(s . m).| " ))) by XCMPLX_1:205
.= (p * (2 " )) * ((|.(lim s).| * (|.(lim s).| * (|.(lim s).| " ))) * (|.(s . m).| " ))
.= (p * (2 " )) * ((|.(lim s).| * 1) * (|.(s . m).| " )) by A7, XCMPLX_0:def 7
.= (p * (|.(lim s).| / 2)) * (|.(s . m).| " )
.= (p * (|.(lim s).| / 2)) / |.(s . m).| by XCMPLX_0:def 9 ;
A18: s . m <> 0c by A3, COMSEQ_1:3;
then (s . m) * (lim s) <> 0c by A2, XCMPLX_1:6;
then 0 < |.((s . m) * (lim s)).| by COMPLEX1:133;
then A19: 0 < |.(s . m).| * |.(lim s).| by COMPLEX1:151;
n2 <= n by NAT_1:12;
then n2 <= m by A13, XXREAL_0:2;
then |.((s . m) - (lim s)).| < p * ((|.(lim s).| * |.(lim s).|) / 2) by A12;
then A20: |.((s . m) - (lim s)).| / (|.(s . m).| * |.(lim s).|) < (p * ((|.(lim s).| * |.(lim s).|) / 2)) / (|.(s . m).| * |.(lim s).|) by A19, XREAL_1:76;
|.(((s " ) . m) - ((lim s) " )).| = |.(((s . m) " ) - ((lim s) " )).| by VALUED_1:10
.= |.((s . m) - (lim s)).| / (|.(s . m).| * |.(lim s).|) by A2, A18, Th1 ;
hence |.(((s " ) . m) - ((lim s) " )).| < p by A20, A17, A16, A10, XXREAL_0:2; :: thesis: verum

end;

s " is convergent by A1, A2, A3, Th34;
hence lim (s " ) = (lim s) " by A8, Def5; :: thesis: verum