let Z be open Subset of REAL ; :: thesis: ( Z c= dom (ln (#) arctan ) & Z c= ].(- 1),1.[ implies ( ln (#) arctan is_differentiable_on Z & ( for x being Real st x in Z holds
((ln (#) arctan ) `| Z) . x = ((arctan . x) / x) + ((ln . x) / (1 + (x ^2 ))) ) ) )
A1: right_open_halfline 0 = { g where g is Real : 0 < g } by XXREAL_1:230;
assume that
A2: Z c= dom (ln (#) arctan ) and
A3: Z c= ].(- 1),1.[ ; :: thesis: ( ln (#) arctan is_differentiable_on Z & ( for x being Real st x in Z holds
((ln (#) arctan ) `| Z) . x = ((arctan . x) / x) + ((ln . x) / (1 + (x ^2 ))) ) )
A4: arctan is_differentiable_on Z by A3, Th81;
Z c= (dom ln ) /\ (dom arctan ) by A2, VALUED_1:def 4;
then A5: Z c= dom ln by XBOOLE_1:18;
A6: for x being Real st x in Z holds
x > 0

proof

let x be Real; :: thesis: ( x in Z implies x > 0 )
assume x in Z ; :: thesis: x > 0
then x in right_open_halfline 0 by A5, TAYLOR_1:18;
then ex g being Real st
( x = g & 0 < g ) by A1;
hence x > 0 ; :: thesis: verum

end;

then for x being Real st x in Z holds
ln is_differentiable_in x by TAYLOR_1:18;
then A7: ln is_differentiable_on Z by A5, FDIFF_1:16;
A8: for x being Real st x in Z holds
diff ln ,x = 1 / x

proof

let x be Real; :: thesis: ( x in Z implies diff ln ,x = 1 / x )
assume x in Z ; :: thesis: diff ln ,x = 1 / x
then x > 0 by A6;
then x in right_open_halfline 0 by A1;
hence diff ln ,x = 1 / x by TAYLOR_1:18; :: thesis: verum

end;

for x being Real st x in Z holds
((ln (#) arctan ) `| Z) . x = ((arctan . x) / x) + ((ln . x) / (1 + (x ^2 )))

proof

let x be Real; :: thesis: ( x in Z implies ((ln (#) arctan ) `| Z) . x = ((arctan . x) / x) + ((ln . x) / (1 + (x ^2 ))) )
assume A9: x in Z ; :: thesis: ((ln (#) arctan ) `| Z) . x = ((arctan . x) / x) + ((ln . x) / (1 + (x ^2 )))
then ((ln (#) arctan ) `| Z) . x = ((arctan . x) * (diff ln ,x)) + ((ln . x) * (diff arctan ,x)) by A2, A7, A4, FDIFF_1:29
.= ((arctan . x) * (1 / x)) + ((ln . x) * (diff arctan ,x)) by A8, A9
.= ((arctan . x) * (1 / x)) + ((ln . x) * ((arctan `| Z) . x)) by A4, A9, FDIFF_1:def 8
.= (((arctan . x) * 1) / x) + ((ln . x) * (1 / (1 + (x ^2 )))) by A3, A9, Th81
.= ((arctan . x) / x) + ((ln . x) / (1 + (x ^2 ))) ;
hence ((ln (#) arctan ) `| Z) . x = ((arctan . x) / x) + ((ln . x) / (1 + (x ^2 ))) ; :: thesis: verum

end;

hence ( ln (#) arctan is_differentiable_on Z & ( for x being Real st x in Z holds
((ln (#) arctan ) `| Z) . x = ((arctan . x) / x) + ((ln . x) / (1 + (x ^2 ))) ) ) by A2, A7, A4, FDIFF_1:29; :: thesis: verum