let X, Y be ComplexLinearSpace; :: thesis: LinearOperators X,Y is linearly-closed
set W = LinearOperators X,Y;
A1: for c being Complex
for v being VECTOR of (ComplexVectSpace the carrier of X,Y) st v in LinearOperators X,Y holds
c * v in LinearOperators X,Y

proof

let c be Complex; :: thesis: for v being VECTOR of (ComplexVectSpace the carrier of X,Y) st v in LinearOperators X,Y holds
c * v in LinearOperators X,Y
let v be VECTOR of (ComplexVectSpace the carrier of X,Y); :: thesis: ( v in LinearOperators X,Y implies c * v in LinearOperators X,Y )
assume A2: v in LinearOperators X,Y ; :: thesis: c * v in LinearOperators X,Y
c * v is LinearOperator of X,Y

proof

reconsider f = c * v as Function of X,Y by FUNCT_2:121;
A3: f is homogeneous

proof

reconsider v9 = v as Element of Funcs the carrier of X,the carrier of Y ;
let x be VECTOR of X; :: according to CLOPBAN1:def 4 :: thesis: for r being Complex holds f . (r * x) = r * (f . x)
let s be Complex; :: thesis: f . (s * x) = s * (f . x)
A4: v9 is LinearOperator of X,Y by A2, Def5;
A5: f = (FuncExtMult the carrier of X,Y) . [c,v9] by CLVECT_1:def 1;
hence f . (s * x) = c * (v9 . (s * x)) by Th3
.= c * (s * (v9 . x)) by A4, Def4
.= (c * s) * (v9 . x) by CLVECT_1:def 4
.= s * (c * (v9 . x)) by CLVECT_1:def 4
.= s * (f . x) by A5, Th3 ;
:: thesis: verum

end;

f is additive

proof

reconsider v9 = v as Element of Funcs the carrier of X,the carrier of Y ;
let x, y be VECTOR of X; :: according to GRCAT_1:def 13 :: thesis: f . (x + y) = (f . x) + (f . y)
A6: v9 is LinearOperator of X,Y by A2, Def5;
A7: f = (FuncExtMult the carrier of X,Y) . [c,v9] by CLVECT_1:def 1;
hence f . (x + y) = c * (v9 . (x + y)) by Th3
.= c * ((v9 . x) + (v9 . y)) by A6, GRCAT_1:def 13
.= (c * (v9 . x)) + (c * (v9 . y)) by CLVECT_1:def 2
.= (f . x) + (c * (v9 . y)) by A7, Th3
.= (f . x) + (f . y) by A7, Th3 ;
:: thesis: verum

end;

hence c * v is LinearOperator of X,Y by A3; :: thesis: verum

end;

hence c * v in LinearOperators X,Y by Def5; :: thesis: verum

end;

for v, u being VECTOR of (ComplexVectSpace the carrier of X,Y) st v in LinearOperators X,Y & u in LinearOperators X,Y holds
v + u in LinearOperators X,Y

proof

let v, u be VECTOR of (ComplexVectSpace the carrier of X,Y); :: thesis: ( v in LinearOperators X,Y & u in LinearOperators X,Y implies v + u in LinearOperators X,Y )
assume that
A8: v in LinearOperators X,Y and
A9: u in LinearOperators X,Y ; :: thesis: v + u in LinearOperators X,Y
v + u is LinearOperator of X,Y

proof

reconsider f = v + u as Function of X,Y by FUNCT_2:121;
A10: f is homogeneous

proof

reconsider v9 = v, u9 = u as Element of Funcs the carrier of X,the carrier of Y ;
let x be VECTOR of X; :: according to CLOPBAN1:def 4 :: thesis: for r being Complex holds f . (r * x) = r * (f . x)
let s be Complex; :: thesis: f . (s * x) = s * (f . x)
A11: u9 is LinearOperator of X,Y by A9, Def5;
A12: v9 is LinearOperator of X,Y by A8, Def5;
thus f . (s * x) = (u9 . (s * x)) + (v9 . (s * x)) by LOPBAN_1:3
.= (s * (u9 . x)) + (v9 . (s * x)) by A11, Def4
.= (s * (u9 . x)) + (s * (v9 . x)) by A12, Def4
.= s * ((u9 . x) + (v9 . x)) by CLVECT_1:def 2
.= s * (f . x) by LOPBAN_1:3 ; :: thesis: verum

end;

f is additive

proof

reconsider v9 = v, u9 = u as Element of Funcs the carrier of X,the carrier of Y ;
let x, y be VECTOR of X; :: according to GRCAT_1:def 13 :: thesis: f . (x + y) = (f . x) + (f . y)
A13: u9 is LinearOperator of X,Y by A9, Def5;
A14: v9 is LinearOperator of X,Y by A8, Def5;
thus f . (x + y) = (u9 . (x + y)) + (v9 . (x + y)) by LOPBAN_1:3
.= ((u9 . x) + (u9 . y)) + (v9 . (x + y)) by A13, GRCAT_1:def 13
.= ((u9 . x) + (u9 . y)) + ((v9 . x) + (v9 . y)) by A14, GRCAT_1:def 13
.= (((u9 . x) + (u9 . y)) + (v9 . x)) + (v9 . y) by RLVECT_1:def 6
.= (((u9 . x) + (v9 . x)) + (u9 . y)) + (v9 . y) by RLVECT_1:def 6
.= ((f . x) + (u9 . y)) + (v9 . y) by LOPBAN_1:3
.= (f . x) + ((u9 . y) + (v9 . y)) by RLVECT_1:def 6
.= (f . x) + (f . y) by LOPBAN_1:3 ; :: thesis: verum

end;

hence v + u is LinearOperator of X,Y by A10; :: thesis: verum

end;

hence v + u in LinearOperators X,Y by Def5; :: thesis: verum

end;

hence LinearOperators X,Y is linearly-closed by A1, CLVECT_1:def 7; :: thesis: verum