let X be Complex_Banach_Algebra; :: thesis: for n being Element of NAT
for z, w being Element of X st z,w are_commutative holds
(Partial_Sums ((z + w) ExpSeq )) . n = (Partial_Sums (Alfa n,z,w)) . n
let n be Element of NAT ; :: thesis: for z, w being Element of X st z,w are_commutative holds
(Partial_Sums ((z + w) ExpSeq )) . n = (Partial_Sums (Alfa n,z,w)) . n
let z, w be Element of X; :: thesis: ( z,w are_commutative implies (Partial_Sums ((z + w) ExpSeq )) . n = (Partial_Sums (Alfa n,z,w)) . n )
assume A1: z,w are_commutative ; :: thesis: (Partial_Sums ((z + w) ExpSeq )) . n = (Partial_Sums (Alfa n,z,w)) . n
defpred S₁[ Element of NAT ] means (Partial_Sums ((z + w) ExpSeq )) . $1 = (Partial_Sums (Alfa $1,z,w)) . $1;
A2: for k being Element of NAT st S₁[k] holds
S₁[k + 1]

proof

let k be Element of NAT ; :: thesis: ( S₁[k] implies S₁[k + 1] )
assume A3: (Partial_Sums ((z + w) ExpSeq )) . k = (Partial_Sums (Alfa k,z,w)) . k ; :: thesis: S₁[k + 1]
(k + 1) -' (k + 1) = 0 by XREAL_1:234;
then (Alfa (k + 1),z,w) . (k + 1) = ((z ExpSeq ) . (k + 1)) * ((Partial_Sums (w ExpSeq )) . 0 ) by Def6
.= ((z ExpSeq ) . (k + 1)) * ((w ExpSeq ) . 0 ) by BHSP_4:def 1
.= ((z ExpSeq ) . (k + 1)) * (1. X) by Th20
.= (z ExpSeq ) . (k + 1) by CLOPBAN3:42
.= (Expan_e (k + 1),z,w) . (k + 1) by Th23 ;
then A4: ((Partial_Sums (Expan_e (k + 1),z,w)) . k) + ((Alfa (k + 1),z,w) . (k + 1)) = (Partial_Sums (Expan_e (k + 1),z,w)) . (k + 1) by BHSP_4:def 1
.= (1r / ((k + 1) !c )) * ((z + w) #N (k + 1)) by A1, Th18 ;
(Partial_Sums (Alfa (k + 1),z,w)) . (k + 1) = ((Partial_Sums (Alfa (k + 1),z,w)) . k) + ((Alfa (k + 1),z,w) . (k + 1)) by BHSP_4:def 1
.= (((Partial_Sums (Alfa k,z,w)) . k) + ((Partial_Sums (Expan_e (k + 1),z,w)) . k)) + ((Alfa (k + 1),z,w) . (k + 1)) by Th22
.= ((Partial_Sums ((z + w) ExpSeq )) . k) + (((Partial_Sums (Expan_e (k + 1),z,w)) . k) + ((Alfa (k + 1),z,w) . (k + 1))) by A3, CLOPBAN3:42 ;
then (Partial_Sums (Alfa (k + 1),z,w)) . (k + 1) = ((Partial_Sums ((z + w) ExpSeq )) . k) + (((z + w) ExpSeq ) . (k + 1)) by A4, Def2
.= (Partial_Sums ((z + w) ExpSeq )) . (k + 1) by BHSP_4:def 1 ;
hence (Partial_Sums ((z + w) ExpSeq )) . (k + 1) = (Partial_Sums (Alfa (k + 1),z,w)) . (k + 1) ; :: thesis: verum

end;

A5: (Partial_Sums ((z + w) ExpSeq )) . 0 = ((z + w) ExpSeq ) . 0 by BHSP_4:def 1
.= 1. X by Th20 ;
A6: 0 -' 0 = 0 by XREAL_1:234;
(Partial_Sums (Alfa 0 ,z,w)) . 0 = (Alfa 0 ,z,w) . 0 by BHSP_4:def 1
.= ((z ExpSeq ) . 0 ) * ((Partial_Sums (w ExpSeq )) . 0 ) by A6, Def6
.= ((z ExpSeq ) . 0 ) * ((w ExpSeq ) . 0 ) by BHSP_4:def 1
.= (1. X) * ((w ExpSeq ) . 0 ) by Th20
.= (1. X) * (1. X) by Th20
.= 1. X by CLOPBAN3:42 ;
then A7: S₁[ 0 ] by A5;
for n being Element of NAT holds S₁[n] from NAT_1:sch 1(A7, A2);
hence (Partial_Sums ((z + w) ExpSeq )) . n = (Partial_Sums (Alfa n,z,w)) . n ; :: thesis: verum