let S, T be non trivial RealNormSpace; :: thesis: for f being PartFunc of S,T
for Z being Subset of S st Z is open & Z c= dom f & ex r being Point of T st rng f = {r} holds
( f is_differentiable_on Z & ( for x being Point of S st x in Z holds
(f `| Z) /. x = 0. (R_NormSpace_of_BoundedLinearOperators S,T) ) )
let f be PartFunc of S,T; :: thesis: for Z being Subset of S st Z is open & Z c= dom f & ex r being Point of T st rng f = {r} holds
( f is_differentiable_on Z & ( for x being Point of S st x in Z holds
(f `| Z) /. x = 0. (R_NormSpace_of_BoundedLinearOperators S,T) ) )
let Z be Subset of S; :: thesis: ( Z is open & Z c= dom f & ex r being Point of T st rng f = {r} implies ( f is_differentiable_on Z & ( for x being Point of S st x in Z holds
(f `| Z) /. x = 0. (R_NormSpace_of_BoundedLinearOperators S,T) ) ) )
assume that
A1: Z is open and
A2: Z c= dom f ; :: thesis: ( for r being Point of T holds not rng f = {r} or ( f is_differentiable_on Z & ( for x being Point of S st x in Z holds
(f `| Z) /. x = 0. (R_NormSpace_of_BoundedLinearOperators S,T) ) ) )
reconsider R = the carrier of S --> (0. T) as PartFunc of S,T ;
set L = 0. (R_NormSpace_of_BoundedLinearOperators S,T);
given r being Point of T such that A3: rng f = {r} ; :: thesis: ( f is_differentiable_on Z & ( for x being Point of S st x in Z holds
(f `| Z) /. x = 0. (R_NormSpace_of_BoundedLinearOperators S,T) ) )
R_NormSpace_of_BoundedLinearOperators S,T = NORMSTR(# (BoundedLinearOperators S,T),(Zero_ (BoundedLinearOperators S,T),(R_VectorSpace_of_LinearOperators S,T)),(Add_ (BoundedLinearOperators S,T),(R_VectorSpace_of_LinearOperators S,T)),(Mult_ (BoundedLinearOperators S,T),(R_VectorSpace_of_LinearOperators S,T)),(BoundedLinearOperatorsNorm S,T) #) by LOPBAN_1:def 15;
then reconsider L = 0. (R_NormSpace_of_BoundedLinearOperators S,T) as Element of BoundedLinearOperators S,T ;
A4: dom R = the carrier of S by FUNCOP_1:19;

A5: now

let h be convergent_to_0 sequence of S; :: thesis: ( (||.h.|| " ) (#) (R /* h) is convergent & lim ((||.h.|| " ) (#) (R /* h)) = 0. T )

A6: now

let n be Nat; :: thesis: ((||.h.|| " ) (#) (R /* h)) . n = 0. T
A7: R /. (h . n) = R . (h . n) by A4, PARTFUN1:def 8
.= 0. T by FUNCOP_1:13 ;
A8: rng h c= dom R by A4;
A9: n in NAT by ORDINAL1:def 13;
hence ((||.h.|| " ) (#) (R /* h)) . n = ((||.h.|| " ) . n) * ((R /* h) . n) by Def2
.= ((||.h.|| " ) . n) * (R /. (h . n)) by A9, A8, FUNCT_2:186
.= 0. T by A7, RLVECT_1:23 ;
:: thesis: verum

end;

then A10: (||.h.|| " ) (#) (R /* h) is constant by VALUED_0:def 18;
hence (||.h.|| " ) (#) (R /* h) is convergent by Th21; :: thesis: lim ((||.h.|| " ) (#) (R /* h)) = 0. T
((||.h.|| " ) (#) (R /* h)) . 0 = 0. T by A6;
hence lim ((||.h.|| " ) (#) (R /* h)) = 0. T by A10, Th21; :: thesis: verum

end;

A11: now

let x0 be Point of S; :: thesis: ( x0 in dom f implies f /. x0 = r )
assume A12: x0 in dom f ; :: thesis: f /. x0 = r
then f . x0 in {r} by A3, FUNCT_1:def 5;
then f /. x0 in {r} by A12, PARTFUN1:def 8;
hence f /. x0 = r by TARSKI:def 1; :: thesis: verum

end;

reconsider R = R as REST of S,T by A5, Def5;
A13: the carrier of S --> (0. T) = L by LOPBAN_1:37;

A14: now

let x0 be Point of S; :: thesis: ( x0 in Z implies f is_differentiable_in x0 )
assume A15: x0 in Z ; :: thesis: f is_differentiable_in x0
then consider N being Neighbourhood of x0 such that
A16: N c= Z by A1, Th2;
A17: N c= dom f by A2, A16, XBOOLE_1:1;
for x being Point of S st x in N holds
(f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0))

proof

let x be Point of S; :: thesis: ( x in N implies (f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0)) )
A18: R /. (x - x0) = R . (x - x0) by A4, PARTFUN1:def 8
.= 0. T by FUNCOP_1:13 ;
assume x in N ; :: thesis: (f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0))
hence (f /. x) - (f /. x0) = r - (f /. x0) by A11, A17
.= r - r by A2, A11, A15
.= 0. T by RLVECT_1:28
.= (0. T) + (0. T) by RLVECT_1:10
.= (L . (x - x0)) + (R /. (x - x0)) by A13, A18, FUNCOP_1:13 ;
:: thesis: verum

end;

hence f is_differentiable_in x0 by A17, Def6; :: thesis: verum

end;

hence A19: f is_differentiable_on Z by A1, A2, Th36; :: thesis: for x being Point of S st x in Z holds
(f `| Z) /. x = 0. (R_NormSpace_of_BoundedLinearOperators S,T)
let x0 be Point of S; :: thesis: ( x0 in Z implies (f `| Z) /. x0 = 0. (R_NormSpace_of_BoundedLinearOperators S,T) )
assume A20: x0 in Z ; :: thesis: (f `| Z) /. x0 = 0. (R_NormSpace_of_BoundedLinearOperators S,T)
then A21: f is_differentiable_in x0 by A14;
then ex N being Neighbourhood of x0 st
( N c= dom f & ex L being Point of (R_NormSpace_of_BoundedLinearOperators S,T) ex R being REST of S,T st
for x being Point of S st x in N holds
(f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0)) ) by Def6;
then consider N being Neighbourhood of x0 such that
A22: N c= dom f ;
A23: for x being Point of S st x in N holds
(f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0))

proof

let x be Point of S; :: thesis: ( x in N implies (f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0)) )
A24: R /. (x - x0) = R . (x - x0) by A4, PARTFUN1:def 8
.= 0. T by FUNCOP_1:13 ;
assume x in N ; :: thesis: (f /. x) - (f /. x0) = (L . (x - x0)) + (R /. (x - x0))
hence (f /. x) - (f /. x0) = r - (f /. x0) by A11, A22
.= r - r by A2, A11, A20
.= 0. T by RLVECT_1:28
.= (0. T) + (0. T) by RLVECT_1:10
.= (L . (x - x0)) + (R /. (x - x0)) by A13, A24, FUNCOP_1:13 ;
:: thesis: verum

end;

thus (f `| Z) /. x0 = diff f,x0 by A19, A20, Def9
.= 0. (R_NormSpace_of_BoundedLinearOperators S,T) by A21, A22, A23, Def7 ; :: thesis: verum