let A be Ordinal; :: thesis: {} +^ A = A
defpred S₁[ Ordinal] means {} +^ $1 = $1;
A1: for A being Ordinal st S₁[A] holds
S₁[ succ A] by Th45;
A2: for A being Ordinal st A <> {} & A is limit_ordinal & ( for B being Ordinal st B in A holds
S₁[B] ) holds
S₁[A]

proof

deffunc H₁( Ordinal) -> Ordinal = {} +^ $1;
let A be Ordinal; :: thesis: ( A <> {} & A is limit_ordinal & ( for B being Ordinal st B in A holds
S₁[B] ) implies S₁[A] )
assume that
A3: ( A <> {} & A is limit_ordinal ) and
A4: for B being Ordinal st B in A holds
{} +^ B = B ; :: thesis: S₁[A]
consider fi being Ordinal-Sequence such that
A5: ( dom fi = A & ( for B being Ordinal st B in A holds
fi . B = H₁(B) ) ) from ORDINAL2:sch 3();
A6: rng fi = A

proof

thus for x being set st x in rng fi holds
x in A :: according to TARSKI:def 3,XBOOLE_0:def 10 :: thesis: A c= rng fi

proof

let x be set ; :: thesis: ( x in rng fi implies x in A )
assume x in rng fi ; :: thesis: x in A
then consider y being set such that
A7: y in dom fi and
A8: x = fi . y by FUNCT_1:def 5;
reconsider y = y as Ordinal by A7;
x = {} +^ y by A5, A7, A8
.= y by A4, A5, A7 ;
hence x in A by A5, A7; :: thesis: verum

end;

let x be set ; :: according to TARSKI:def 3 :: thesis: ( not x in A or x in rng fi )
assume A9: x in A ; :: thesis: x in rng fi
then reconsider B = x as Ordinal ;
( {} +^ B = B & fi . B = {} +^ B ) by A4, A5, A9;
hence x in rng fi by A5, A9, FUNCT_1:def 5; :: thesis: verum

end;

{} +^ A = sup fi by A3, A5, Th46
.= sup (rng fi) ;
hence S₁[A] by A6, Th26; :: thesis: verum

end;

A10: S₁[ {} ] by Th44;
for A being Ordinal holds S₁[A] from ORDINAL2:sch 1(A10, A1, A2);
hence {} +^ A = A ; :: thesis: verum