let Y be non empty set ; :: thesis: for G being Subset of (PARTITIONS Y)
for u, a being Element of Funcs Y,BOOLEAN
for PA being a_partition of Y st u is_independent_of PA,G holds
All (u 'or' a),PA,G = u 'or' (All a,PA,G)
let G be Subset of (PARTITIONS Y); :: thesis: for u, a being Element of Funcs Y,BOOLEAN
for PA being a_partition of Y st u is_independent_of PA,G holds
All (u 'or' a),PA,G = u 'or' (All a,PA,G)
let u, a be Element of Funcs Y,BOOLEAN ; :: thesis: for PA being a_partition of Y st u is_independent_of PA,G holds
All (u 'or' a),PA,G = u 'or' (All a,PA,G)
let PA be a_partition of Y; :: thesis: ( u is_independent_of PA,G implies All (u 'or' a),PA,G = u 'or' (All a,PA,G) )
consider k3 being Function such that
A1: All (u 'or' a),PA,G = k3 and
A2: dom k3 = Y and
rng k3 c= BOOLEAN by FUNCT_2:def 2;
consider k4 being Function such that
A3: u 'or' (All a,PA,G) = k4 and
A4: dom k4 = Y and
rng k4 c= BOOLEAN by FUNCT_2:def 2;
assume u is_independent_of PA,G ; :: thesis: All (u 'or' a),PA,G = u 'or' (All a,PA,G)
then A5: u is_dependent_of CompF PA,G by Def8;
for z being Element of Y holds (B_INF (u 'or' a),(CompF PA,G)) . z = (u 'or' (B_INF a,(CompF PA,G))) . z

proof

let z be Element of Y; :: thesis: (B_INF (u 'or' a),(CompF PA,G)) . z = (u 'or' (B_INF a,(CompF PA,G))) . z
A6: (u 'or' (B_INF a,(CompF PA,G))) . z = (u . z) 'or' ((B_INF a,(CompF PA,G)) . z) by BVFUNC_1:def 7;

per cases ( for x being Element of Y st x in EqClass z,(CompF PA,G) holds
a . x = TRUE or ( ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not a . x = TRUE ) & ( for x being Element of Y st x in EqClass z,(CompF PA,G) holds
u . x = TRUE ) ) or ( ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not a . x = TRUE ) & ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not u . x = TRUE ) ) ) ;

suppose A7: for x being Element of Y st x in EqClass z,(CompF PA,G) holds
a . x = TRUE ; :: thesis: (B_INF (u 'or' a),(CompF PA,G)) . z = (u 'or' (B_INF a,(CompF PA,G))) . z

A8: for x being Element of Y st x in EqClass z,(CompF PA,G) holds
(u 'or' a) . x = TRUE

proof

let x be Element of Y; :: thesis: ( x in EqClass z,(CompF PA,G) implies (u 'or' a) . x = TRUE )
assume A9: x in EqClass z,(CompF PA,G) ; :: thesis: (u 'or' a) . x = TRUE
(u 'or' a) . x = (u . x) 'or' (a . x) by BVFUNC_1:def 7
.= (u . x) 'or' TRUE by A7, A9
.= TRUE by BINARITH:19 ;
hence (u 'or' a) . x = TRUE ; :: thesis: verum

end;

(B_INF a,(CompF PA,G)) . z = TRUE by A7, BVFUNC_1:def 19;
then (u 'or' (B_INF a,(CompF PA,G))) . z = TRUE by A6, BINARITH:19;
hence (B_INF (u 'or' a),(CompF PA,G)) . z = (u 'or' (B_INF a,(CompF PA,G))) . z by A8, BVFUNC_1:def 19; :: thesis: verum

end;

suppose A10: ( ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not a . x = TRUE ) & ( for x being Element of Y st x in EqClass z,(CompF PA,G) holds
u . x = TRUE ) ) ; :: thesis: (B_INF (u 'or' a),(CompF PA,G)) . z = (u 'or' (B_INF a,(CompF PA,G))) . z

A11: for x being Element of Y st x in EqClass z,(CompF PA,G) holds
(u 'or' a) . x = TRUE

proof

let x be Element of Y; :: thesis: ( x in EqClass z,(CompF PA,G) implies (u 'or' a) . x = TRUE )
assume A12: x in EqClass z,(CompF PA,G) ; :: thesis: (u 'or' a) . x = TRUE
(u 'or' a) . x = (u . x) 'or' (a . x) by BVFUNC_1:def 7
.= TRUE 'or' (a . x) by A10, A12
.= TRUE by BINARITH:19 ;
hence (u 'or' a) . x = TRUE ; :: thesis: verum

end;

z in EqClass z,(CompF PA,G) by EQREL_1:def 8;
then (u 'or' (B_INF a,(CompF PA,G))) . z = TRUE 'or' ((B_INF a,(CompF PA,G)) . z) by A6, A10;
then (u 'or' (B_INF a,(CompF PA,G))) . z = TRUE by BINARITH:19;
hence (B_INF (u 'or' a),(CompF PA,G)) . z = (u 'or' (B_INF a,(CompF PA,G))) . z by A11, BVFUNC_1:def 19; :: thesis: verum

end;

suppose A13: ( ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not a . x = TRUE ) & ex x being Element of Y st
( x in EqClass z,(CompF PA,G) & not u . x = TRUE ) ) ; :: thesis: (B_INF (u 'or' a),(CompF PA,G)) . z = (u 'or' (B_INF a,(CompF PA,G))) . z

then consider x2 being Element of Y such that
A14: x2 in EqClass z,(CompF PA,G) and
A15: u . x2 <> TRUE ;
consider x1 being Element of Y such that
A16: x1 in EqClass z,(CompF PA,G) and
A17: a . x1 <> TRUE by A13;
u . x1 = u . x2 by A5, A16, A14, BVFUNC_1:def 18;
then A18: u . x1 = FALSE by A15, XBOOLEAN:def 3;
A19: (B_INF a,(CompF PA,G)) . z = FALSE by A13, BVFUNC_1:def 19;
z in EqClass z,(CompF PA,G) by EQREL_1:def 8;
then A20: u . x1 = u . z by A5, A16, BVFUNC_1:def 18;
a . x1 = FALSE by A17, XBOOLEAN:def 3;
then (u 'or' a) . x1 = FALSE 'or' FALSE by A18, BVFUNC_1:def 7;
hence (B_INF (u 'or' a),(CompF PA,G)) . z = (u 'or' (B_INF a,(CompF PA,G))) . z by A6, A19, A16, A18, A20, BVFUNC_1:def 19; :: thesis: verum

end;

end;

end;

then for u being set st u in Y holds
k3 . u = k4 . u by A1, A3;
hence All (u 'or' a),PA,G = u 'or' (All a,PA,G) by A1, A2, A3, A4, FUNCT_1:9; :: thesis: verum