let p be real number ; :: thesis: for s being Real_Sequence st p > 1 & ( for n being Element of NAT st n >= 1 holds
s . n = 1 / (n to_power p) ) holds
s is summable
let s be Real_Sequence; :: thesis: ( p > 1 & ( for n being Element of NAT st n >= 1 holds
s . n = 1 / (n to_power p) ) implies s is summable )
assume that
A1: p > 1 and
A2: for n being Element of NAT st n >= 1 holds
s . n = 1 / (n to_power p) ; :: thesis: s is summable
defpred S₁[ Element of NAT , real number ] means ( ( $1 = 0 & $2 = 1 ) or ( $1 >= 1 & $2 = 1 / ($1 to_power p) ) );
A3: for n being Element of NAT ex r being Real st S₁[n,r]

proof

let n be Element of NAT ; :: thesis: ex r being Real st S₁[n,r]
( n = 0 or n >= 1 )

proof

assume that
A4: n <> 0 and
A5: n < 1 ; :: thesis: contradiction
n >= 0 + 1 by A4, NAT_1:13;
hence contradiction by A5; :: thesis: verum

end;

hence ex r being Real st S₁[n,r] ; :: thesis: verum

end;

consider s1 being Real_Sequence such that
A6: for n being Element of NAT holds S₁[n,s1 . n] from FUNCT_2:sch 3(A3);
deffunc H₁( Element of NAT ) -> Element of REAL = (2 to_power $1) * (s1 . (2 to_power $1));
consider s2 being Real_Sequence such that
A7: for n being Element of NAT holds s2 . n = H₁(n) from SEQ_1:sch 1();
A8: s1 . 0 = 1 by A6;

now

let n be Element of NAT ; :: thesis: s1 . (n + 1) <= s1 . n

now

per cases ( n = 0 or ex m being Nat st n = m + 1 ) by NAT_1:6;

suppose A9: n = 0 ; :: thesis: s1 . (n + 1) <= s1 . n

then (n + 1) #R p >= 1 by A1, PREPOWER:99;
then A10: (n + 1) to_power p >= 1 by POWER:def 2;
s1 . (n + 1) = 1 / ((n + 1) to_power p) by A6;
hence s1 . (n + 1) <= s1 . n by A8, A9, A10, XREAL_1:213; :: thesis: verum

end;

suppose A11: ex m being Nat st n = m + 1 ; :: thesis: s1 . (n + 1) <= s1 . n

then n to_power p > 0 by POWER:39;
then 1 / (n to_power p) > 0 ;
then A12: s1 . n > 0 by A6;
A13: n / (n + 1) <= 1 by NAT_1:11, XREAL_1:185;
A14: n / (n + 1) > 0 by A11, XREAL_1:141;
(s1 . (n + 1)) / (s1 . n) = (1 / ((n + 1) to_power p)) / (s1 . n) by A6
.= (1 / ((n + 1) to_power p)) / (1 / (n to_power p)) by A6, A11
.= (1 / ((n + 1) to_power p)) * (n to_power p)
.= (n to_power p) / ((n + 1) to_power p)
.= (n / (n + 1)) to_power p by A11, POWER:36
.= (n / (n + 1)) #R p by A14, POWER:def 2 ;
then (s1 . (n + 1)) / (s1 . n) <= (n / (n + 1)) #R 0 by A1, A14, A13, PREPOWER:98;
then (s1 . (n + 1)) / (s1 . n) <= 1 by A11, PREPOWER:85, XREAL_1:141;
hence s1 . (n + 1) <= s1 . n by A12, XREAL_1:189; :: thesis: verum

end;

end;

end;

hence s1 . (n + 1) <= s1 . n ; :: thesis: verum

end;

then A15: s1 is non-increasing by SEQM_3:def 14;

A16: now

let n be Element of NAT ; :: thesis: ( n >= 0 implies (s1 ^\ 1) . n >= (s ^\ 1) . n )
assume n >= 0 ; :: thesis: (s1 ^\ 1) . n >= (s ^\ 1) . n
A17: n + 1 >= 0 + 1 by XREAL_1:8;
(s ^\ 1) . n = s . (n + 1) by NAT_1:def 3
.= 1 / ((n + 1) to_power p) by A2, A17
.= s1 . (n + 1) by A6
.= (s1 ^\ 1) . n by NAT_1:def 3 ;
hence (s1 ^\ 1) . n >= (s ^\ 1) . n ; :: thesis: verum

end;

deffunc H₂( Element of NAT ) -> Element of REAL = $1 -root (s2 . $1);
consider s3 being Real_Sequence such that
A18: for n being Element of NAT holds s3 . n = H₂(n) from SEQ_1:sch 1();

A19: now

let n be Element of NAT ; :: thesis: ( s2 . n = 2 to_power ((1 - p) * n) & s2 . n >= 0 & s3 . n = n -root ((2 to_power (1 - p)) to_power n) )
A20: 2 to_power n > 0 by POWER:39;
thus A21: s2 . n = (2 to_power n) * (s1 . (2 to_power n)) by A7
.= (2 to_power n) * (1 / ((2 to_power n) to_power p)) by A6, A20
.= (2 to_power n) * (1 / (2 to_power (n * p))) by POWER:38
.= (2 to_power n) * (2 to_power (- (n * p))) by POWER:33
.= 2 to_power (n + (- (n * p))) by POWER:32
.= 2 to_power ((1 - p) * n) ; :: thesis: ( s2 . n >= 0 & s3 . n = n -root ((2 to_power (1 - p)) to_power n) )
hence s2 . n >= 0 by POWER:39; :: thesis: s3 . n = n -root ((2 to_power (1 - p)) to_power n)
s2 . n = (2 to_power (1 - p)) to_power n by A21, POWER:38;
hence s3 . n = n -root ((2 to_power (1 - p)) to_power n) by A18; :: thesis: verum

end;

A22: now

let n be Nat; :: thesis: (s3 ^\ 1) . n = 2 to_power (1 - p)
A23: ( n + 1 >= 0 + 1 & 2 to_power (1 - p) >= 0 ) by POWER:39, XREAL_1:8;
thus (s3 ^\ 1) . n = s3 . (n + 1) by NAT_1:def 3
.= (n + 1) -root ((2 to_power (1 - p)) to_power (n + 1)) by A19
.= 2 to_power (1 - p) by A23, POWER:5 ; :: thesis: verum

end;

then A24: s3 ^\ 1 is V8() by VALUED_0:def 18;
then lim (s3 ^\ 1) = (s3 ^\ 1) . 0 by SEQ_4:41
.= 2 to_power (1 - p) by A22 ;
then A25: lim s3 = 2 to_power (1 - p) by A24, SEQ_4:36;

A26: now

let n be Element of NAT ; :: thesis: ( s1 . n >= 0 & s2 . n = (2 to_power n) * (s1 . (2 to_power n)) )

now

per cases ( n = 0 or ex m being Nat st n = m + 1 ) by NAT_1:6;

suppose n = 0 ; :: thesis: s1 . n >= 0

hence s1 . n >= 0 by A6; :: thesis: verum

end;

suppose ex m being Nat st n = m + 1 ; :: thesis: s1 . n >= 0

then n to_power p > 0 by POWER:39;
then 1 / (n to_power p) >= 0 ;
hence s1 . n >= 0 by A6; :: thesis: verum

end;

end;

end;

hence ( s1 . n >= 0 & s2 . n = (2 to_power n) * (s1 . (2 to_power n)) ) by A7; :: thesis: verum

end;

A27: now

let n be Element of NAT ; :: thesis: (s ^\ 1) . n >= 0
A28: n + 1 >= 0 + 1 by XREAL_1:8;
A29: s1 . (n + 1) >= 0 by A26;
(s ^\ 1) . n = s . (n + 1) by NAT_1:def 3
.= 1 / ((n + 1) to_power p) by A2, A28
.= s1 . (n + 1) by A6
.= (s1 ^\ 1) . n by NAT_1:def 3 ;
hence (s ^\ 1) . n >= 0 by A29, NAT_1:def 3; :: thesis: verum

end;

A30: s3 is convergent by A24, SEQ_4:35;
1 - p < 0 by A1, XREAL_1:51;
then lim s3 < 1 by A25, POWER:41;
then s2 is summable by A18, A19, A30, Th32;
then s1 is summable by A15, A26, Th35;
then s1 ^\ 1 is summable by Th15;
then s ^\ 1 is summable by A27, A16, Th22;
hence s is summable by Th16; :: thesis: verum