let M be non empty set ; :: thesis: for V being ComplexNormSpace
for f being PartFunc of M,the carrier of V
for X being set holds
( (- f) | X = - (f | X) & ||.f.|| | X = ||.(f | X).|| )
let V be ComplexNormSpace; :: thesis: for f being PartFunc of M,the carrier of V
for X being set holds
( (- f) | X = - (f | X) & ||.f.|| | X = ||.(f | X).|| )
let f be PartFunc of M,the carrier of V; :: thesis: for X being set holds
( (- f) | X = - (f | X) & ||.f.|| | X = ||.(f | X).|| )
let X be set ; :: thesis: ( (- f) | X = - (f | X) & ||.f.|| | X = ||.(f | X).|| )

A1: now

let c be Element of M; :: thesis: ( c in dom ((- f) | X) implies ((- f) | X) /. c = (- (f | X)) /. c )
assume A2: c in dom ((- f) | X) ; :: thesis: ((- f) | X) /. c = (- (f | X)) /. c
then A3: c in (dom (- f)) /\ X by RELAT_1:90;
then A4: c in X by XBOOLE_0:def 4;
A5: c in dom (- f) by A3, XBOOLE_0:def 4;
then c in dom f by Def6;
then c in (dom f) /\ X by A4, XBOOLE_0:def 4;
then A6: c in dom (f | X) by RELAT_1:90;
then A7: c in dom (- (f | X)) by Def6;
thus ((- f) | X) /. c = (- f) /. c by A2, PARTFUN2:32
.= - (f /. c) by A5, Def6
.= - ((f | X) /. c) by A6, PARTFUN2:32
.= (- (f | X)) /. c by A7, Def6 ; :: thesis: verum

end;

dom ((- f) | X) = (dom (- f)) /\ X by RELAT_1:90
.= (dom f) /\ X by Def6
.= dom (f | X) by RELAT_1:90
.= dom (- (f | X)) by Def6 ;
hence (- f) | X = - (f | X) by A1, PARTFUN2:3; :: thesis: ||.f.|| | X = ||.(f | X).||
A8: dom (||.f.|| | X) = (dom ||.f.||) /\ X by RELAT_1:90
.= (dom f) /\ X by Def5
.= dom (f | X) by RELAT_1:90
.= dom ||.(f | X).|| by Def5 ;

now

let c be Element of M; :: thesis: ( c in dom (||.f.|| | X) implies (||.f.|| | X) . c = ||.(f | X).|| . c )
assume A9: c in dom (||.f.|| | X) ; :: thesis: (||.f.|| | X) . c = ||.(f | X).|| . c
then A10: c in dom (f | X) by A8, Def5;
c in (dom ||.f.||) /\ X by A9, RELAT_1:90;
then A11: c in dom ||.f.|| by XBOOLE_0:def 4;
thus (||.f.|| | X) . c = ||.f.|| . c by A9, FUNCT_1:70
.= ||.(f /. c).|| by A11, Def5
.= ||.((f | X) /. c).|| by A10, PARTFUN2:32
.= ||.(f | X).|| . c by A8, A9, Def5 ; :: thesis: verum

end;

hence ||.f.|| | X = ||.(f | X).|| by A8, PARTFUN1:34; :: thesis: verum