let L be non empty multMagma ; :: thesis: for a being Element of L
for p, q being FinSequence of the carrier of L holds (p ^ q) * a = (p * a) ^ (q * a)
let a be Element of L; :: thesis: for p, q being FinSequence of the carrier of L holds (p ^ q) * a = (p * a) ^ (q * a)
let p, q be FinSequence of the carrier of L; :: thesis: (p ^ q) * a = (p * a) ^ (q * a)
A1: dom ((p ^ q) * a) = dom (p ^ q) by Def3;
A2: dom (q * a) = dom q by Def3;
then A3: len (q * a) = len q by FINSEQ_3:31;
A4: dom (p * a) = dom p by Def3;
then A5: len (p * a) = len p by FINSEQ_3:31;

A6: now

let i be Nat; :: thesis: ( i in dom ((p ^ q) * a) implies ((p ^ q) * a) /. b₁ = ((p * a) ^ (q * a)) /. b₁ )
assume A7: i in dom ((p ^ q) * a) ; :: thesis: ((p ^ q) * a) /. b₁ = ((p * a) ^ (q * a)) /. b₁

per cases ( i in dom p or ex n being Nat st
( n in dom q & i = (len p) + n ) ) by A1, A7, FINSEQ_1:38;

suppose A8: i in dom p ; :: thesis: ((p ^ q) * a) /. b₁ = ((p * a) ^ (q * a)) /. b₁

thus ((p ^ q) * a) /. i = ((p ^ q) /. i) * a by A1, A7, Def3
.= (p /. i) * a by A8, FINSEQ_4:83
.= (p * a) /. i by A8, Def3
.= ((p * a) ^ (q * a)) /. i by A4, A8, FINSEQ_4:83 ; :: thesis: verum

end;

suppose ex n being Nat st
( n in dom q & i = (len p) + n ) ; :: thesis: ((p ^ q) * a) /. b₁ = ((p * a) ^ (q * a)) /. b₁

then consider n being Nat such that
A9: n in dom q and
A10: i = (len p) + n ;
thus ((p ^ q) * a) /. i = ((p ^ q) /. i) * a by A1, A7, Def3
.= (q /. n) * a by A9, A10, FINSEQ_4:84
.= (q * a) /. n by A9, Def3
.= ((p * a) ^ (q * a)) /. i by A5, A2, A9, A10, FINSEQ_4:84 ; :: thesis: verum

end;

end;

end;

len ((p * a) ^ (q * a)) = (len (p * a)) + (len (q * a)) by FINSEQ_1:35
.= len (p ^ q) by A5, A3, FINSEQ_1:35 ;
then dom ((p ^ q) * a) = dom ((p * a) ^ (q * a)) by A1, FINSEQ_3:31;
hence (p ^ q) * a = (p * a) ^ (q * a) by A6, FINSEQ_5:13; :: thesis: verum