let r, s, p, q be ext-real number ; :: thesis: ( [.r,s.[ meets [.p,q.[ implies [.r,s.[ \/ [.p,q.[ = [.(min r,p),(max s,q).[ )
assume [.r,s.[ meets [.p,q.[ ; :: thesis: [.r,s.[ \/ [.p,q.[ = [.(min r,p),(max s,q).[
then consider u being ext-real number such that
A1: u in [.r,s.[ and
A2: u in [.p,q.[ by MEMBERED:def 20;
let t be ext-real number ; :: according to MEMBERED:def 14 :: thesis: ( ( not t in [.r,s.[ \/ [.p,q.[ or t in [.(min r,p),(max s,q).[ ) & ( not t in [.(min r,p),(max s,q).[ or t in [.r,s.[ \/ [.p,q.[ ) )
thus ( t in [.r,s.[ \/ [.p,q.[ implies t in [.(min r,p),(max s,q).[ ) :: thesis: ( not t in [.(min r,p),(max s,q).[ or t in [.r,s.[ \/ [.p,q.[ )

proof

assume t in [.r,s.[ \/ [.p,q.[ ; :: thesis: t in [.(min r,p),(max s,q).[
then ( t in [.r,s.[ or t in [.p,q.[ ) by XBOOLE_0:def 3;
then A3: ( ( r <= t & t < s ) or ( p <= t & t < q ) ) by Th3;
then A4: min r,p <= t by XXREAL_0:23;
t < max s,q by A3, XXREAL_0:30;
hence t in [.(min r,p),(max s,q).[ by A4, Th3; :: thesis: verum

end;

A5: r <= u by A1, Th3;
A6: u < s by A1, Th3;
A7: p <= u by A2, Th3;
A8: u < q by A2, Th3;
assume A9: t in [.(min r,p),(max s,q).[ ; :: thesis: t in [.r,s.[ \/ [.p,q.[
then A10: min r,p <= t by Th3;
A11: t < max s,q by A9, Th3;

per cases ( ( r <= t & t < s ) or ( p <= t & t < q ) or ( p <= t & t < s ) or ( r <= t & t < q ) ) by A10, A11, XXREAL_0:21, XXREAL_0:28;

suppose ( ( r <= t & t < s ) or ( p <= t & t < q ) ) ; :: thesis: t in [.r,s.[ \/ [.p,q.[

then ( t in [.r,s.[ or t in [.p,q.[ ) by Th3;
hence t in [.r,s.[ \/ [.p,q.[ by XBOOLE_0:def 3; :: thesis: verum

end;

suppose that A12: p <= t and
A13: t < s ; :: thesis: t in [.r,s.[ \/ [.p,q.[

( u <= t or t <= u ) ;
then ( r <= t or t < q ) by A5, A8, XXREAL_0:2;
then ( t in [.r,s.[ or t in [.p,q.[ ) by A12, A13, Th3;
hence t in [.r,s.[ \/ [.p,q.[ by XBOOLE_0:def 3; :: thesis: verum

end;

suppose that A14: r <= t and
A15: t < q ; :: thesis: t in [.r,s.[ \/ [.p,q.[

( u <= t or t <= u ) ;
then ( t < s or p <= t ) by A6, A7, XXREAL_0:2;
then ( t in [.r,s.[ or t in [.p,q.[ ) by A14, A15, Th3;
hence t in [.r,s.[ \/ [.p,q.[ by XBOOLE_0:def 3; :: thesis: verum

end;

end;