let X be ComplexUnitarySpace; :: thesis: for z being Complex
for seq being sequence of X st seq is convergent holds
z * seq is convergent
let z be Complex; :: thesis: for seq being sequence of X st seq is convergent holds
z * seq is convergent
let seq be sequence of X; :: thesis: ( seq is convergent implies z * seq is convergent )
assume seq is convergent ; :: thesis: z * seq is convergent
then consider g being Point of X such that
A1: for r being Real st r > 0 holds
ex m being Element of NAT st
for n being Element of NAT st n >= m holds
dist (seq . n),g < r by Def1;
take h = z * g; :: according to CLVECT_2:def 1 :: thesis: for r being Real st r > 0 holds
ex m being Element of NAT st
for n being Element of NAT st n >= m holds
dist ((z * seq) . n),h < r

A2: now

A3: 0 / |.z.| = 0 ;
assume A4: z <> 0 ; :: thesis: for r being Real st r > 0 holds
ex k being Element of NAT st
for n being Element of NAT st n >= k holds
dist ((z * seq) . n),h < r
then A5: |.z.| > 0 by COMPLEX1:133;
let r be Real; :: thesis: ( r > 0 implies ex k being Element of NAT st
for n being Element of NAT st n >= k holds
dist ((z * seq) . n),h < r )
assume r > 0 ; :: thesis: ex k being Element of NAT st
for n being Element of NAT st n >= k holds
dist ((z * seq) . n),h < r
then consider m1 being Element of NAT such that
A6: for n being Element of NAT st n >= m1 holds
dist (seq . n),g < r / |.z.| by A1, A5, A3, XREAL_1:76;
take k = m1; :: thesis: for n being Element of NAT st n >= k holds
dist ((z * seq) . n),h < r
let n be Element of NAT ; :: thesis: ( n >= k implies dist ((z * seq) . n),h < r )
assume n >= k ; :: thesis: dist ((z * seq) . n),h < r
then A7: dist (seq . n),g < r / |.z.| by A6;
A8: |.z.| <> 0 by A4, COMPLEX1:133;
A9: |.z.| * (r / |.z.|) = |.z.| * ((|.z.| " ) * r) by XCMPLX_0:def 9
.= (|.z.| * (|.z.| " )) * r
.= 1 * r by A8, XCMPLX_0:def 7
.= r ;
dist (z * (seq . n)),(z * g) = ||.((z * (seq . n)) - (z * g)).|| by CSSPACE:def 16
.= ||.(z * ((seq . n) - g)).|| by CLVECT_1:10
.= |.z.| * ||.((seq . n) - g).|| by CSSPACE:45
.= |.z.| * (dist (seq . n),g) by CSSPACE:def 16 ;
then dist (z * (seq . n)),h < r by A5, A7, A9, XREAL_1:70;
hence dist ((z * seq) . n),h < r by CLVECT_1:def 15; :: thesis: verum

end;

now

assume A10: z = 0 ; :: thesis: for r being Real st r > 0 holds
ex k being Element of NAT st
for n being Element of NAT st n >= k holds
dist ((z * seq) . n),h < r
let r be Real; :: thesis: ( r > 0 implies ex k being Element of NAT st
for n being Element of NAT st n >= k holds
dist ((z * seq) . n),h < r )
assume r > 0 ; :: thesis: ex k being Element of NAT st
for n being Element of NAT st n >= k holds
dist ((z * seq) . n),h < r
then consider m1 being Element of NAT such that
A11: for n being Element of NAT st n >= m1 holds
dist (seq . n),g < r by A1;
take k = m1; :: thesis: for n being Element of NAT st n >= k holds
dist ((z * seq) . n),h < r
let n be Element of NAT ; :: thesis: ( n >= k implies dist ((z * seq) . n),h < r )
assume n >= k ; :: thesis: dist ((z * seq) . n),h < r
then A12: dist (seq . n),g < r by A11;
dist (z * (seq . n)),(z * g) = dist (0c * (seq . n)),H₁(X) by A10, CLVECT_1:2
.= dist H₁(X),H₁(X) by CLVECT_1:2
.= 0 by CSSPACE:53 ;
then dist (z * (seq . n)),h < r by A12, CSSPACE:56;
hence dist ((z * seq) . n),h < r by CLVECT_1:def 15; :: thesis: verum

end;

hence for r being Real st r > 0 holds
ex m being Element of NAT st
for n being Element of NAT st n >= m holds
dist ((z * seq) . n),h < r by A2; :: thesis: verum